WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ClusteringTree[{e1,e2,…}]

要素 e1, e2, …の階層的クラスタ化から重み付きツリーを構築する．

ClusteringTree[{e1v1,e2v2,…}]

構築されたグラフ内の viで eiを表す．

ClusteringTree[{e1,e2,…}{v1,v2,…}]

構築されたグラフ内の viで eiを表す．

ClusteringTree[label1e1,label2e2…]

構築されたグラフ内でラベル labeliを使って eiを表す．

ClusteringTree[data,h]

h 未満の距離にあるサブクラスタを繋いで，data の階層的クラスタ化から重み付きツリーを構築する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
ClusterDissimilarityFunction  
DistanceFunction  
FeatureExtractor  
ImageSize  
VertexLabelStyle  
関連項目
関連するガイド
履歴
引用書式

ClusteringTree

ClusteringTree[{e1,e2,…}]

要素 e1, e2, …の階層的クラスタ化から重み付きツリーを構築する．

ClusteringTree[{e1v1,e2v2,…}]

構築されたグラフ内の viで eiを表す．

ClusteringTree[{e1,e2,…}{v1,v2,…}]

構築されたグラフ内の viで eiを表す．

ClusteringTree[label1e1,label2e2…]

構築されたグラフ内でラベル labeliを使って eiを表す．

ClusteringTree[data,h]

h 未満の距離にあるサブクラスタを繋いで，data の階層的クラスタ化から重み付きツリーを構築する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (5)

数のリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[{1, 2, 5}]

距離が2未満のクラスタを統一する：

Wolfram Language code: ClusteringTree[{1, 2, 5}, 1.3]

文字列のリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[{"a", "abba", "ababa", "abcdefg"}]

画像のリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[{[image], [image], [image], [image]}]

都市のリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[{Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"Sydney", "NewSouthWales", "Australia"}], Entity["City", {"Boston", "Massachusetts", "UnitedStates"}], Entity["City", {"SanFrancisco", "California", "UnitedStates"}]}]

ブール項目からクラスタ階層を得る：

Wolfram Language code: ClusteringTree[{{False, False}, {True, False}, {True, True}}]

スコープ  (8)

数のリストからクラスタ階層を得る：

Wolfram Language code: g = ClusteringTree[{0.1, 2.2, 3.4, 5.6, 8.9}]

葉のラベルを得る：

Wolfram Language code: AnnotationValue[g, "LeafLabels"]

VertexWeightを見ることで，サブクラスタ間の距離を見る：

Wolfram Language code: AnnotationValue[g, VertexWeight]

根の頂点から葉3.4までの最短経路を求める：

Wolfram Language code: FindShortestPath[g, 1, 7 ]

非同次のデータ集合からクラスタ階層を取り出す：

Wolfram Language code: data = {{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], "brown"}, {RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], "light blue"}, {RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], "blue"}, {RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], "violet"}, {RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], "light blue"}, {RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], "yellow"}, {RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], "light violet"}};
Wolfram Language code: ClusteringTree[data]

これを色のクラスタ階層と比較する：

Wolfram Language code: ClusteringTree[data[[All, 1]]]

ランダムな色のリストを生成する：

Wolfram Language code: data = RandomColor[20]

"Centroid"結合を使ってリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[data, ClusterDissimilarityFunction -> "Centroid"]

Associationから階層的クラスタ化を計算する：

Wolfram Language code: association = <|"Red" -> RGBColor[0.7355420127983632, 0.2464091158003272, 0.1318671396857256], "Blue" -> RGBColor[0.19595271830233885, 0.10998208611256777, 0.5195988419509086], "Pink" -> RGBColor[0.98714064424384, 0.4517971556938676, 0.7345757642205208], "Yellow" -> RGBColor[0.914802573832932, 0.9472567075421043, 0.19573643015491093]|>;
Wolfram Language code: ClusteringTree[association]

上記をそのValuesの階層的クラスタ化と比較する：

Wolfram Language code: ClusteringTree[Values[association]]

上記をそのKeysの階層的クラスタ化と比較する：

Wolfram Language code: ClusteringTree[Keys[association]]

距離が0.4未満のクラスタを結合することでクラスタ階層を得る：

Wolfram Language code: data = RandomColor[20]
Wolfram Language code: ClusteringTree[data, 0.4, ClusterDissimilarityFunction -> "Centroid"]

ClusteringTreeのスタイルとレイアウトを変更する：

Wolfram Language code: data = RandomInteger[{0, 100}, 50];
Wolfram Language code: disk = Graphics[{GrayLevel[.45], Disk[]}]
Wolfram Language code: ClusteringTree[data, VertexSize -> 0.2, VertexShape -> disk]
Wolfram Language code: ClusteringTree[data, GraphLayout -> "RadialEmbedding"]

三次元ベクトルのリストからクラスタ階層を得，対応する要素の合計で葉にラベルを付ける：

Wolfram Language code: r = RandomReal[1, {7, 3}];
Wolfram Language code: g = ClusteringTree[r -> Total /@ r]

上記を各ベクトルの合計のクラスタ階層と比較する：

Wolfram Language code: ClusteringTree[Total /@ r]

整数のリストからクラスタ階層を得る：

Wolfram Language code: data = RandomSample[Range[3, 10], 6];
Wolfram Language code: g = ClusteringTree[data]

頂点ラベルを正多角形に変更する：

Wolfram Language code: labels = Graphics[{Blue, RegularPolygon[#]}, ImageSize -> 20]& /@ data
Wolfram Language code: g = ClusteringTree[data -> labels]

オプション  (9)

ClusterDissimilarityFunction  (1)

ランダムな色のリストを生成する：

Wolfram Language code: data = RandomColor[80]

"Centroid"結合を使ってリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[data, ClusterDissimilarityFunction -> "Centroid"]

"Single"結合を使ってリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[data, ClusterDissimilarityFunction -> "Single"]

異なる"ClusterDissimilarityFunction"を使ってリストからクラスタ階層を得る：

Wolfram Language code: ClusteringTree[data, ClusterDissimilarityFunction -> (Max[#]&)]

DistanceFunction  (1)

ランダムベクトルのリストを生成する：

Wolfram Language code: data = RandomReal[{10, 20}, {10, 2}];

異なるDistanceFunctionを使ってクラスタ階層を得る：

Wolfram Language code: ClusteringTree[data, DistanceFunction -> ManhattanDistance]
Wolfram Language code: ClusteringTree[data, DistanceFunction -> ChessboardDistance]

FeatureExtractor  (1)

絵のリストからクラスタ階層を得る：

Wolfram Language code: flowers = { [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: ClusteringTree[flowers]

別のFeatureExtractorを使って特徴を抽出する：

Wolfram Language code: fe = FeatureExtraction[flowers, "ImageFeatures"]
Wolfram Language code: ClusteringTree[flowers, FeatureExtractor -> fe]

Identity FeatureExtractorを使ってデータを変更しないでおく：

Wolfram Language code: ClusteringTree[flowers, FeatureExtractor -> Identity]

ImageSize  (2)

木全体に明示的な画像サイズを指定する：

Wolfram Language code: ClusteringTree[{1, 2, 5}, ImageSize -> Tiny]

幅と高さを別々に設定すると木の境界ボックスに影響するが，縦横比には影響しない：

Wolfram Language code: ClusteringTree[{1, 2, 5}, ImageSize -> {300, 150}]//Framed

ImageSizeとAspectRatioの両方を明示的に設定する：

Wolfram Language code: ClusteringTree[{1, 2, 5}, ImageSize -> {300, 150}, AspectRatio -> 150 / 300]

VertexLabelStyle  (4)

ラベルサイズをカスタマイズする：

Wolfram Language code: ClusteringTree[{3, 3, 5, 4, 7, 7}, VertexLabelStyle -> Large]

ラベルの色をカスタマイズする：

Wolfram Language code: ClusteringTree[{3, 3, 5, 4, 7, 7}, VertexLabelStyle -> Red]

ラベルのいくつかの側面をカスタマイズする：

Wolfram Language code: ClusteringTree[{3, 3, 5, 4, 7, 7}, VertexLabelStyle -> Directive[Purple, Italic, 40]]

式の中には，画像のようにFontSizeの影響を受けないものがある：

Wolfram Language code: images = {[image], [image], [image], [image]};
Wolfram Language code: ClusteringTree[images, VertexLabelStyle -> Tiny, ImageSize -> Small]

Magnificationを使うとあらゆるタイプの式に影響する：

Wolfram Language code: ClusteringTree[images, VertexLabelStyle -> Directive[Magnification -> .3], ImageSize -> Small]

明示的なラベルを与えることもできる：

Wolfram Language code: labels = ColorConvert[ImageResize[#, {Automatic, 40}], "Grayscale"]& /@ images
Wolfram Language code: ClusteringTree[images -> labels, ImageSize -> Small]
Wolfram Research (2016), ClusteringTree, Wolfram言語関数， https://reference.wolfram.com/language/ref/ClusteringTree.html （2017年に更新）.

テキスト

Wolfram Research (2016), ClusteringTree, Wolfram言語関数， https://reference.wolfram.com/language/ref/ClusteringTree.html （2017年に更新）.

CMS

Wolfram Language. 2016. "ClusteringTree." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/ClusteringTree.html.

APA

Wolfram Language. (2016). ClusteringTree. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ClusteringTree.html

BibTeX

@misc{reference.wolfram_2026_clusteringtree, author="Wolfram Research", title="{ClusteringTree}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/ClusteringTree.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_clusteringtree, organization={Wolfram Research}, title={ClusteringTree}, year={2017}, url={https://reference.wolfram.com/language/ref/ClusteringTree.html}, note=[Accessed: 11-September-2026]}