FourierTransform
FourierTransform
FourierTransform[f[t],t,ω]
给出 f[t] （变量为 t ）的符号傅里叶变换 F[ω] （变量为 ω ）.
FourierTransform[f[t],t,
]
给出 
处的数值傅里叶变换.
FourierTransform[f[t1,…,tn],{t1,…,tn},{ω1,…,ωn}]
给出 f[t1,…,tn] 的多维傅立叶变换.
更多信息和选项
- 傅立叶变换及其逆变换是一种在时域和频域之间转换的方式.
- 傅立叶变换通常用于将常微分方程和偏微分方程分别简化为代数方程或常微分方程. 它们还广泛应用于控制理论和信号处理领域. 此外，它们在研究量子力学现象、噪声过滤等方面也有应用.
- 时域函数
的傅立叶变换是频域函数 
： - 在缺省情况下，函数
的傅立叶变换的定义为 
. - 函数
的多维傅立叶变换默认定义为 
或向量表示形式 
. - 不同的定义选择可以使用选项 FourierParameters 指定.
- 如果第三个参数
被赋予数值，则积分会通过数值方法计算. - 渐近傅立叶变换可以通过 Asymptotic 方法计算.
- 以下是几种相关的傅立叶变换：
-
FourierTransform 无限连续时间函数 (FT) FourierSequenceTransform 无限离散时间函数 (DTFT) FourierCoefficient 有限连续时间函数 (FS) Fourier 有限离散时间函数 (DFT) - 傅立叶变换是函数在施瓦茨向量空间上的一个自同构，其导数快速降低，因此在其对偶空间（缓和分布空间）中也诱导出一个自同构. 这些空间包括绝对可积函数、多项式增长的良好函数以及紧支撑分布.
- 因此，FourierTransform 不仅可以处理绝对可积函数，还可以处理诸如 DiracDelta 函数等各种缓增分布，从而扩大了它可以有效变换的函数或广义函数的范围.
- 可以给出下列选项：
-
AccuracyGoal Automatic 绝对精度的目标位数 Assumptions $Assumptions 所做的参数假定 FourierParameters {0,1} 定义傅立叶变换的参数 GenerateConditions False 是否生成涉及参数条件的答案 PerformanceGoal $PerformanceGoal 优化的性能方面 PrecisionGoal Automatic 精度的目标位数 WorkingPrecision Automatic 内部计算使用的精度 - 常见的 FourierParameters 设置包括：
-
{0,1} 
默认设置/物理学 {1,-1} 
系统工程/数学 {-1,1} 
经典物理学 {0,-2Pi} 
普通频率 {a,b} 
通用设置 - 在 TraditionalForm 中，FourierTransform 用 ℱ 输出. »
范例
打开所有单元 关闭所有单元基本范例 (6)
FourierTransform[UnitBox[t / 2], t, ω]{Plot[UnitBox[t / 2], {t, -2, 2}, Exclusions -> None], Plot[%, {ω, -10, 10}]}
FourierTransform[DiracDelta[t], t, ω]FourierTransform[DiracDelta[t], t, ω, FourierParameters -> {1, -1}]FourierTransform[E ^ (-t ^ 2), t, ω]{Plot[E ^ (-t ^ 2), {t, -5, 5}, PlotRange -> Full], Plot[%, {ω, -5, 5}, PlotRange -> Full]}FourierTransform[1 / Sqrt[x ^ 2 + y ^ 2], {x, y}, {u, v}]Plot3D[%, {u, -2, 2}, {v, -2, 2}, PlotRange -> {0, 10}, Mesh -> None]FourierTransform[Exp[-t ^ 6] Sin[t ^ 2], t, 0.3]范围 (44)
基本用法 (4)
FourierTransform[HeavisideTheta[t], t, ω]FourierTransform[Sin[α t], t, ω]FourierTransform[Cos[α t], t, ω]
FourierTransform[Exp[-t ^ 2 + t], t, 0.3]TraditionalForm 格式：
FourierTransform[f[t], t, ω]//TraditionalForm初等函数 (8)
FourierTransform[t ^ 2, t, ω]FourierTransform[3t ^ 2 + 5t - 7, t, ω]FourierTransform[1 / (1 + t ^ 2), t, ω]Plot[%, {ω, -5, 5}]FourierTransform[t / (1 + t ^ 3), t, ω]ReImPlot[%, {ω, -4, 4}]FourierTransform[1 / Sqrt[Abs[t]], t, ω]Plot[%, {ω, -5, 5}]FourierTransform[Cos[t] ^ 2, t, ω]FourierTransform[Exp[α t] Sin[ β t], t, ω]FourierTransform[Exp[-t ^ 2] Sin[t], t, ω]FourierTransform[(1/2α)(Sin[α t] + α t Cos[α t]), t, ω]FourierTransform[Sin[t] + Cos[t], t, ω]FourierTransform[(Sin[3 t]/t), t, ω]Plot[%, {ω, -5, 5}, Exclusions -> None]FourierTransform[Sin[t ^ 2], t, ω]Plot[%, {ω, -5, 5}]FourierTransform[Log[Abs[t]], t, ω]Plot[%, {ω, -5, 5}]特殊函数 (5)
Sinc 函数：
FourierTransform[Sinc[t], t, ω]Plot[%, {ω, -5, 5}, Exclusions -> None]FourierTransform[BesselJ[2, t], t, ω]Plot[%, {ω, -5, 5}]SinIntegral 函数：
FourierTransform[SinIntegral[t], t, ω, Assumptions -> -1 < ω < 1]FourierTransform[LaguerreL[5, t], t, ω]FourierTransform[AiryAi[t], t, ω]
Plot3D[Abs[%] /. ω -> a + b I, {a, -5, 5}, {b, -5, 5}]分段函数和分布 (7)
f[t_] = Piecewise[{{t, 0 ≤ t ≤ 1}, {1, t > 1}}];
Plot[f[t], {t, 0, 3}]FourierTransform[f[t], t, ω]使用 Sign 函数求绝对值：
f[t_] = t Sign[t];
Plot[f[t], {t, -2, 2}]FourierTransform[f[t], t, ω]Plot[Sin[α t]UnitBox[α t / π] /. α -> π, {t, -1, 1}]Simplify[FourierTransform[Sin[α t]UnitBox[α t / π], t, ω], α > 0]f[t_] = Piecewise[{{t, 0 ≤ t ≤ 1}, {2 - t, 1 < t ≤ 2}, {0, 2 < t }}];
Plot[f[t], {t, 0, 4}]FourierTransform[f[t], t, ω]Ramp：
FourierTransform[Ramp[t - α], t, ω]FourierTransform[UnitStep[t - α], t, ω]UnitStep 函数与余弦函数的乘积：
FourierTransform[UnitStep[t - π]Cos[t - π], t, ω]GraphicsRow[{Plot[Abs[%], {ω, -5, 5}, ...], Plot[Arg[%], {ω, -5, 5}, ...]}]周期函数 (5)
SquareWave 的傅立叶变换：
Plot[SquareWave[t], {t, 0, 4}, Exclusions -> None]FourierTransform[SquareWave[t], t, ω]Plot[TriangleWave[t], {t, 0, 4}]FourierTransform[TriangleWave[t], t, ω]Plot[SawtoothWave[t], {t, 0, 6}, Exclusions -> None]FourierTransform[SawtoothWave[t], t, ω]
Plot[RealAbs[Sin[t]], {t, -2π, 2π}]FourierTransform[RealAbs[Sin[t]], t, ω]f[t_] = Piecewise[{{Sin[t], 0 ≤ Mod[(t/π), 2] ≤ 1}, {0, 1 < Mod[(t/π), 2] < 2}}];
Plot[f[t], {t, 0, 10}]FourierTransform[f[t], t, ω]广义函数 (5)
涉及 HeavisideTheta 的傅立叶变换：
FourierTransform[HeavisideTheta[t], t, ω]FourierTransform[HeavisideTheta[t] HeavisideTheta[1 - t], t, ω]GraphicsRow[{Plot[Abs[%], {ω, -10, 10}, ...], Plot[Arg[%], {ω, -10, 10}, ...]}]FourierTransform[DiracDelta[t], t, ω]DiracDelta 的导数：
FourierTransform[DiracDelta'[t], t, ω]Plot[HeavisideLambda[t - 1], {t, 0, 4}]FourierTransform[HeavisideLambda[t - 1], t, ω]Plot[HeavisidePi[t - (3/2)], {t, 0, 3}, Exclusions -> None]FourierTransform[HeavisidePi[t - (3/2)], t, ω]多元函数 (5)
FourierTransform[1, {x, y}, {u, v}]FourierTransform[Exp[α x + β y], {x, y}, {u, v}]FourierTransform[Cos[x + y + z], {x, y, z}, {u, v, w}]FourierTransform[(x y z) ^ 3 Exp[-(x ^ 2 + y ^ 2 + z ^ 2)], {x, y, z}, {u, v, w}]指数函数与 SquareWave 函数乘积的傅立叶变换：
Plot3D[E ^ (-Abs[x])SquareWave[y / (2π)], {x, -2π, 2π}, {y, -2π, 2π}, PlotRange -> All, Mesh -> None]FourierTransform[E ^ (-Abs[x]) SquareWave[y / (2 Pi)], {x, y}, {u, v}]形式性质 (3)
选项 (6)
AccuracyGoal (1)
选项 AccuracyGoal 设置精度的位数：
exact = FourierTransform[HeavisideLambda[t - 1], t, -9 / 10]FourierTransform[HeavisideLambda[t - 1], t, -.9, AccuracyGoal -> 5] - exactFourierTransform[HeavisideLambda[t - 1], t, -.9] - exactAssumptions (1)
使用 Assumptions 指定变量的范围：
FourierTransform[BesselJ[3, t], t, ω, Assumptions -> -1 < ω < 1 ]FourierTransform[BesselJ[3, t], t, ω, Assumptions -> ω > 1 ]FourierTransform[BesselJ[3, t], t, ω, Assumptions -> ω < -1 ]FourierParameters (1)
params = {{0, 1}, {1, 1}, {-1, 1}, {0, 2 π}};
funs = funs = Table[FourierTransform[UnitBox[t - (1/2)], t, ω, FourierParameters -> p], {p, params}]header = { "Parameters", HoldForm@FourierTransform[UnitBox[t - (1/2)], t, ω]};
Grid[Prepend[Transpose[{params, funs}], header], IconizedObject[«Grid options»]]//TraditionalFormGenerateConditions (1)
使用 GenerateConditionsTrue 获取结果有效时的参数条件：
FourierTransform[E ^ (-α t ^ 2), t, ω, GenerateConditions -> True]PrecisionGoal (1)
选项 PrecisionGoal 设置积分的相对误差：
exact = FourierTransform[8 / (t ^ 2 + 1), t, 1 / 2]FourierTransform[8 / (t ^ 2 + 1), t, .5, PrecisionGoal -> 15] - exactFourierTransform[8 / (t ^ 2 + 1), t, .5] - exactWorkingPrecision (1)
如果指定了 WorkingPrecision，则计算按该工作精度进行：
exact = FourierTransform[8 / (t ^ 2 + 1), t, 1 / 2]FourierTransform[8 / (t ^ 2 + 1), t, .5, WorkingPrecision -> 18] - exactFourierTransform[8 / (t ^ 2 + 1), t, .5] - exact应用 (11)
信号与系统 (3)
h[t_] := UnitStep[t + 1 / 2] - UnitStep[t - 1 / 2];
x[t_] := Cos[π t];FourierTransform[h[t], t, ω, FourierParameters -> {1, -1}] * FourierTransform[x[t], t, ω, FourierParameters -> {1, -1}]InverseFourierTransform[%, ω, t, FourierParameters -> {1, -1}]与 Convolve 比较：
Convolve[h[τ], x[τ], τ, t]Plot[UnitTriangle[ω], {ω, -1.2, 1.2}]
FourierTransform[Cos[2 t], t, ω, FourierParameters -> {1, -1}]
1 / 2π Convolve[UnitTriangle[t], % /. ω -> t, t, ω]Plot[%, {ω, -5, 5}]eqn = y'[t] + y[t] == x'[t];FourierTransform[eqn, t, ω]
Solve[%, FourierTransform[y[t], t, ω]]LTI 系统的频率响应是输出函数 
与输入函数 
的傅立叶变换之比：
%[[1]][[1, 2]] / FourierTransform[x[t], t, ω]常微分方程 (1)
eqn = y'[t] + y[t] == Sin[t];FourierTransform[eqn, t, ω]SolveValues[%, FourierTransform[y[t], t, ω]]InverseFourierTransform[%[[1]], ω, t]与 DSolveValue 比较：
DSolveValue[{eqn, y[0] == -1 / 2}, y[t], t]偏微分方程 (1)
eqn = D[u[x, t], t] == α ^ 2 D[u[x, t], x, x];
FourierTransform[eqn, x, ω]
DSolveValue[{D[u1[ω, t], t] == -α^2 ω^2 u1[ω, t], u1[ω, 0] == Subscript[ω, 0]}, u1[ω, t], t]InverseFourierTransform[1 / Sqrt[2 π]E ^ (-ω ^ 2α ^ 2t), ω, x]Convolve[(E^-(x^2/4 t α^2)/2 Sqrt[π] Sqrt[t α^2]) /. x -> y, u[y, 0], y, x]
% /. {u[y, 0] -> UnitBox[y], α -> 1}与 DSolveValue 比较：
DSolveValue[{eqn /. {α -> 1}, {u[x, 0] == UnitBox[x]}}, u[x, t], {x, t}]
Plot[{UnitBox[x], Evaluate@Table[%, {t, {.005, .1, .3, .8}}]}, {x, -3, 3}, PlotLegends -> {UnitBox[x], .005, .1, .3, .8}, Exclusions -> None]
Plot3D[Evaluate[(1/2) (Erf[(1 - 2 x/4 Sqrt[t])] + Erf[(1 + 2 x/4 Sqrt[t])])], {x, -2, 2}, {t, 0, 1}, ...]积分计算 (1)
Inactive[Integrate][(u Cos[t u]/1 + u^2), {u, 0, ∞}]
Inactive[Integrate][FourierTransform[(u Cos[t u]/1 + u^2), t, ω], {u, 0, ∞}]
Activate[%]FullSimplify[InverseFourierTransform[%, ω, t], Assumptions -> t > 0]与 Integrate 比较：
Integrate[(u Cos[t u]/1 + u^2), {u, 0, ∞}, Assumptions -> t > 0]其它应用 (5)
FourierTransform[Sin[10 ^ 3 t]Exp[-t / 10]UnitStep[t], t, ω]LogLogPlot[Evaluate@Abs[%], {ω, 1*^-1, 1*^5}, PlotRange -> All]平面中径向对称函数的傅立叶变换可以表示为汉克尔变换. 验证由下面定义的函数的这种关系：
f[x_, y_] := (x ^ 2 + y ^ 2) E ^ (-Sqrt[x ^ 2 + y ^ 2])Plot3D[f[x, y], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, Mesh -> False]FourierTransform[f[x, y], {x, y}, {u, v}]用 HankelTransform 得到同样的结果：
HankelTransform[f[x, y] /. {x -> r Cos[m], y -> r Sin[m]}//Simplify, r, s] /. {s -> Sqrt[u^2 + v^2]}Plot3D[%, {u, -3, 3}, {v, -3, 3}, PlotRange -> All, Mesh -> False]flist = {(1/Sqrt[r^2 + 1]), (Cos[2 π r]/r), (1/r), E^-r, BesselJ[0, r]^2, E^-r^2};tlist = FullSimplify[HankelTransform[flist, r, s], Assumptions -> 0 < s < 2](Grid[#1, Alignment -> {{Right, {Left}}, Center}, Spacings -> 0]&)[Table[{...}, {i, 6}]]计算平稳 OrnsteinUhlenbeckProcess 的功率谱：
FourierTransform[CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h], h, ω, FourierParameters -> {1, 1}, Assumptions -> θ > 0]考虑一个固定面积的盒框函数作为粒子的位置空间波函数. 它的傅立叶变换给出粒子的动量空间波函数：
Simplify[FourierTransform[1 / Sqrt[2α]UnitBox[x / (2α)], x, k, Assumptions -> α∈PositiveIntegers], α∈PositiveIntegers]当 
较小时，固定面积盒框的高度较大，粒子的位置几乎可以确定. 动量空间波函数在其两个最接近零的根之间的值约为 
，这使得几乎无法确定其动量. 同样地，反之亦然，如下所示：
Manipulate[GraphicsRow[{Plot[1 / Sqrt[2α]UnitBox[x / (2α)], {x, -6.1, 6.1}, ...], Plot[...]}], ...]属性和关系 (6)
HoldForm[FourierTransform[f[t], t, ω] = HoldForm[1 / Sqrt[2π]] * Integrate[f[t]E ^ (I ω t), {t, -∞, ∞}]]//TraditionalForm
1 / Sqrt[2π]Integrate[Exp[-t ^ 2]Cos[t]Exp[I ω t], {t, -∞, ∞}]//FullSimplify与 FourierTransform 比较：
FourierTransform[Exp[-t ^ 2]Cos[t], t, ω]//TrigToExp//Factor//Simplify用 Asymptotic 计算渐近逼近：
Asymptotic[Inactive[FourierTransform][E ^ (-t ^ 2 - t ^ 4), t, x], x -> 0]FourierTransform 和 InverseFourierTransform 是互逆的：
InverseFourierTransform[FourierTransform[f[t], t, ω], ω, t]FourierTransform[InverseFourierTransform[G[ ω], ω, t], t, ω]FourierTransform[1 / (t ^ 2 + 1), t, ω]InverseFourierTransform[%, ω, t]对奇函数，FourierTransform 和 FourierCosTransform 是相等的：
FourierTransform[Exp[-t ^ 2], t, ω]FourierCosTransform[Exp[-t ^ 2], t, ω ]对偶函数，FourierTransform 和 FourierSinTransform 的差异为 ：
FourierSinTransform[t Exp[-Abs[t]], t, ω]FourierTransform[t Exp[-Abs[t]], t, ω]可能存在的问题 (1)
巧妙范例 (2)
加权的 Hermite 多项式的傅立叶变换有非常简单的形式：
FourierTransform[Exp[-t ^ 2]HermiteH[10, t], t, ω]InverseFourierTransform[%, ω, t]//Factorflist = {t ^ n, E ^ (a t), E ^ (-a t), Exp[-t ^ 2], Sin[a t], t Sin[a t], Sinc[t], DiracDelta[t - a], Log[Abs[t]], UnitStep[t], UnitBox[t], BesselJ[2, a t], BesselY[0, Abs[t]]};Grid[Prepend[{#, Assuming[{a > 0}, Simplify[FourierTransform[#1, t, ω]]]}& /@ flist, {f[t], FourierTransform[f[t], t, ω]}], IconizedObject[«Grid options»]]//TraditionalForm相关链接
MathWorld
Wolfram Research (1999)，FourierTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FourierTransform.html （更新于 2025 年）.
文本
Wolfram Research (1999)，FourierTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FourierTransform.html （更新于 2025 年）.
CMS
Wolfram 语言. 1999. "FourierTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/FourierTransform.html.
APA
Wolfram 语言. (1999). FourierTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FourierTransform.html 年