Wolfram 语言与系统参考资料中心

BubbleChart

BubbleChart[{{x₁,y₁,z₁},{x₂,y₂,z₂},…}]

制作一个气泡图，气泡在坐标 {x_i,y_i} 处的大小为 z_i.

BubbleChart[{…,w_i[{x_i,y_i,z_i},…],…,w_j[{x_j,y_j,z_j},…],…}]

制作一个气泡图，其气泡特征由符号式封装 w_k 定义.

BubbleChart[{data₁,data₂,…}]

根据多个数据集 data_i 制作一个气泡图.

范例

打开所有单元关闭所有单元

基本范例 (3)

创建一个三元组列表的气泡图：

Wolfram Language code: BubbleChart[RandomReal[1, {10, 3}]]

多个数据集：

Wolfram Language code: BubbleChart[RandomReal[1, {5, 7, 3}]]

设置气泡的样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {5, 7, 3}], PlotStyle -> {RGBColor[0.237736, 0.340215, 0.575113], RGBColor[0.277947, 0.45009699999999997, 0.32815550000000004], RGBColor[0.624866, 0.673302, 0.264296], RGBColor[0.8453409999999999, 0.6248695, 0.3151775], RGBColor[0.72987, 0.239399, 0.230961]}]

绘图式气泡：

Wolfram Language code: BubbleChart[RandomReal[1, {10, 3}], ChartElements -> [image]]

程序式的气泡：

Wolfram Language code: BubbleChart[RandomReal[1, {10, 3}], ChartElementFunction -> "NoiseBubble"]

范围 (32)

数据和封装 (14)

数据集中的项用相同方式着色：

Wolfram Language code: BubbleChart[{Table[{i, i, 1}, {i, 3}], Table[{i, i + 1, 1}, {i, 3}], Table[{i, i + 2, 1}, {i, 3}]}]

非实数数据被认为缺失：

Wolfram Language code: data = ReplacePart[Flatten[Table[{i, j, 1}, {i, 4}, {j, 4}], 1], {2 -> Missing[], 4 -> 1 + I, 6 -> foo}]

Wolfram Language code: BubbleChart[data, PlotLabels -> Range[16]]

数据可以带有单位：

Wolfram Language code:

BubbleChart[{{Quantity[2, "Feet"], Quantity[-4, "Feet"], Quantity[14, "Feet"]}, {Quantity[6, "Feet"], Quantity[25, "Feet"], Quantity[22, "Feet"]}, {Quantity[-3, "Feet"], Quantity[17, "Feet"], Quantity[1, "Feet"]}, {Quantity[11, "Feet"], Quantity[17, "Feet"], Quantity[7, "Feet"]}, {Quantity[25, "Feet"], Quantity[-3, "Feet"], Quantity[21, "Feet"]}}, FrameLabel -> Automatic]

指定所用的单位：

Wolfram Language code:

BubbleChart[{{Quantity[2, "Feet"], Quantity[-4, "Feet"], Quantity[14, "Feet"]}, {Quantity[6, "Feet"], Quantity[25, "Feet"], Quantity[22, "Feet"]}, {Quantity[-3, "Feet"], Quantity[17, "Feet"], Quantity[1, "Feet"]}, {Quantity[11, "Feet"], Quantity[17, "Feet"], Quantity[7, "Feet"]}, {Quantity[25, "Feet"], Quantity[-3, "Feet"], Quantity[21, "Feet"]}}, FrameLabel -> Automatic, TargetUnits -> {"Meters", "Yards", "Inches"}]

TimeSeries、EventSeries 和 TemporalData 的时间标记将被忽略：

Wolfram Language code: BubbleChart[TimeSeries[{{23, 12, 24}, {15, 3, 9}, {3, 23, 12}, {7, 11, 6}, {5, 24, 20}, {5, 17, 8}}, {"May 24, 1982"}]]

关联中的值被用作气泡值：

Wolfram Language code: BubbleChart[<|"a" -> {3, 1, 5}, "b" -> {2, 2, 4}, "c" -> {1, 2, 3}, "d" -> {2, 1.5, 8}|>]

使用键作为标签：

Wolfram Language code: BubbleChart[<|"a" -> {3, 1, 5}, "b" -> {2, 2, 4}, "c" -> {1, 2, 3}, "d" -> {2, 1.5, 8}|>, PlotLabels -> Automatic]

使用键作为图例：

Wolfram Language code:

BubbleChart[<|"a" -> {3, 1, 5}, "b" -> {2, 2, 4}, "c" -> {1, 2, 3}, "d" -> {2, 1.5, 8}|>, PlotLegends -> Automatic, PlotStyle -> {Hue[0.61, 0.7, 1], Hue[0.17, 0.4, 0.65], Hue[0.64, 0.5, 0.75], Hue[0.45, 0.4, 0.7]}]

关联可以嵌套，低至点层：

Wolfram Language code:

BubbleChart[<|"a" -> <|"x" -> 3, "y" -> 1, "z" -> 5|>, "b" -> <|"x" -> 2, "y" -> 2, "z" -> 4|>, "c" -> <|"x" -> 1, "y" -> 2, "z" -> 3|>|>, PlotLegends -> Automatic, PlotStyle -> {Hue[0.61, 0.7, 1], Hue[0.17, 0.4, 0.65], Hue[0.64, 0.5, 0.75]}, FrameLabel -> Automatic]

或者高至组层：

Wolfram Language code:

BubbleChart[<|"group1" -> <|"a" -> {3, 1, 5}, "b" -> {2, 2, 4}, "c" -> {1, 2, 3}, "d" -> {2, 1.5, 8}|>, "group2" -> <|"a" -> {2, 5, 9}, "b" -> {6, 1, 3}, "c" -> {1, 3, 6}, "d" -> {3, 2, 6}|>|>, PlotLegends -> Automatic, PlotStyle -> {Hue[0.08, 1, 1], Hue[0.17, 0.8, 0.5]}]

WeightedData 中的权值将被忽略：

Wolfram Language code:

BubbleChart[WeightedData[{{23, 12, 24}, {15, 3, 9}, {3, 23, 12}, {7, 11, 6}, {5, 24, 20}, {5, 17, 8}}, {0.4, 0.2, 0.6, 0.3, 0.4, 0.3}]]

单个数据、数据集或数据集的集合上的封装：

Wolfram Language code:

{d1, d2, d3} = {{1, 2, 1}, {2, 2, 1}, {3, 2, 1}};
{e1, e2, e3} = {{1, 1, 1}, {2, 1, 1}, {3, 1, 1}};

Wolfram Language code:

{BubbleChart[{{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3}, {e1, e2, e3}}], BubbleChart[{Style[{d1, d2, d3}, RGBColor[0.93, 0.27, 0.27]], {e1, e2, e3}}], BubbleChart[Style[{{d1, d2, d3}, {e1, e2, e3}}, RGBColor[0.93, 0.27, 0.27]]]}

嵌套封装：

Wolfram Language code:

{d1, d2, d3} = {{1, 2, 1}, {2, 2, 1}, {3, 2, 1}};
{e1, e2, e3} = {{1, 1, 1}, {2, 1, 1}, {3, 1, 1}};

Wolfram Language code:

{BubbleChart[{{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3}, {e1, e2, e3}}, PlotStyle -> GrayLevel[0.62]], BubbleChart[{Style[{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3}, RGBColor[0.14, 0.8, 0.14]], {e1, e2, e3}}, PlotStyle -> GrayLevel[0.62]], BubbleChart[Style[{Style[{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3}, RGBColor[0.14, 0.8, 0.14]], {e1, e2, e3}}, RGBColor[0.4, 0.6, 1]], PlotStyle -> GrayLevel[0.62]]}

屏蔽缺省的工具提示：

Wolfram Language code: BubbleChart[{{1, 2, 1}, Tooltip[{1, 1, 2}, "median"], {2, 3, 3}}, BubbleSizes -> {0.2, 0.7}]

用工具提示上的任何对象：

Wolfram Language code:

data = Table[Tooltip[{CountryData[c, #]& /@ {"LifeExpectancy", "GDPPerCapita", "Population"}}, CountryData[c, "Flag"]], {c, CountryData["G8"]}];

Wolfram Language code: BubbleChart[data]

用 PopupWindow 提供其它的向下钻取（drill down）的信息：

Wolfram Language code:

BubbleChart[{{1, 2, 2}, {1, 1, 1}, PopupWindow[{2, 3, 3}, DateListPlot[FinancialData["IBM", "Jan. 1, 2004"]]]}, BubbleSizes -> {0.2, 0.7}]

Button 可以用于触发任何行为：

Wolfram Language code: BubbleChart[{{1, 2, 2}, {1, 1, 1}, Button[{2, 3, 3}, Speak[2]]}, BubbleSizes -> {0.2, 0.7}]

表格数据 (3)

获取表格数据：

Wolfram Language code: cars = ResourceData["Sample Tabular Data: Car Models"]

根据排量绘制马力图，气泡大小取决于里程数：

Wolfram Language code: BubbleChart[cars -> {"displacement", "horsepower", "mpg"}]

透视数据，创建每个地区的里程数列：

Wolfram Language code: pivot = PivotToColumns[cars, "origin" -> "mpg"]

按原产地绘制数据图：

Wolfram Language code:

BubbleChart[pivot -> {{"displacement", "horsepower", ExtendedKey["mpg", "europe"]}, {"displacement", "horsepower", ExtendedKey["mpg", "japan"]}, {"displacement", "horsepower", ExtendedKey["mpg", "usa"]}}, PlotLegends -> {"Europe", "Japan", "USA"}]

Wolfram Language code:

BubbleChart[TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 5, 
   "Endpoints" -> TabularColumn[Association[
      "Data" -> {2, {{NumericArray[{20563, -2147483648}, "Integer32"], {}, 
          DataStructure["BitVec ... ularColumn[Association[
           "Data" -> {{17, 5, 7, 6, 13}, {}, None}, "ElementType" -> "Integer64"]], 
         TabularColumn[Association["Data" -> {{3, 2, 2, 1, 1}, {}, None}, 
           "ElementType" -> "Integer64"]]}}]]]], Association[]]]

绘制 TimeSeries 或 EventSeries 中一个分量的值：

Wolfram Language code:

ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 5, 
   "Endpoints" -> TabularColumn[Association[
      "Data" -> {2, {{NumericArray[{20563, -2147483648}, "Integer32"], {}, 
          DataStructure["BitVec ... e" -> "Integer64"]], TabularColumn[Association[
           "Data" -> {{3.5511999004449324, 1.777675777376151, 1.3490852490420469, 
              3.8396388450135266, 4.100051503528421}, {}, None}, "ElementType" -> "Real64"]]}}]]]], 
 Association[]];

Wolfram Language code: BubbleChart[ts -> {"a", "b", "c"}]

绘制多个分量的值：

Wolfram Language code: BubbleChart[ts -> {{"a", "b", "c"}, {"d", "e", "f"}}]

样式和外观 (6)

对于气泡用明确的样式列表：

Wolfram Language code:

BubbleChart[RandomReal[1, {3, 5, 3}], PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

PlotStyle 可以对所有图表元素设置一个初始样式：

Wolfram Language code:

BubbleChart[{{1, 2, 2}, {1, 1, 1}, {2, 3, 3}}, PlotStyle -> <|"Base" -> EdgeForm[Dashed], "Elements" -> {RGBColor[0.797253, 0.904982, 0.410498], RGBColor[0.934691, 0.945708, 0.75346], RGBColor[0.769879, 0.92369, 0.977371]}|>, BubbleSizes -> {0.2, 0.7}]

Style 可以用于屏蔽样式：

Wolfram Language code:

BubbleChart[{{1, 2, 2}, {1, 1, 1}, Style[{2, 3, 3}, RGBColor[0.93, 0.27, 0.27]], {3, 4, 1}}, PlotStyle -> GrayLevel[0.62], BubbleSizes -> {0.2, 0.7}]

对绘图气泡用任何图形：

Wolfram Language code:

BubbleChart[{{1, 2, 2}, {1, 1, 1}, {2, 3, 3}}, ChartElements -> Graphics3D[Cylinder[], Boxed -> False], BubbleSizes -> {0.2, 0.7}]

用内置的程序产生气泡：

Wolfram Language code: ChartElementData["BubbleChart"]

Wolfram Language code:

Table[BubbleChart[{{1, 2, 2}, {1, 1, 1}, {2, 3, 3}}, ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}, BubbleSizes -> {0.2, 0.7}], {f, {"PolyhedronBubble", "MarkerBubble"}}]

用面板 ▶ 图表元素方案具体设置：

Wolfram Language code:

BubbleChart[{{1, 2, 2}, {1, 1, 1}, {2, 3, 3}}, ChartElementFunction -> ChartElementDataFunction["Bubble", "Shape" -> "Hexagon"], BubbleSizes -> {0.2, 0.7}]

使用明亮色彩方案中具有简单刻度和网格线的主题：

Wolfram Language code: BubbleChart[RandomReal[1, {3, 3, 3}], PlotTheme -> "Business"]

使用具有高对比度色彩方案和三维气泡的主题：

Wolfram Language code: BubbleChart[RandomReal[1, {3, 3, 3}], PlotTheme -> "Marketing"]

标签和图例 (9)

用 Labeled 对一个气泡添加标签：

Wolfram Language code: BubbleChart[{{1, 2, 1}, Labeled[{1, 1, 2}, "label", Left], {2, 3, 3}}, BubbleSizes -> {0.2, 0.7}]

对标签替换用符号坐标：

Wolfram Language code:

Table[BubbleChart[{{1, 2, 2}, Labeled[{2, 3, 3}, "label", p], {1, 1, 1}}, BubbleSizes -> {0.2, 0.7}, PlotLabel -> p, Ticks -> None], {p, {Bottom, Center, Top}}]

用 Placed 控制标签坐标，用和 Labeled 的相同坐标：

Wolfram Language code:

BubbleChart[{{{2, 1, 1}, {1, 1, 1}}, {{1, 2, 2}, {2, 3, 3}}}, PlotLabels -> <|"Elements" -> Placed[{"c1", "c2"}, Center]|>, BubbleSizes -> {0.2, 0.7}]

用 LabelingFunction 对气泡提供值的标签：

Wolfram Language code: labeler[v_, {i_, j_}, {ri_, cj_}] := Placed[{v, ri[[1]], cj[[1]]}, Tooltip, MatrixForm]

Wolfram Language code:

BubbleChart[{{{2, 3, 3}, {1, 2, 2}, {1, 1, 1}}, {{1, 3, 2}, {2, 1, 1}}}, PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>, FrameTicks -> None, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> labeler]

指定标签的最大尺寸：

Wolfram Language code: data = Table[Callout[RandomReal[1, 3], RandomWord[]], {i, 20}];

Wolfram Language code: BubbleChart[data, LabelingSize -> 30]

显示完整的标签：

Wolfram Language code: BubbleChart[data, LabelingSize -> Full]

对于密集点集，默认情况下，某些标签会变成提示条：

Wolfram Language code: data = Table[Callout[RandomReal[1, 3], RandomWord[]], {i, 100}];

Wolfram Language code: BubbleChart[data]

增加图的大小会绘制更多的标签：

Wolfram Language code: BubbleChart[data, ImageSize -> 400]

对不同数据集用图例项：

Wolfram Language code: data = RandomReal[1, {7, 3}];

Wolfram Language code:

BubbleChart[{data, data + 1}, PlotLegends -> {"data1", "data2"}, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}]

用 Legended 增加其它图例项：

Wolfram Language code:

BubbleChart[{{{2, 3, 3}, Legended[Style[{1, 2, 2}, RGBColor[1, 0.75, 0]], "extra"], {1, 1, 1}}, {{1, 3, 2}, {2, 1, 1}}}, PlotLegends -> {"data1", "data2"}, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}]

用 Placed 影响图例坐标：

Wolfram Language code: data = RandomReal[1, {7, 3}];

Wolfram Language code:

Table[BubbleChart[{data, data + 1}, PlotLegends -> Placed[{"data1", "data2"}, p], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}], {p, {Below, Above}}]

选项 (122)

AspectRatio (3)

默认情况下，BubbleChart 使用固定的高宽比：

Wolfram Language code: BubbleChart[IconizedObject[«data»]]

用数值指定高宽比：

Wolfram Language code: BubbleChart[IconizedObject[«data»], AspectRatio -> 1 / 2]

AspectRatioAutomatic 根据数值确定范围：

Wolfram Language code: BubbleChart[IconizedObject[«data»], AspectRatio -> Automatic]

Axes (3)

默认情况下，BubbleChart 使用边框而非轴：

Wolfram Language code: BubbleChart[IconizedObject[«data»]]

使用轴而非边框：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True]

单独显示每条轴：

Wolfram Language code:

{BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> {True, False}], BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> {False, True}]}

AxesLabel (4)

默认情况下不绘制坐标轴标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True]

在轴上放置标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesLabel -> "Y-axis"]

指定轴标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesLabel -> {"x position", "y position"}]

使用单位作为标签：

Wolfram Language code: BubbleChart[QuantityArray[IconizedObject[«data»], "Meters"], Frame -> False, Axes -> True, AxesLabel -> Automatic]

AxesOrigin (2)

自动确定轴的位置：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True]

为轴指定明确原点：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesOrigin -> {1, 0}]

AxesStyle (4)

更改轴的样式：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> RGBColor[0.93, 0.27, 0.27]]

指定每条轴的样式：

Wolfram Language code:

**BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> {{Thick, RGBColor[0.93, 0.27, 0.27]}, {Thick, RGBColor[0.4, 0.6, 1]}}]**

对刻度和轴使用不同的样式：

Wolfram Language code:

**BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> RGBColor[0.14, 0.8, 0.14], TicksStyle -> GrayLevel[0.62]]**

对标签和轴使用不同的样式：

Wolfram Language code:

**BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, AxesStyle -> RGBColor[0.14, 0.8, 0.14], LabelStyle -> RGBColor[0.93, 0.27, 0.27]]**

BubbleScale (2)

缺省下气泡的面积和 z 值成比例：

Wolfram Language code: BubbleChart[RandomReal[1, {3, 3, 3}], BubbleSizes -> {0.1, 0.4}, BubbleScale -> "Diameter"]

比较面积尺度和直径尺度：

Wolfram Language code: data = Table[{i, i, i}, {i, 10}];

Wolfram Language code:

Table[BubbleChart[data, BubbleSizes -> {0.1, 0.4}, BubbleScale -> scale, PlotLabel -> scale], {scale, {"Area", "Diameter"}}]

BubbleSizes (1)

改变气泡的范围大小：

Wolfram Language code: data = Table[{i, i, i}, {i, 5}];

Wolfram Language code: Table[BubbleChart[data, BubbleSizes -> {0.1, smax}, PlotLabel -> {0.1, smax}], {smax, {0.2, 0.3, 0.5}}]

ChartElementFunction (5)

获得 ChartElementFunction 的内置设置的列表：

Wolfram Language code: ChartElementData["BubbleChart"]

用面板 ▶ 图表元素方案具体设置：

Wolfram Language code: data = {{1, 0, 1}, {0, 1, 2}, {1, 2, 3}};

Wolfram Language code:

Table[BubbleChart[data, ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}, PlotLabel -> f], {f, {"Bubble", "MarkerBubble"}}]

Wolfram Language code:

Table[BubbleChart[data, ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}, PlotLabel -> f], {f, {"SphereBubble", "PolyhedronBubble"}}]

Wolfram Language code:

Table[BubbleChart[data, ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}, PlotLabel -> f], {f, {"NoiseBubble", "OscillatingBubble"}}]

写入一个自定义的 ChartElementFunction：

Wolfram Language code:

f[{{xmin_, xmax_}, {ymin_, ymax_}}, v_, meta_, style___] := 
	{Rectangle[{xmin, ymin}, {xmax, ymax}]}

Wolfram Language code: BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, ChartElementFunction -> f]

用输入传递的元数据，在这个例子中对数据的制图：

Wolfram Language code:

DataDrilldownBubble[{{xmin_, xmax_}, {ymin_, ymax_}}, v_, {meta_}, style___] := 
	PopupWindow[Polygon[{{xmin, ymin}, {xmax, ymax}, {xmin, ymax}, {xmax, ymin}}], PieChart[meta]]

Wolfram Language code:

DataDrilldownBubble[{{xmin_, xmax_}, {ymin_, ymax_}}, y_, ___] := 
	Rectangle[{xmin, ymin}, {xmax, ymax}]

Wolfram Language code:

BubbleChart[{{1, 0, 1} -> Range[5], {0, 1, 2}, {1, 2, 3} -> RandomReal[1, 10]}, ChartElementFunction -> DataDrilldownBubble]

内置元素函数可能有选项；用面板 ▶ 图表元素方案设置它们：

Wolfram Language code: ChartElementData["MarkerBubble", "Options"]

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, ChartElementFunction -> ChartElementDataFunction["MarkerBubble", "Shape" -> s, "Filled" -> True]], {s, {"CircleTimes", "Diamond"}}]

ChartElements (5)

创建基于任何 Graphics 对象的绘图图表：

Wolfram Language code: data = RandomReal[1, {7, 3}];

Wolfram Language code: BubbleChart[data, ChartElements -> Graphics[Rectangle[]]]

Graphics3D：

Wolfram Language code: BubbleChart[data, ChartElements -> Graphics3D[Sphere[]]]

Image：

Wolfram Language code: BubbleChart[data, ChartElements -> ExampleData[{"TestImage", "House"}]]

对每个数据集用不同的图形：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 3}}, {{5, 4, 5}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code: BubbleChart[data, ChartElements -> {[image], [image]}]

循环使用图形：

Wolfram Language code: BubbleChart[{{1, 1, 1}, {2, 2, 1}, {3, 3, 1}, {4, 4, 1}, {5, 5, 1}}, ChartElements -> {[image], [image], [image]}]

样式可以继承 PlotStyle 等样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {10, 3}], ChartElements -> [image], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}]

图形中明确的样式设置会屏蔽其它样式设置：

Wolfram Language code:

BubbleChart[RandomReal[1, {10, 3}], ChartElements -> [image], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}]

创建三维阴影气泡：

Wolfram Language code:

g = Graphics3D[{Specularity[White, 30], Sphere[]}, ViewPoint -> {0, -Infinity, 0}, Boxed -> False, Lighting -> "Neutral"];

Wolfram Language code:

BubbleChart[RandomReal[1, {10, 3}], ChartElements -> g, PlotStyle -> {RGBColor[0.782803, 0.164904, 0.400458], RGBColor[0.909499, 0.613916, 0.204196], RGBColor[0.806577, 0.385397, 0.762768], RGBColor[0.698817, 0.873304, 0.295247], RGBColor[0.378897, 0.873304, 0.787549], RGBColor[1, 0.529198, 0.324819], RGBColor[1, 0.998367, 0.434775], RGBColor[0.873304, 0.150484, 0.255131], RGBColor[0.723598, 0.791043, 0.963806], RGBColor[0.85037, 0.558389, 0]}]

ColorFunction (3)

通过坐标值的着色：

Wolfram Language code: BubbleChart[RandomInteger[100, {2, 70, 3}], ColorFunction -> Function[{x, y, r}, Lighter[RGBColor[0.14, 0.8, 0.14], x]]]

用 ColorFunctionScaling->False，获得未缩放的高度值：

Wolfram Language code:

BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, ColorFunction -> Function[{x, y, r}, Switch[{x, y, r}, {0, 0, 1}, RGBColor[1, 0.75, 0], {0.1, 0.8, 2}, RGBColor[0.98, 0.56, 0.17], {1, 2, 3}, RGBColor[0.93, 0.27, 0.27]]], ColorFunctionScaling -> False]

ColorFunction 屏蔽 PlotStyle 中的样式：

Wolfram Language code: data = {{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}};

Wolfram Language code: BubbleChart[data, PlotStyle -> RGBColor[0.14, 0.8, 0.14], ColorFunction -> "SolarColors"]

用 ColorFunction 组合不同样式效果：

Wolfram Language code: BubbleChart[data, PlotStyle -> EdgeForm /@ {None, Dashed, Dotted}, ColorFunction -> "SolarColors"]

ColorFunctionScaling (2)

缺省下使用尺度的高度值：

Wolfram Language code: BubbleChart[RandomInteger[100, {2, 70, 3}], ColorFunction -> Function[{x, y, r}, Lighter[RGBColor[0.14, 0.8, 0.14], x]]]

用 ColorFunctionScaling->False 得到未缩放的高度值：

Wolfram Language code:

BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, ColorFunction -> Function[{x, y, r}, Switch[{x, y, r}, {0, 0, 1}, RGBColor[1, 0.75, 0], {0.1, 0.8, 2}, RGBColor[0.98, 0.56, 0.17], {1, 2, 3}, RGBColor[0.93, 0.27, 0.27]]], ColorFunctionScaling -> False]

Frame (4)

BubbleChart 默认情况下使用边框：

Wolfram Language code: BubbleChart[IconizedObject[«data»]]

使用 FrameFalse 关闭边框：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False]

在左边和右边绘制边框：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> {{True, True}, {False, False}}]

在左边和底边绘制边框：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> {{True, False}, {True, False}}]

FrameLabel (4)

在图表底边放置标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameLabel -> {"label"}]

默认情况下，边框标签放置在边框的底边和左边：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameLabel -> {"Bottom", "Left"}]

在边框的每边都放置标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameLabel -> {{"left", "right"}, {"bottom", "top"}}]

对标签和边框刻度标签使用自定义样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameLabel -> {{"left", "right"}, {"bottom", "top"}}, LabelStyle -> Directive[Bold, GrayLevel[0.62]]]

FrameStyle (2)

指定边框的样式：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameStyle -> Directive[GrayLevel[0.62], Thick]]

为每条边框边指定样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameStyle -> {{Directive[RGBColor[0.14, 0.8, 0.14], Thick], Directive[RGBColor[0.93, 0.27, 0.27]]}, {Directive[GrayLevel[0.62], Thick], Directive[RGBColor[0.4, 0.6, 1]]}}]

FrameTicks (7)

默认情况下自动放置边框刻度：

Wolfram Language code: BubbleChart[IconizedObject[«data»]]

默认情况下，顶边和右边有刻度线但没有刻度标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»]]

使用 All 可在所有边上添加刻度标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameTicks -> All]

在指定位置放置刻度线：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameTicks -> {{{.1, .5, .8}, Automatic}, {Automatic, Automatic}}]

使用特定标签在指定位置绘制边框刻度线：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameTicks -> {{{{.1, a}, {.5, b}, {.8, c}}, Automatic}, {{{.1, a}, {.5, b}, {.8, c}}, Automatic}}]

将刻度长度指定为图表大小的一定比例：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameTicks -> {{{{.1, a, .1}, {.5, b, .1}, {.8, c, .1}}, Automatic}, {{{.1, a, .2}, {.5, b, .2}, {.8, c, .2}}, Automatic}}]

在正向和负向使用不同尺寸的刻度线：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameTicks -> {{{{.1, a, {.1, .1}}, {.5, b, {.1, .1}}, {.8, c, {.1, .1}}}, Automatic}, {{{.1, a, {.2, .05}}, {.5, b, {.2, .05}}, {.8, c, {.2, .05}}}, Automatic}}]

为边框刻度指定样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameTicks -> {{{{.1, a, {.1, .1}, Directive[Thick, RGBColor[0.4, 0.6, 1], Dashed]}, {.5, b, {.1, .1}, Directive[Thick, RGBColor[0.14, 0.8, 0.14]]}, {.8, c, {.1, .1}, Directive[Thick, RGBColor[0.93, 0.27, 0.27]]}}, Automatic}, {Automatic, Automatic}}]

FrameTicksStyle (3)

默认情况下，边框刻度和边框刻度标签使用与边框相同的样式：

Wolfram Language code: BubbleChart[IconizedObject[«data»], FrameStyle -> Directive[RGBColor[0.93, 0.27, 0.27]]]

为边框刻度指定样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameTicksStyle -> Directive[RGBColor[0.4, 0.6, 1], Thick], FrameStyle -> GrayLevel[0.85]]

每条边框边使用不同的刻度样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], FrameTicksStyle -> {{Directive[RGBColor[0.93, 0.27, 0.27], Thick], Directive[RGBColor[0.4, 0.6, 1], Thick]}, {Directive[RGBColor[0.98, 0.56, 0.17], Thick], Directive[RGBColor[0.14, 0.8, 0.14], Thick]}}, FrameTicks -> All, FrameStyle -> GrayLevel[0.85]]

ImageSize (7)

使用有名称的尺寸如 Tiny、Small、Medium 和 Large：

Wolfram Language code: {BubbleChart[IconizedObject[«data»], ImageSize -> Tiny], BubbleChart[IconizedObject[«data»], ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code:

{BubbleChart[IconizedObject[«data»], ImageSize -> 150], BubbleChart[IconizedObject[«data»], AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code:

{BubbleChart[IconizedObject[«data»], ImageSize -> {Automatic, 150}], BubbleChart[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定尺寸：

Wolfram Language code:

{BubbleChart[IconizedObject[«data»], ImageSize -> UpTo[200]], BubbleChart[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code: BubbleChart[IconizedObject[«data»], ImageSize -> {200, 200}, Background -> GrayLevel[0.62]]

设置 AspectRatioFull 可填充可用空间：

Wolfram Language code: BubbleChart[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {200, 200}, Background -> GrayLevel[0.62]]

使用最大尺寸的宽度和高度：

Wolfram Language code:

{BubbleChart[IconizedObject[«data»], ImageSize -> {UpTo[150], UpTo[100]}], BubbleChart[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

使用 ImageSizeFull 可填充对象中的可用空间：

Wolfram Language code: Framed[Pane[BubbleChart[IconizedObject[«data»], ImageSize -> Full, Background -> GrayLevel[0.62]], {200, 100}]]

将图像大小指定为可用空间的一定比例：

Wolfram Language code:

Framed[Pane[BubbleChart[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> GrayLevel[0.62]], {200, 100}]]

LabelingFunction (7)

Tooltip 和 StatusArea 使用自动标签值：

Wolfram Language code: BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> Automatic]

不使用标签：

Wolfram Language code: BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> None]

用 Placed 控制标签坐标：

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> (Placed[#, p]&), PlotLabel -> p, Ticks -> None], {p, {Bottom, Center, Top}}]

相对于一个气泡的基于坐标的放置：

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, PlotRange -> All, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> (Placed[#, p]&), PlotLabel -> p, Ticks -> None], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

使用 Callout 自动放置标签：

Wolfram Language code:

BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, PlotRange -> All, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> (Callout[Row[#, ","], Automatic]&)]

使用符号位置放置 Callout 标签：

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, PlotRange -> All, BubbleSizes -> {0.2, 0.7}, LabelingFunction -> (Callout[#, p]&)], {p, {Above, Below}}]

控制标签的格式化：

Wolfram Language code:

BubbleChart[{{1, 0, 1}, {0, 1, 2}, {1, 2, 3}}, LabelingFunction -> (Placed[#1, Tooltip, MatrixForm]&), BubbleSizes -> {0.2, 0.7}]

用给定的图表标签作为标签函数的参数：

Wolfram Language code:

bubbleLabel[v : {x_, y_, w_}, level_, {r_, c_}] := Placed[Grid[{{Row[{r[[1]], c[[1]], "Fund"}, " "], SpanFromLeft}, {"Age", x}, {"Return %", y}, {"Market Cap", w}}, Frame -> All, Alignment -> Left], Tooltip]

Wolfram Language code: data = {{{1, 11, 300}, {2, 50, 200}, {3, 20, 300}}, {{6, 20, 300}, {2, 8, 600}, {6, 16, 500}}};

Wolfram Language code:

BubbleChart[data, PlotLabels -> <|"Groups" -> {"Growth", "Value"}, "Elements" -> Placed[{"Small-Cap", "Mid-Cap", "Large-Cap"}, None]|>, LabelingFunction -> bubbleLabel]

LabelingSize (4)

文本标签按自然尺寸显示：

Wolfram Language code:

BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, PlotLabels -> Callout[{"healthfulness", "obstreperous", "spectrogram"}]]

图像标签自动调整：

Wolfram Language code: BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, PlotLabels -> Callout[{[image], [image], [image]}]]

指定文本标签的最大尺寸：

Wolfram Language code:

BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, PlotLabels -> Callout[{"healthfulness", "obstreperous", "spectrogram"}], LabelingSize -> 30]

指定图像标签的最大尺寸：

Wolfram Language code:

BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, PlotLabels -> Callout[{[image], [image], [image]}], LabelingSize -> 20]

按自然尺寸显示图像标签：

Wolfram Language code:

BubbleChart[{{0, 0, 1}, {0.1, 0.8, 2}, {1, 2, 3}}, PlotLabels -> Callout[{[image], [image], [image]}], LabelingSize -> Full]

LabelingTarget (7)

自动放置标签，以最大程度提高可读性：

Wolfram Language code: BubbleChart[IconizedObject[«data»]]

显示所有标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> All]

更紧凑地排布标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> "Dense"]

显示最容易阅读的四分之一标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> 0.25]

只显示与点正交的标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> "Sides"|>]

只显示与点斜对的标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> "Corners"|>]

将标签限制在点的上方或右侧：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> {"Right", "Top"}|>]

允许标签遮挡其他点：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> <|"AllowedOverlaps" -> {"Points"}|>]

允许边框处的标签被裁剪：

Wolfram Language code: BubbleChart[IconizedObject[«data»], LabelingTarget -> <|"AllowLabelClipping" -> True|>]

PerformanceGoal (1)

产生交互式高亮气泡图：

Wolfram Language code: data = RandomReal[1, {3, 6, 3}];

Wolfram Language code: BubbleChart[data, PerformanceGoal -> "Quality"]

不启用交互行为，强调性能：

Wolfram Language code: BubbleChart[data, PerformanceGoal -> "Speed"]

通常非交互图表需要的内存较少：

Wolfram Language code: Table[ByteCount@BubbleChart[data, PerformanceGoal -> p], {p, {"Quality", "Speed"}}]

PlotInteractivity (4)

气泡数量适中时，会自动显示提示条和鼠标悬停效果：

Wolfram Language code: BubbleChart[{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}]

关闭所有互动元素：

Wolfram Language code: BubbleChart[{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}, PlotInteractivity -> False]

输入中提供的互动元素被禁用：

Wolfram Language code: BubbleChart[{{1, 1, 1}, {2, 2, 2}, Tooltip[{3, 3, 3}, "hello"]}, PlotInteractivity -> False]

允许使用提供的互动元素，但禁用自动生成的互动元素：

Wolfram Language code:

BubbleChart[{{1, 1, 1}, {2, 2, 2}, Tooltip[{3, 3, 3}, "hello"]}, PlotInteractivity -> <|"User" -> True, "System" -> False|>]

PlotLabels (9)

默认情况下，径向居中放置标签：

Wolfram Language code: BubbleChart[RandomReal[1, {4, 3}], PlotLabels -> {"a", "b", "c", "d"}]

默认情况下，标签会自动与数据元素或分组相关联：

Wolfram Language code:

{BubbleChart[RandomReal[1, {4, 3}], PlotLabels -> {"c1", "c2", "c3"}], 
	BubbleChart[RandomReal[1, {2, 4, 3}], PlotLabels -> {"r1", "r2", "r3"}]}

专门为数据元素指定标签：

Wolfram Language code: BubbleChart[RandomReal[1, {4, 3, 3}], PlotLabels -> <|"Elements" -> {"c1", "c2", "c3"}|>]

同时标记数据组和元素：

Wolfram Language code: BubbleChart[RandomReal[1, {4, 3, 3}], PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>]

数据中的 Labeled 封装将会放置额外的标签：

Wolfram Language code: data = {{1, 0, 1}, Labeled[{0, 1, 2}, "label", Below], {2, 2, 3}};

Wolfram Language code: BubbleChart[data, PlotLabels -> {"a", "b", "c"}]

用 Placed 控制标签的放置：

Wolfram Language code: data = {{1, 0, 1}, {0, 1, 2}, {2, 2, 3}};

Wolfram Language code:

BubbleChart[data, PlotLabels -> <|"Groups" -> Placed[{"r1", "r2"}, Center], "Elements" -> Placed[{"c1", "c2", "c3"}, Below]|>]

指定放置在气泡以外的符号位置：

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Placed[{"a", "b", "c"}, p], PlotLabel -> p, Ticks -> None], {p, {Below, Above}}]

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Placed[{"a", "b", "c"}, p], PlotLabel -> p, Ticks -> None], {p, {Before, After}}]

给出相对于气泡的坐标：

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Placed[{"aa", "bb", "cc"}, p], PlotLabel -> p], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

将所有标签放置于右上角，并改变标签内的坐标：

Wolfram Language code:

Table[BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Placed[Framed /@ {"aa", "bb", "cc"}, {{1, 1}, p}], Ticks -> None, PlotLabel -> p], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

用 Placed 的第三个参数控制格式：

Wolfram Language code:

BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, BubbleSizes -> {0.3, 0.4}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Rotate[#, 45Degree]&]]

Wolfram Language code:

BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, BubbleSizes -> {0.3, 0.4}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Panel[#, FrameMargins -> 0]&]]

使用超链接标签：

Wolfram Language code:

BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Hyperlink[#, "http://www.wolfram.com"]&]]

旋转标签：

Wolfram Language code: BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Rotate[#, Pi / 4]&]]

用 Callout 连接标签与气泡：

Wolfram Language code: BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, PlotLabels -> Callout[{"c1", "c2", "c3"}]]

用 Placed 放置多个标签：

Wolfram Language code:

BubbleChart[{{1, 0, 1}, {0, 1, 2}, {2, 2, 3}}, BubbleSizes -> {0.4, 0.6}, PlotLabels -> Placed[{{"a", "b", "c"}, {"x", "y", "z"}}, {Top, Bottom}, Framed[#, FrameMargins -> 1, Background -> RGBColor[1, 0.75, 0]]&]]

PlotLegends (7)

为数据元素添加分类图例：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code:

BubbleChart[data, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3"}|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>]

为数据组添加图例：

Wolfram Language code:

BubbleChart[data, PlotLegends -> <|"Groups" -> {"rr1", "rr2"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]

用 Legended 添加其他图例：

Wolfram Language code:

BubbleChart[{{{1, 0, 3}, Legended[Style[{0, 1, 2}, RGBColor[0.93, 0.27, 0.27]], "aa"], {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3"}|>]

用 Legended 指定几个图例：

Wolfram Language code:

BubbleChart[{{1, 0, 3}, Legended[{0, 1, 2}, "aa"], {1, 2, 1}, Legended[{5, 4, 1}, "bb"], {4, 5, 6}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.898695, 0.686452, 0.6785475], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.86116075, 0.930182, 0.758764], RGBColor[0.431296, 0.709773, 0.927077]}|>]

为数据组生成图例：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code:

BubbleChart[data, PlotLegends -> <|"Groups" -> {"Group A", "Group B"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]

未使用的图例标签会被丢弃：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code:

BubbleChart[data, PlotLegends -> <|"Groups" -> {"Group A", "Group B", "Group C"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]

指定数据组和元素的图例：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code:

BubbleChart[data, PlotLegends -> <|"Groups" -> {"Test A", "Test B"}, "Elements" -> {"John", "Mary", "Bob"}|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}, "Groups" -> {EdgeForm[{Opacity[1], RGBColor[0.93, 0.27, 0.27]}], EdgeForm[{Opacity[1], RGBColor[0.4, 0.6, 1]}]}|>]

用 Placed 控制图例的放置：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code:

Table[BubbleChart[data, PlotLegends -> <|"Elements" -> Placed[{"John", "Mary", "Bob"}, pos]|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>], {pos, {Below, Above, Before, After}}]

PlotStyle (10)

给出一组样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {4, 3}], PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1], RGBColor[1, 0.75, 0]}]

指定统一的样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {4, 3}], PlotStyle -> Directive[Opacity[0.7], EdgeForm[Dashed], RGBColor[0.3655821205642109, 0.582006632236133, 0.0357851567943297]]]

指定数据组的颜色：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code: BubbleChart[data, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.4, 0.6, 1]}]

循环使用样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {5, 3}], PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14]}|>]

为每个数据元素指定样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {4, 3}], PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1], RGBColor[1, 0.75, 0]}|>]

为每个数据组指定样式：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code: BubbleChart[data, PlotStyle -> <|"Groups" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14]}|>]

指定基础样式：

Wolfram Language code: BubbleChart[data, PlotStyle -> <|"Base" -> {EdgeForm[Dashed], Opacity[0.7]}|>]

设计数据元素和数据组的样式：

Wolfram Language code:

BubbleChart[data, PlotStyle -> <|"Groups" -> {EdgeForm[Dotted], EdgeForm[Dashed]}, "Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}|>]

当同时为元素和数据组指定样式时，元素的样式可能会覆盖组的样式：

Wolfram Language code: data = {{{1, 0, 3}, {0, 1, 2}, {1, 2, 1}}, {{5, 4, 1}, {4, 5, 6}, {5, 6, 5}}};

Wolfram Language code:

BubbleChart[data, PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}, "Groups" -> {RGBColor[1, 0.75, 0], RGBColor[0.95, 0.43, 0.96]}|>]

PlotStyle 与 Style 一起使用：

Wolfram Language code:

BubbleChart[{{1, 0, 3}, Style[{0, 1, 2}, Opacity[0.1]], {1, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

Wolfram Language code:

BubbleChart[{{1, 0, 3}, Style[{0, 1, 2}, EdgeForm[Dashed]], {1, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

Style 可能会覆盖 PlotStyle 的设置：

Wolfram Language code:

BubbleChart[{{1, 0, 3}, Style[{0, 1, 2}, RGBColor[1, 0.75, 0]], {1, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

可组合使用 ColorFunction 的 PlotStyle 的样式：

Wolfram Language code:

BubbleChart[{{1, 0, 3}, {0, 1, 2}, {2, 2, 1}}, PlotStyle -> EdgeForm /@ {Dashed, Dotted, DotDashed}, ColorFunction -> (Blend[{RGBColor[0.4, 0.6, 1], RGBColor[0.93, 0.27, 0.27]}, #]&)]

ColorFunction 可能会覆盖 PlotStyle 的设置：

Wolfram Language code:

BubbleChart[{{1, 0, 3}, {0, 1, 2}, {2, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}, ColorFunction -> "SolarColors"]

ChartElements 可能会覆盖 PlotStyle 的设置：

Wolfram Language code:

BubbleChart[{{1, 0, 3}, {0, 1, 2}, {2, 2, 1}}, ChartElements -> [image], PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

PlotTheme (2)

使用黑体配色方案中具有简单刻度的主题：

Wolfram Language code: BubbleChart[RandomReal[1, {3, 4, 3}], PlotTheme -> "Web"]

改变图表样式：

Wolfram Language code:

BubbleChart[RandomReal[1, {3, 4, 3}], PlotTheme -> "Web", PlotStyle -> {Hue[0.42, 0.67, 0.75], Hue[0.17, 1, 0.75], Hue[0.05, 0.7, 1]}]

Ticks (6)

将刻度自动放置在每个图表中：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True]

设置 TicksNone 可绘制没有任何刻度线的轴：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> None]

在指定位置放置刻度标记：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{.1, .5, .8}, {.1, .5, .8}}]

使用特定标签在指定位置绘制刻度线：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{.1, a}, {.5, b}, {.8, c}}, {{.1, a}, {.5, b}, {.8, c}}}]

将刻度的长度指定为图形大小的一定比例：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{.1, a, .1}, {.5, b, .1}, {.8, c, .1}}, {{.1, a, .2}, {.5, b, .2}, {.8, c, .2}}}]

在刻度的正负方向上使用不同的尺寸：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{.1, a, {.1, .1}}, {.5, b, {.1, .15}}, {.8, c, {.1, .2}}}, Automatic}]

指定刻度的样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, Ticks -> {{{.04, a, .45, Directive[Thick, RGBColor[0.93, 0.27, 0.27]]}, {.64, b, .35, Directive[RGBColor[0.93, 0.27, 0.27]]}, {.72, c, .1, Directive[Thick, RGBColor[0.4, 0.6, 1]]}}, Automatic}]

TicksStyle (4)

默认情况下，刻度和刻度标签使用与轴相同的样式：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True]

指定整体刻度样式，包括刻度标签：

Wolfram Language code: BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, TicksStyle -> RGBColor[0.93, 0.27, 0.27]]

为每条轴指定刻度样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, TicksStyle -> {Directive[RGBColor[0.93, 0.27, 0.27], Thick], Directive[RGBColor[0.4, 0.6, 1], Thick]}]

对刻度标签和刻度线使用不同的样式：

Wolfram Language code:

BubbleChart[IconizedObject[«data»], Frame -> False, Axes -> True, TicksStyle -> Directive[RGBColor[0.93, 0.27, 0.27], Thick], LabelStyle -> RGBColor[0.4, 0.6, 1]]

应用 (4)

显示非洲国家的人均国内生产总值、贫困比例和人口：

Wolfram Language code:

countries = CountryData["Africa"];
properties = {"PovertyFraction", "GDPPerCapita", "Population"};
data = {#1, Log@QuantityMagnitude@#2, #3}&@@@Table[CountryData[c, p], {c, countries}, {p, properties}];

对更多复杂的工具提示，定义一个标签函数：

Wolfram Language code:

labeler[v_, {r_, c_}, ___] := Placed[Grid[{{Style[countries[[c]], Bold, 12], SpanFromLeft}, {"Poverty", Row[{Round[100v[[1]]], "%"}]}, {"GDP Per Capita", Row[{"$", Round[Exp[v[[2]]]]}]}, {"Population", Row[{NumberForm[v[[3]] 10 ^ -6, {4, 2}], " million"}]}}, Alignment -> Left], Tooltip]

鼠标指向气泡，显示一个国家的数据：

Wolfram Language code:

BubbleChart[data, PlotStyle -> {RGBColor[0.9215686274509803, 0.49411764705882355, 0.43137254901960786], RGBColor[1., 0.7215686274509804, 0.2196078431372549], RGBColor[0.9490196078431372, 0.8627450980392157, 0.43529411764705883], RGBColor[0.6705882352941176, 0.8784313725490196, 0.9372549019607843], RGBColor[0.3176470588235294, 0.6549019607843137, 0.7529411764705882], RGBColor[0.09019607843137255, 0.33725490196078434, 0.49411764705882355], RGBColor[0.5333333333333333, 0.23529411764705882, 0.3058823529411765], RGBColor[0.8941176470588236, 0.7098039215686275, 0.7490196078431373]}, LabelingFunction -> labeler, FrameLabel -> {"Poverty Fraction", "Log GDP Per Capita"}]

用 PieChart 指示输入和输出，显示 G15 国的原油数据：

Wolfram Language code:

countries = CountryData["G15"];
properties = {"OilConsumption", "OilProduction", "OilReserves", "OilExports", "OilImports"};
data = Table[CountryData[c, p], {c, countries}, {p, properties}];

Wolfram Language code:

BubbleChart[data[[All, 1 ;; 3]], ChartElements -> Table[PieChart[d, LabelingFunction -> None], {d, data[[All, 4 ;; 5]]}], BubbleSizes -> {0.05, 0.15}, PlotLabels -> Placed[countries, Tooltip], FrameLabel -> properties[[1 ;; 2]]]

得到日本许多城市的人口、气候和坐标数据：

Wolfram Language code:

data = Table[Tooltip[Flatten@{Reverse@CityData[city, "Coordinates"], CityData[city, "Population"]}, Column[{CityData[city, "Name"], WeatherData[city, "Temperature"] "°C"}]], {city, CityData[{Large, "Japan"}]}];

得到日本地图：

Wolfram Language code: map = Graphics[{LightGray, CountryData["Japan", "Polygon"]}]

鼠标指向气泡，显示城市和气候的数据：

Wolfram Language code:

Show[map, BubbleChart[data, BubbleSizes -> {0.01, 0.15}, PlotStyle -> {RGBColor[0.70135, 0.093019, 0.00140383], RGBColor[0.289647, 0.222614, 0.484169], RGBColor[0.98677, 0.98793, 0.458686], RGBColor[0.42948, 0.524086, 0.719463], RGBColor[0.30808, 0.443137, 0.124895], RGBColor[0.895125, 0.71606, 0.0964523], RGBColor[0.138415, 0.184848, 0.429862], RGBColor[0.882353, 0.0253147, 0.11165], RGBColor[0.895125, 0.870893, 0.632624]}], PlotLabel -> Style["Current Temperature of the Largest Cities in Japan", "Title", 14]]

表示基于三个属性的元素的簇：

Wolfram Language code:

properties = {"Density", "BoilingPoint", "ThermalConductivity"};
elements = Table[ElementData[z], {z, 1, 80}];
data = Table[Table[ElementData[e, p], {p, properties}] -> e, {e, elements}];
clusters = FindClusters[QuantityMagnitude[#[[1]]] -> #[[2]]& /@ data, 10];

根据元素的属性值，将元素分成群：

Wolfram Language code:

tooltipLabel[elem_Entity] := Module[{d, bPt, tc, dat}, {d, bPt, tc} = dat = Table[ElementData[elem, p], {p, properties}];
	Tooltip[dat, Grid[{{elem}, {"Density", d, "kg/SuperscriptBox[m, 3]"}, {"BoilingPoint", bPt, "°C"}, {"ThermalConductivity", tc, "W/mK"}}, Alignment -> Left]]]

鼠标指向气泡，得到元素信息：

Wolfram Language code:

BubbleChart[Table[tooltipLabel /@ d, {d, clusters}], ImageSize -> 400, PlotLegends -> <|"Groups" -> Table[Row[{"Cluster ", i}], {i, Length[clusters]}]|>, PlotStyle -> {RGBColor[0.33725490196078434, 0.403921568627451, 0.6235294117647059], RGBColor[0.08627450980392157, 0.1411764705882353, 0.28627450980392155], RGBColor[0.20784313725490197, 0.23921568627450981, 0.3215686274509804], RGBColor[0.7019607843137254, 0.7450980392156863, 0.8235294117647058], RGBColor[1., 0.8784313725490196, 0.5058823529411764], RGBColor[0.4823529411764706, 0.18823529411764706, 0.03529411764705882], RGBColor[1., 0.4549019607843137, 0.2549019607843137], RGBColor[1., 0.26666666666666666, 0.], RGBColor[0.8588235294117647, 0.00784313725490196, 0.00784313725490196]}, FrameLabel -> properties[[1 ;; 2]]]

属性和关系 (2)

用 BubbleChart3D 获得三维的气泡图：

Wolfram Language code: {BubbleChart[{{3, 4, 4}, {3, 6, 3}, {4, 3, 5}}], BubbleChart3D[{{3, 4, 1, 4}, {3, 6, 1, 3}, {4, 3, 1, 5}}]}

用 SectorChart3D 和 RectangleChart3D 选择可视化：

Wolfram Language code: Table[f[{{3, 4, 4}, {3, 6, 3}, {4, 3, 5}}], {f, {RectangleChart3D, SectorChart3D, BubbleChart}}]

巧妙范例 (2)

绘制数字与数字的平方模 67 的关系图，气泡尺寸逐渐增大：

Wolfram Language code: BubbleChart[Table[{i, Mod[i ^ 2, 67], i}, {i, 300}], BubbleSizes -> {0.01, 0.05}]

图表：

Wolfram Language code:

BubbleChart[RandomReal[1, {80, 3}], Frame -> False, PerformanceGoal -> "Speed", ChartElementFunction -> "FadingRectangle", PlotStyle -> <|"Base" -> EdgeForm[None], "Elements" -> {RGBColor[0.6235294117647059, 0.1450980392156863, 0.12549019607843137], RGBColor[0.6588235294117647, 0.3058823529411765, 0.17254901960784313], RGBColor[0.24313725490196078, 0.11764705882352941, 0.058823529411764705], RGBColor[0.9450980392156862, 0.7529411764705882, 0.6352941176470588], RGBColor[0.8392156862745098, 0.4745098039215686, 0.21176470588235294], RGBColor[0.8274509803921568, 0.7254901960784313, 0.43529411764705883], RGBColor[0.44313725490196076, 0.4980392156862745, 0.5490196078431373], RGBColor[0.24705882352941178, 0.30980392156862746, 0.37254901960784315], RGBColor[0.16862745098039217, 0.23921568627450981, 0.3803921568627451], RGBColor[0.2980392156862745, 0.17647058823529413, 0.19607843137254902]}|>]

Top

	{x_i,y_i,z_i}	纯气泡值
	{Quantity[x_i,u_x],Quantity[y_i,u_y],Quantity[z_i,u_z]}	带有单位的气泡值
	<\|k_xx_i,k_yy_i,k_zz_i\|>	键和气泡值的关联
	w_i[{x_i,y_i,z_i},…]	值为 {x_i,y_i,z_i}、封装为 w_i 的气泡
	form_i->m_i	有元数据 m_i 的扇形

	{e₁,e₂,…}	有封装和无封装的元素列表
	<\|k₁e₁,k₂e₂,…\|>	键和值的关联
	TimeSeries[…],EventSeries[…],TemporalData[…]	时间序列、事件序列和时间数据
	WeightedData[…]	扩展数据集
	w[{e₁,e₂,…},…]	应用到整个数据集中的封装
	w[{data₁,data₁,…},…]	应用到所有数据集中的封装

	{col_x,col_y,col_z}	绘制列 x、y 和 z 的数据
	{{col_x1,col_y1,col_z1},{col_x2,col_y2,col_z2},…}	绘制列的多个集

	Annotation[e,label]	提供一个注解
	Button[e,action]	当点击元素时执行的行为
	Callout[e,label]	显示具有标注标签的元素
	EventHandler[e,…]	对元素定义一个普通的事件处理器
	Hyperlink[e,uri]	元素作为超链接
	Labeled[e,…]	用标签显示元素
	Legended[e,…]	在图例中包含元素的特点
	Mouseover[e,over]	元素显示鼠标指向的形式
	PopupWindow[e,cont]	对元素附上一个弹出窗口
	StatusArea[e,label]	当鼠标指向元素时，显示在状态栏上
	Style[e,opts]	用指定样式显示元素
	Tooltip[e,label]	对元素增加任意工具提示

	Top,Bottom,Left,Right,Center	在气泡图中的坐标
	Above,Below, Before, After	在气泡图外的坐标
	{{b_x,b_y},{l_x,l_y}}	缩放尺度坐标 {l_x,l_y} 到气泡图坐标 {b_x,b_y}

AspectRatio	1	整体高宽比
BubbleScale	"Area"	气泡图使用的特征尺度
BubbleSizes	Automatic	气泡图使用的尺寸范围
ChartElementFunction	Automatic	如何产生气泡的原始图形
ChartElements	Automatic	每个气泡使用的图形
ColorFunction	Automatic	如何对气泡着色
ColorFunctionScaling	True	是否归一化 ColorFunction 的参数
Frame	True	在边界框上绘制的网格线
LabelingFunction	Automatic	如何标注气泡
LabelingSize	Automatic	标注和标签的最大尺寸
LabelingTarget	Automatic	如何确定自动放置的标签的位置
LegendAppearance	Automatic	图例的整体外观
PerformanceGoal	$PerformanceGoal	优化的目标
PlotFit	None	怎样将曲线拟合到气泡
PlotFitElements	Automatic	在气泡图中显示的拟合元素
PlotInteractivity	$PlotInteractivity	是否允许绘制互动元素
PlotLabels	None	气泡的类别标签
PlotLegends	None	数据元素和数据集的图例
PlotStyle	Automatic	气泡的样式
PlotTheme	$PlotTheme	绘图的整体主题
ScalingFunctions	None	如何调整单个坐标
TargetUnits	Automatic	在图中显示的单位

	None	没有图例
	Automatic	自动确定图例
	{lbl₁,lbl₂,…}	用 lbl₁, lbl₂, … 作为图例的标签
	Placed[lspec,…]	指定图例的位置

	{sty₁,sty₂,…}	针对每组数据的一系列样式
	<\|"key"val,…\|>	针对不同层级的数据的样式元素

	"Base"	所有气泡的整体样式
	"Elements"	针对每个组中的元素 y_i 的样式列表
	"Groups"	每个数据组 data_i 的样式列表

BubbleChart

更多信息和选项

所有选项的列表

范例

基本范例 (3)

范围 (32)

数据和封装 (14)

表格数据 (3)

样式和外观 (6)

标签和图例 (9)

选项 (122)

AspectRatio (3)

Axes (3)

AxesLabel (4)

AxesOrigin (2)

AxesStyle (4)

BubbleScale (2)

BubbleSizes (1)

ChartElementFunction (5)

ChartElements (5)

ColorFunction (3)

ColorFunctionScaling (2)

Frame (4)

FrameLabel (4)

FrameStyle (2)

FrameTicks (7)

FrameTicksStyle (3)

ImageSize (7)

LabelingFunction (7)

LabelingSize (4)

LabelingTarget (7)

PerformanceGoal (1)

PlotInteractivity (4)

PlotLabels (9)

PlotLegends (7)

PlotStyle (10)

PlotTheme (2)

Ticks (6)

TicksStyle (4)

应用 (4)

属性和关系 (2)

巧妙范例 (2)

参见

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX