WOLFRAM

Wolfram 语言与系统参考资料中心

DiscretizeGraphics[g]

将二维或三维图形 g 离散为 MeshRegion.

DiscretizeGraphics[g,patt]

仅离散 g 中与模式 patt 匹配的元素.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
Graphics  
Graphics3D  
选项  
AccuracyGoal  
MaxCellMeasure  
MeshCellHighlight  
Show More Show More
MeshCellLabel  
MeshCellMarker  
MeshCellShapeFunction  
MeshCellStyle  
PlotRange  
PlotTheme  
PrecisionGoal  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DiscretizeGraphics

DiscretizeGraphics[g]

将二维或三维图形 g 离散为 MeshRegion.

DiscretizeGraphics[g,patt]

仅离散 g 中与模式 patt 匹配的元素.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

离散包括 Circle 在内的二维特殊区域：

Wolfram Language code: DiscretizeGraphics[Graphics[{Circle[]}]]

Parallelogram：

Wolfram Language code: DiscretizeGraphics[Graphics[{Parallelogram[{0, 0}, {{1, 1}, {1, 0}}]}]]

离散包括 Cone 在内的三维特殊区域：

Wolfram Language code: DiscretizeGraphics[Graphics3D[{Cone[]}]]

Prism：

Wolfram Language code: DiscretizeGraphics[Graphics3D[{Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]}]]

离散化整个 2D Graphics 场景，其中多个图元被视为并集：

Wolfram Language code: DiscretizeGraphics[[image]]
Wolfram Language code: Area[%]

范围  (16)

Graphics  (9)

离散包括 Circle 的二维特殊区域：

Wolfram Language code: DiscretizeGraphics[Graphics[{Circle[]}]]

Parallelogram：

Wolfram Language code: DiscretizeGraphics[Graphics[{Parallelogram[{0, 0}, {{1, 1}, {1, 0}}]}]]

离散由包括 Point、Line 和 Polygon 的 GraphicsComplex 组成的 Graphics：

Wolfram Language code: v = {{0, 0}, {3, 0}, {3, 3}, {0, 3}};
Wolfram Language code: g = Graphics /@ {GraphicsComplex[v, Point[{1, 2, 3, 4}]], GraphicsComplex[v, Line[{1, 2, 3, 4, 1}]], GraphicsComplex[v, Polygon[{1, 2, 3, 4}]]}
Wolfram Language code: DiscretizeGraphics /@ g

离散由包括 Rectangle、Circle 和 Disk 的 GraphicsComplex 组成的 Graphics：

Wolfram Language code: v = {{0, 0}, {2, 0}, {2, 2}, {0, 2}};
Wolfram Language code: g = Graphics /@ {GraphicsComplex[v, Rectangle /@ {1, 2, 3, 4}], GraphicsComplex[v, Circle /@ {1, 2, 3, 4}], GraphicsComplex[v, Disk /@ {1, 2, 3, 4}]}
Wolfram Language code: DiscretizeGraphics /@ g

仅对匹配某种模式的那些基元进行离散：

Wolfram Language code: g = Graphics[{Brown, Disk[{-1, 0}, 2], LightBlue, Rectangle[{0, -2}, {4, 2}], Red, Point[{6, 1}], Circle[{5, 0}, 2], Line[{{-4, 0}, {8, 0}}]}]
Wolfram Language code: DiscretizeGraphics[g, _Circle | _Rectangle]

离散维数小于 2 的基元：

Wolfram Language code: DiscretizeGraphics[g, x_ /; RegionDimension[x] < 2]

离散 All 基元：

Wolfram Language code: DiscretizeGraphics[g, All]

有界分段线性 Graphics 基元可以被精确表示：

Wolfram Language code: g = Graphics[{Orange, Triangle[{{-1, 1}, {0, 2}, {1, 1}}], Blue, Rectangle[{-1, 0}], Yellow, Simplex[2], Brown, Parallelogram[{2, 0}, {{-1, 0}, {-1, 1}}], Purple, Polygon[{{2, 1}, {4, 0}, {3, 1}, {4, 2}}]}]
Wolfram Language code: DiscretizeGraphics[g]

无界分段线性 Graphics 基元仅能在有限范围内表示：

Wolfram Language code: p = {InfiniteLine[{0, 0}, {1, 1}], HalfLine[{0, 0}, {-1, 1}], HalfPlane[{{1, 0}, {2, 1}}, {1, -1}], ConicHullRegion[{{-1, 0}}, {{-1, -1}, {-1, 1}}]};
Wolfram Language code: g = Graphics[p, PlotRange -> {{-3, 3}, {-1.5, 1.5}}]
Wolfram Language code: DiscretizeGraphics[g]

非线性 Graphics 基元仅能被近似表示：

Wolfram Language code: g = Graphics[{BSplineCurve[{{0, 0}, {1, -1}, {2, -1}, {3, 0}, {4, -2}, {5, 0}}], Circle[{2, 1}]}]
Wolfram Language code: DiscretizeGraphics[g]

涉及 GraphicsComplex 的图形：

Wolfram Language code: v = Table[15{Cos[t], Sin[t]}, {t, 0, 4Pi, 4Pi / 5}];
Wolfram Language code: g = Graphics[GraphicsComplex[v, {Orange, Line[{1, 4, 2, 5, 3, 1}], Polygon[{1, 2, 3, 4, 5}]}]]
Wolfram Language code: DiscretizeGraphics[g]

使用 MaxCellMeasure 控制离散化水平：

Wolfram Language code: g = Graphics[{Disk[{0, 0}], Circle[{1, 0}]}]
Wolfram Language code: Table[DiscretizeGraphics[g, MaxCellMeasure -> {"Length" -> m}], {m, {0.9, 0.6, 0.3}}]

Graphics3D  (7)

离散包括 Cone 的三维特殊区域：

Wolfram Language code: DiscretizeGraphics[Graphics3D[{Cone[]}]]

Prism：

Wolfram Language code: DiscretizeGraphics[Graphics3D[{Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]}]]

离散由包括 Point、Line 和 Polygon 的 GraphicsComplex 组成的 Graphics3D：

Wolfram Language code: v = {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}; i = {{1, 2, 5}, {2, 3, 5}, {3, 4, 5}, {4, 1, 5}};
Wolfram Language code: g = Graphics3D /@ {GraphicsComplex[v, {PointSize@Large, Point[Range@5]}], GraphicsComplex[v, Line[i]], GraphicsComplex[v, Polygon[i]]}
Wolfram Language code: DiscretizeGraphics /@ g

离散整个 Graphics3D 场景，将多个基元当作并集处理：

Wolfram Language code: DiscretizeGraphics[[image]]
Wolfram Language code: Volume[%]

仅对匹配某种模式的那些基元进行离散：

Wolfram Language code: p = {Point[Tuples[{0, 1}, 3]], Table[Line[{{x, -0.5, 0}, {x, -2, 0}}], {x, 2, 6}], Triangle[{{6, 0, 0}, {4.5, 0, 0}, {5, 2, 0}}], Cone[{{3, 1, 0}, {3, 1, 2}}]};
Wolfram Language code: g = Graphics3D[p, Boxed -> False]
Wolfram Language code: DiscretizeGraphics[g, _Line | _Cone]

离散维数小于 2 的基元：

Wolfram Language code: DiscretizeGraphics[g, x_ /; RegionDimension[x] < 2]

离散 All 基元：

Wolfram Language code: DiscretizeGraphics[g, All]

有界分段线性 Graphics3D 基元可以被精确表示：

Wolfram Language code: p = {Point[{-3, 0, 0}], Line[{{-2.5, 0, 0}, {-1.5, 0, 0}}], Triangle[{{-1.2, 0, 0}, {-0.5, 0, 0}, {-1, 1, 0}}], Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}]};
Wolfram Language code: g = Graphics3D[p, Boxed -> False]
Wolfram Language code: DiscretizeGraphics[g]

无界 Graphics3D 基元仅能在有限范围内表示：

Wolfram Language code: p = {InfiniteLine[{0, 0, 0}, {1, 0, 0}], HalfLine[{0, 0, 0}, {0, 0, -1}], InfinitePlane[{0, 0, -2}, {{1, 0, 0}, {0, 1, 0}}], HalfPlane[{{-1 / 2, 0, -2}, {-1 / 2, 1, -2}}, {-1, 0, 1}], ConicHullRegion[{{0, 0, 0}}, {{1, 1, 0}, {0, 1, 1}, {1, 0, 1}}]};
Wolfram Language code: g = Graphics3D[p, Boxed -> False, PlotRange -> {{-3, 3}, {-3, 3}, {-6, 3}}]
Wolfram Language code: DiscretizeGraphics[g]

非线性 Graphics3D 基元仅能被近似表示：

Wolfram Language code: g = Graphics3D[{Cylinder[{{2, 2, 0}, {2, 2, 2}}, 1], Sphere[{3, 3, 1}], BSplineSurface[Table[{i, j, RandomReal[{-1, 0}]}, {i, 5}, {j, 5}]]}]
Wolfram Language code: DiscretizeGraphics[g]

选项  (24)

AccuracyGoal  (1)

确保离散化的边界表示接近边界：

Wolfram Language code: g = Graphics3D[{Cylinder[{{2, 2, 0}, {2, 2, 2}}, 1], Sphere[{3, 3, 1}]}]
Wolfram Language code: {mr2, mr3} = Table[DiscretizeGraphics[g, AccuracyGoal -> n], {n, {2, 3}}]

MaxCellMeasure  (6)

以最大单元面积 0.1 进行离散：

Wolfram Language code: mr = DiscretizeGraphics[Graphics[{Disk[{0, 0}], Circle[{1, 0}]}], MaxCellMeasure -> 0.1]

这给出单元的面积：

Wolfram Language code: AnnotationValue[{mr, 2}, MeshCellMeasure]

以最大单元体积 0.1 进行离散：

Wolfram Language code: g = Graphics3D[{Cylinder[{{2, 2, 0}, {2, 2, 2}}, 1], Sphere[{3, 3, 1}]}]
Wolfram Language code: mr = DiscretizeGraphics[g, MaxCellMeasure -> 0.1]

单元体积的 Histogram：

Wolfram Language code: Histogram[AnnotationValue[{mr, 3}, MeshCellMeasure]]

比较不同长度设定：

Wolfram Language code: g = Graphics[{Circle[{0, 0}], Circle[{1, 0}]}]
Wolfram Language code: Table[DiscretizeGraphics[g, MaxCellMeasure -> {"Length" -> m}], {m, {0.8, 0.1, 0.05}}]

比较不同面积设定：

Wolfram Language code: g = Graphics[{Disk[{0, 0}], Disk[{1, 0}]}]
Wolfram Language code: Table[DiscretizeGraphics[g, MaxCellMeasure -> {"Area" -> m}], {m, {0.4, 0.2, 0.05}}]

比较不同表面面积设定：

Wolfram Language code: g = Graphics3D[{Cylinder[{{2, 2, 0}, {2, 2, 2}}, 1], Sphere[{3, 3, 1}]}]
Wolfram Language code: Table[DiscretizeGraphics[g, MaxCellMeasure -> {"Area" -> m}], {m, {1, 0.1, 0.01}}]

比较不同体积设定：

Wolfram Language code: g = Graphics3D[{Ball[]}]
Wolfram Language code: Table[DiscretizeGraphics[g, MaxCellMeasure -> {"Volume" -> m}], {m, {0.3, 0.01, 0.001}}]

MeshCellHighlight  (2)

MeshCellHighlight 允许你指定 MeshRegion 的部分的突出显示：

Wolfram Language code: DiscretizeGraphics[Graphics[Disk[]], MeshCellHighlight -> {{1, All} -> Red, {0, All} -> Green}]

单个单元可以使用单元索引突出显示：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{{0, 0}, {1, 0}}, {{1, 0}, {2, 0}}}]], MeshCellHighlight -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Green}}]

或者通过单元自身：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{{0, 0}, {1, 0}}, {{1, 0}, {2, 0}}}]], MeshCellHighlight -> {Line[{1, 2}] -> {Thick, Red}, Line[{2, 3}] -> {Dashed, Green}}]

MeshCellLabel  (3)

MeshCellLabel 可用于对 MeshRegion 的部分添加标签：

Wolfram Language code: DiscretizeGraphics[Graphics[Point[{{0, 0}, {1, 0}, {2, 0}}]], MeshCellLabel -> {0 -> "Index"}]

对平行四边形的顶点和边添加标签：

Wolfram Language code: DiscretizeGraphics[Graphics[{Parallelogram[{0, 0}, {{1, 1}, {1, 0}}]}], MeshCellLabel -> {0 -> "Index", 1 -> "Index"}]

单个单元可以使用单元索引添加标签：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{{0, 0}, {1, 0}}, {{1, 0}, {2, 0}}}]], MeshCellLabel -> {{1, 1} -> "x", {1, 2} -> "y"}]

或者通过单元自身：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{{0, 0}, {1, 0}}, {{1, 0}, {2, 0}}}]], MeshCellLabel -> {Line[{1, 2}] -> "x", Line[{2, 3}] -> "y"}]

MeshCellMarker  (1)

MeshCellMarker 可用于将数值赋予 MeshRegion 的部分：

Wolfram Language code: DiscretizeGraphics[Graphics[Point[{{0, 0}, {1, 0}, {2, 0}}]], MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3}]

使用 MeshCellLabel 显示记号：

Wolfram Language code: DiscretizeGraphics[Graphics[Point[{{0, 0}, {1, 0}, {2, 0}}]], MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3}, MeshCellLabel -> {0 -> "Marker"}]

MeshCellShapeFunction  (2)

MeshCellShapeFunction 允许您指定 MeshRegion 的部分的函数：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{0, 0}, {2, 0}, {1, Sqrt[3]}, {0, 0}}]], MeshCellShapeFunction -> {0 -> (Disk[#, .1]&)}]

单个单元可以使用单元索引绘制：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{0, 0}, {2, 0}, {1, Sqrt[3]}, {0, 0}}]], MeshCellShapeFunction -> {{0, 1} -> (Disk[#, .1]&), {0, 2} -> (Disk[#, {.1, .2}]&)}]

或者通过单元自身：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{0, 0}, {2, 0}, {1, Sqrt[3]}, {0, 0}}]], MeshCellShapeFunction -> {Point[1] -> (Disk[#, .1]&), Point[2] -> (Disk[#, {.1, .2}]&)}]

MeshCellStyle  (2)

MeshCellStyle 允许您指定 MeshRegion 的部分的样式：

Wolfram Language code: DiscretizeGraphics[Graphics[Disk[]], MeshCellStyle -> {{1, All} -> Red, {0, All} -> Green}]

单个单元可以使用单元索引突出显示：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{{0, 0}, {1, 0}}, {{1, 0}, {2, 0}}}]], MeshCellStyle -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Green}}]

或者通过单元自身：

Wolfram Language code: DiscretizeGraphics[Graphics[Line[{{{0, 0}, {1, 0}}, {{1, 0}, {2, 0}}}]], MeshCellStyle -> {Line[{1, 2}] -> {Thick, Red}, Line[{2, 3}] -> {Dashed, Green}}]

PlotRange  (4)

Automatic 包括有限区域的整个范围：

Wolfram Language code: g = Graphics[{Triangle[], Circle[{-1, -1}]}];
Wolfram Language code: DiscretizeGraphics[g, PlotRange -> Automatic]

Automatic 包括无限区域的部分范围：

Wolfram Language code: g = Graphics[{HalfLine[{0, 0}, {-1, 1}], HalfPlane[{{1, 0}, {2, 1}}, {1, -1}]}];
Wolfram Language code: DiscretizeGraphics[g, PlotRange -> Automatic]

显式设定被采纳：

Wolfram Language code: g = Graphics[{Disk[{0, 0}], Circle[{1.5, 0}]}, PlotRange -> {{-1, 3}, {-1, 1}}]
Wolfram Language code: DiscretizeGraphics[g]

除非被覆盖：

Wolfram Language code: DiscretizeGraphics[g, PlotRange -> {{0, 3}, {0, 1}}]

聚焦于感兴趣的区域：

Wolfram Language code: g = Graphics[{Circle[], HalfPlane[{{1, 0}, {2, 1}}, {1, -1}]}];
Wolfram Language code: DiscretizeGraphics[g, PlotRange -> {{-3, 3}, {-3, 3}}]

剪切实体基元得到实体基元；否则会暴露出内部：

Wolfram Language code: g = Graphics3D[{Ball[], Sphere[{2, 0, 0}]}]
Wolfram Language code: DiscretizeGraphics[g, PlotRange -> {{-1, 3}, {0.1, 1}, {-2, 2}}]

PlotTheme  (2)

使用具有网格线和图例的主题：

Wolfram Language code: DiscretizeGraphics[Graphics3D[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}]], PlotTheme -> "Detailed"]
Wolfram Language code: DiscretizeGraphics[Graphics[Disk[]], PlotTheme -> "Detailed"]

使用主题绘制线框：

Wolfram Language code: DiscretizeGraphics[Graphics3D[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}]], PlotTheme -> "Lines"]
Wolfram Language code: DiscretizeGraphics[Graphics[Disk[]], PlotTheme -> "Lines"]

PrecisionGoal  (1)

比较每个 PrecisionGoal 设置的结果：

Wolfram Language code: g = Graphics3D[{Cylinder[{{2, 2, 0}, {2, 2, 2}}, 1], Sphere[{3, 3, 1}]}]
Wolfram Language code: {mr2, mr3} = Table[DiscretizeGraphics[g, PrecisionGoal -> n], {n, {1, 3}}]

应用  (4)

通过将曲线转换为几何区域，计算它的长度：

Wolfram Language code: g = KnotData["Trefoil", "KnotDiagram"];
Wolfram Language code: ℛ = DiscretizeGraphics[g]//Quiet
Wolfram Language code: ArcLength[ℛ]

通过将图形转换为几何区域，计算它的表面积：

Wolfram Language code: p = PolyhedronData["Dodecahedron"];
Wolfram Language code: ℛ = DiscretizeGraphics[p]
Wolfram Language code: Area[ℛ]

把 Text 转化为几何区域：

Wolfram Language code: t = Text[Style["π", Bold]]
Wolfram Language code: DiscretizeGraphics[t, _Text, MaxCellMeasure -> 0.1]

将国家多边形转化为几何区域：

Wolfram Language code: DiscretizeGraphics[CountryData["France", "Polygon"]]

属性和关系  (9)

多个基元被解释为并集：

Wolfram Language code: g = Graphics[{Rectangle[], Circle[], Line[{{1, -1}, {-1, 1}}]}]
Wolfram Language code: DiscretizeGraphics[g]

有界线性基元可以被精确离散：

Wolfram Language code: g = Graphics[{Line[{{1, -1}, {-1, 1}}], Triangle[], Rectangle[{-1, -1}, {0, 0}]}]
Wolfram Language code: DiscretizeGraphics[g]

无界线性基元仅能在有限范围内表示：

Wolfram Language code: g = Graphics[{InfiniteLine[{0, 0}, {1, 1}], HalfPlane[{{1, 0}, {2, 1}}, {1, -1}]}, PlotRange -> {{-1.5, 2.75}, {-1.5, 1.5}}]
Wolfram Language code: DiscretizeGraphics[g]

非线性基元仅能被近似离散：

Wolfram Language code: g = Graphics[Table[Circle[{0, 0}, r], {r, {1, 4, 7}}]]
Wolfram Language code: DiscretizeGraphics[g]

使用 BoundaryDiscretizeGraphics 得到 BoundaryMeshRegion 表示：

Wolfram Language code: g = Graphics[{Brown, Disk[{1.5, 1}], Orange, Rectangle[]}]
Wolfram Language code: {br, mr} = {BoundaryDiscretizeGraphics[g], DiscretizeGraphics[g]}
Wolfram Language code: {BoundaryMeshRegionQ[br], MeshRegionQ[mr]}

DiscretizeRegion 可用于离散任何 RegionQ 对象：

Wolfram Language code: DiscretizeRegion[ImplicitRegion[x ^ 2 - y ^ 2 ≤ 1, {{x, -2, 2}, {y, -2, 2}}]]

DiscretizeGraphics 可用于离散 Graphics 和 Graphics3D 对象：

Wolfram Language code: DiscretizeGraphics[Graphics[{BezierCurve[{{0, 1}, {1, 1}, {2, -1}, {5, 1}}], Circle[]}]]

它们都可以离散也是图形基元的特殊区域：

Wolfram Language code: {DiscretizeRegion[Disk[]], DiscretizeGraphics[Disk[]]}

可以使用同时也是几何区域的图形基元，不用离散化：

Wolfram Language code: r = Disk[{0, 0}, 1];
Wolfram Language code: RegionQ[r]

直接计算该区域：

Wolfram Language code: Area[r]

或它的离散化版本：

Wolfram Language code: Area[DiscretizeGraphics[r]]

Rasterize 离散含有 Raster 对象的 Graphics 的任意渲染表达式：

Wolfram Language code: g = Graphics[{Disk[{0, 0}], Circle[{1, 0}]}]
Wolfram Language code: Rasterize[g, RasterSize -> {30, 20}, ImageSize -> 100]

Image 离散 Image 对象的任意渲染表达式：

Wolfram Language code: g = Graphics[{Disk[{0, 0}], Circle[{1, 0}]}]
Wolfram Language code: Image[g, ImageSize -> {30, 20}, Magnification -> 4]
Wolfram Research (2014)，DiscretizeGraphics，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscretizeGraphics.html （更新于 2015 年）.

文本

Wolfram Research (2014)，DiscretizeGraphics，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscretizeGraphics.html （更新于 2015 年）.

CMS

Wolfram 语言. 2014. "DiscretizeGraphics." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/DiscretizeGraphics.html.

APA

Wolfram 语言. (2014). DiscretizeGraphics. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscretizeGraphics.html 年

BibTeX

@misc{reference.wolfram_2026_discretizegraphics, author="Wolfram Research", title="{DiscretizeGraphics}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DiscretizeGraphics.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discretizegraphics, organization={Wolfram Research}, title={DiscretizeGraphics}, year={2015}, url={https://reference.wolfram.com/language/ref/DiscretizeGraphics.html}, note=[Accessed: 06-September-2026]}