WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

StreamDensityPlot[{{vx,vy},r},{x,xmin,xmax},{y,ymin,ymax}]

ベクトル場{vx,vy}の流線プロットをスカラー場 r の背景濃度のプロットに重ね合された x と y の関数として生成する．

StreamDensityPlot[{vx,vy},{x,xmin,xmax},{y,ymin,ymax}]

スカラー場がベクトル場のノルムであるとする．

StreamDensityPlot[{{vx,vy},{wx,wy},…,r},{x,xmin,xmax},{y,ymin,ymax}]

複数のベクトル場のプロットを生成する．

StreamDensityPlot[…,{x,y}∈reg]

変数{x,y}が，幾何学領域 reg にあるものと解釈する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
サンプリング  
プレゼンテーション  
オプション  
Background  
BoundaryStyle  
ColorFunction  
Show More Show More
ColorFunctionScaling  
EvaluationMonitor  
MaxRecursion  
Mesh  
MeshFunctions  
MeshShading  
MeshStyle  
NormalsFunction  
PerformanceGoal  
PlotLegends  
PlotRange  
PlotTheme  
RegionFunction  
StreamColorFunction  
StreamColorFunctionScaling  
StreamMarkers  
StreamPoints  
StreamScale  
StreamStyle  
アプリケーション  
特性と関係  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

StreamDensityPlot

StreamDensityPlot[{{vx,vy},r},{x,xmin,xmax},{y,ymin,ymax}]

ベクトル場{vx,vy}の流線プロットをスカラー場 r の背景濃度のプロットに重ね合された x と y の関数として生成する．

StreamDensityPlot[{vx,vy},{x,xmin,xmax},{y,ymin,ymax}]

スカラー場がベクトル場のノルムであるとする．

StreamDensityPlot[{{vx,vy},{wx,wy},…,r},{x,xmin,xmax},{y,ymin,ymax}]

複数のベクトル場のプロットを生成する．

StreamDensityPlot[…,{x,y}∈reg]

変数{x,y}が，幾何学領域 reg にあるものと解釈する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (4)

場の強度に基づいた背景でベクトル場の流線をプロットする：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]

スカラー場の凡例を加える：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]

場の強度の対数に基づいた背景でベクトル場の流線をプロットする：

Wolfram Language code: StreamDensityPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, Log[Norm[{-1 - x ^ 2 + y, 1 + x - y ^ 2}] + 1]}, {x, -3, 3}, {y, -3, 3}]

最初の場の強度に基づいた背景で2つの場の流線をプロットする：

Wolfram Language code: StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}]

スコープ  (24)

サンプリング  (11)

に基づいた背景でベクトル場の流線を可視化する：

Wolfram Language code: StreamDensityPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, Cos[x]}, {x, -3, 3}, {y, -3, 3}]

2つのベクトル場の流線を，最初のベクトル場の強度に基づいた背景色でプロットする：

Wolfram Language code: StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}]

Evaluateを使って，数値割当ての前にベクトル場を記号的に評価する：

Wolfram Language code: StreamDensityPlot[Evaluate[D[Sin[x y], {{x, y}}]], {x, 0, 1}, {y, 0, 1}]

流線を任意の密度で置いて，ベクトル場をプロットする：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> None, PlotLabel -> p, StreamPoints -> p], {p, {Coarse, Medium, Automatic, Fine}}]

一連のシード点を通る流線をプロットする：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> Tuples[{-2, 0, 2}, 2], Epilog -> Point[Tuples[{-2, 0, 2}, 2]]]

明示的にシードされた流線のスタイルに自動的なシードと明示的なシードの両方を使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamPoints -> {{{{1, 0}, Red}, {{-1, -1}, Green}, Automatic}}]

指定領域の上で流線をプロットする：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, x y < 0]]

指定の数のメッシュラインを使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5]

メッシュラインを指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{2, 4, 5}}]

領域は別の領域で指定することができる：

Wolfram Language code: StreamDensityPlot[{{y, -x}, x + y}, {x, y}∈Disk[]]

領域はMeshRegionで指定することができる：

Wolfram Language code: 𝒟 = MeshRegion[{{0, 0}, {5, -2}, {3, 0}, {5, 2}}, Polygon[{1, 2, 3, 4}]];
Wolfram Language code: StreamDensityPlot[{{Sin[x], Cos[y]}, x^2 + y^2}, {x, y}∈𝒟]

プレゼンテーション  (13)

StreamScaleの設定で異なる破線と鏃を指定する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> ToString@s, StreamScale -> s], {s, {Automatic, None, 0.2, Full}}]

背景のスカラー場を色関数で彩色する：

Wolfram Language code: v = {-1 - x ^ 2 + y, 1 + x - y ^ 2}; s = Exp[Norm[v] / 10];
Wolfram Language code: Table[StreamDensityPlot[f, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"], {f, {v, {v, s}}}]

場の強度が反映されるように流線の色関数を変える：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Hue]

さまざまな流線のスタイルを適用する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> s], {s, {"Toothpick", "Dart", Dashed, Arrowheads[{{0.03, Automatic, Graphics[Circle[]]}}]}}]

プロットに異なるテーマを使う：

Wolfram Language code: {StreamDensityPlot[{x, y}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Detailed"], StreamDensityPlot[{x, y}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Monochrome"]}

名前付きの外観を使って流線を描く：

Wolfram Language code: StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop"]

流線にもスタイルを付ける：

Wolfram Language code: StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop", StreamStyle -> Blue, StreamColorFunction -> None]

異なるスタイルのメッシュラインを指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{{2, Thick}, {4, Green}, {5, {Thick, Red, Dashed}}}}]

大域的メッシュラインスタイルを指定する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshStyle -> s], {s, {Red, Thick, Directive[Red, Dashed]}}]

メッシュ領域に循環的に陰影付けする：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, Yellow, Green, None}]

領域の境界にさまざまなスタイルを適用する：

Wolfram Language code: regionFn = Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2];
Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn, BoundaryStyle -> b], {b, {Red, Thick, Directive[Red, Dashed]}}]

スカラー場の凡例を含む：

Wolfram Language code: StreamDensityPlot[{x, y^2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]

流線の凡例を含む：

Wolfram Language code: StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, PlotLegends -> LineLegend[97, {"one", "two"}]]

下に向けて数が大きくなるように y スケールを逆にする：

Wolfram Language code: StreamDensityPlot[{x, y}, {x, 1, 100}, {y, 1, 100}, ScalingFunctions -> {None, "Reverse"}]

オプション  (85)

Background  (1)

色付きの背景を使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Background -> LightGreen]

BoundaryStyle  (2)

デフォルトで，領域の境界にはスタイルがない：

Wolfram Language code: StreamDensityPlot[{Sin[x + y], Cos[y - x]}, {x, -3, 3}, {y, -3, 3}]

領域のスタイルを変更する：

Wolfram Language code: StreamDensityPlot[{Sin[x + y], Cos[y - x]}, {x, -3, 3}, {y, -3, 3}, BoundaryStyle -> Directive[Thick, Purple]]

ColorFunction  (6)

Hueを使って場の強度に彩色する：

Wolfram Language code: StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> Hue]

に基づいてHueを使って彩色する：

Wolfram Language code: StreamDensityPlot[{{y, -x}, Sin[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 2, ColorFunction -> Hue]

ColorDataから任意の名前付き色階調度を使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"]

定義済みの色階調度にColorDataを使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> Function[{x, y, vx, vy, n}, ColorData["SolarColors"][x y]]]

座標によって2色を混ぜ合せる色関数を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> Function[{x, y, vx, vy, n}, Blend[{Green, Red}, x]]]

ColorFunctionScaling->Falseを使ってスケールされていない値を得る：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 4, ColorFunctionScaling -> False, ColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]

ColorFunctionScaling  (4)

デフォルトで，スケールされた値が使われる：

Wolfram Language code: StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 2, ColorFunction -> GrayLevel]

ColorFunctionScaling->Falseを使ってスケールされていない値を得る：

Wolfram Language code: StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 4, ColorFunctionScaling -> False, ColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]

方向にスケールされていない座標を， 方向にはスケールされた座標を使う：

Wolfram Language code: StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, ColorFunctionScaling -> {False, True}, ColorFunction -> Function[{x, y, vx, vy, n}, Hue[x, y, 1]]]

各色関数引数のスケールを明示的に指定する：

Wolfram Language code: StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 3, ColorFunctionScaling -> {True, True, True, True, False}, ColorFunction -> Function[{x, y, vx, vy, n}, Hue[n, y, 1]]]

EvaluationMonitor  (2)

ベクトル場関数がサンプルとして取られたところを示す：

Wolfram Language code: ListPlot[Reap[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, EvaluationMonitor :> Sow[{x, y}]]][[-1, 1]]]

ベクトル場関数が評価された回数を数える：

Wolfram Language code: Block[{k = 0}, StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, EvaluationMonitor :> k++];k]

MaxRecursion  (1)

変化の急減なところでプロットを精緻化する：

Wolfram Language code: Table[StreamDensityPlot[{{y, -x}, Sin[x y]}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> r, ColorFunction -> Hue, MaxRecursion -> r], {r, 0, 2}]

Mesh  (5)

デフォルトではメッシュラインは表示されない：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> None]

最終的なサンプルメッシュを示す：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]

特定の数のメッシュラインを使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5]

メッシュラインを指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{2, 4, 5}}]

異なるメッシュラインに異なるスタイルを使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{{2, Thick}, {4, Yellow}, {5, {Thick, Red, Dashed}}}}]

MeshFunctions  (3)

デフォルトで，メッシュラインは場の強度に対応する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, n], Mesh -> 5]

の値をメッシュ関数として使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, x], Mesh -> 5]

原点から一定の離にあるメッシュラインを使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, Sqrt[x ^ 2 + y ^ 2]], Mesh -> 5]

MeshShading  (3)

Noneを使って領域を削除する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, None}]

スタイルは循環的に用いられる：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, Yellow, Green, None}]

ColorDataからの指標付きの色を循環的に使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> ColorData[51, "ColorList"]]

MeshStyle  (1)

メッシュラインにさまざまなスタイルを適用する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshStyle -> s], {s, {Red, Thick, Directive[Red, Dashed]}}]

NormalsFunction  (2)

陰影付けに法線を用いない：

Wolfram Language code: StreamDensityPlot[{Cos[x ^ 2 + y], 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, LightingAngle -> Pi / 4, NormalsFunction -> None]

有効な法線をランダムに変化させる：

Wolfram Language code: StreamDensityPlot[{Cos[x ^ 2 + y], 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, LightingAngle -> Pi / 4, NormalsFunction -> Function[{x, y, vx, vy, n}, RandomReal[{0, 1}, {3}]]]

PerformanceGoal  (2)

高品質プロットを生成する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PerformanceGoal -> "Quality"]

たとえ品質を犠牲にしてもパフォーマンスを向上させる：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PerformanceGoal -> "Speed"]

PlotLegends  (4)

デフォルトでは凡例は含まれない：

Wolfram Language code: StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}]

スカラー場の凡例を加える：

Wolfram Language code: StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]

流線の凡例を加える：

Wolfram Language code: StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, PlotLegends -> {None, {"one", "two"}}]

凡例の置き方を制御する：

Wolfram Language code: StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Placed[Automatic, Below]]

PlotRange  (7)

デフォルトではプロット範囲全体が使われる：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> Full]

と の両方の範囲に明示的な限界を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> 2]

明示的な の範囲を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{-1, 2}, Automatic}]

明示的な の最小範囲を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{0, Full}, Automatic}]

明示的な の範囲を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {Full, {0, 2}}]

明示的な の最大範囲を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {Full, {Full, 5}}]

と に別々の範囲を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{-2, 1.5}, {-1, 2}}]

PlotTheme  (2)

白黒のテーマを使う：

Wolfram Language code: StreamDensityPlot[{x, y}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Monochrome"]

流線スタイルを変える：

Wolfram Language code: StreamDensityPlot[{x, y}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Monochrome", StreamStyle -> White]

RegionFunction  (3)

特定の象限のみで流線をプロットする：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, x y < 0]]

場の強度が指定された閾値を超えている領域のみで流線をプロットする：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, n < 6]]

条件の任意の論理結合を使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2]]

StreamColorFunction  (6)

ベクトル場のノルムに従って流線に色付けする：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Hue]

異なるスカラー場に従って流線に色付けする：

Wolfram Language code: StreamDensityPlot[{{Sin[x], Cos[y]}, x}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Hue]

ColorDataから任意の名前付き色階調度を使う：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> "Rainbow"]

定義済みの色階調度にColorDataを使う：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData["RedGreenSplit"][x y]]]

座標によって2色を混ぜ合せる色関数を指定する：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Blend[{Green, Red}, x]]]

StreamColorFunctionScaling->Falseを使ってスケールされていない値を得る：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunctionScaling -> False, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]

StreamColorFunctionScaling  (4)

デフォルトで，スケールされた値が使われる：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> GrayLevel]

StreamColorFunctionScaling->Falseを使ってスケールされていない値を得る：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunctionScaling -> False, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]

方向にスケールされていない座標を， 方向にはスケールされた座標を使う：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Hue[x, y, 1]], StreamColorFunctionScaling -> {False, True}]

各色関数引数のスケールを明示的に指定する：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Hue[n, y, 1]], StreamColorFunctionScaling -> {True, True, True, True, False}]

StreamMarkers  (7)

デフォルトで，流線は矢印として描かれる：

Wolfram Language code: StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}]

名前付きの外観を使って流線を描く：

Wolfram Language code: StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop"]

異なるベクトル場に異なるマーカーを使う：

Wolfram Language code: StreamDensityPlot[{{y, -x}, {x, y}}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> {"Drop", "Dart"}]

名前付きの矢印スタイル：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.05}, StreamMarkers -> s], {s, {"Arrow", "ArrowArrow", "CircleArrow"}}]

名前付きのドットスタイル：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"BarDot", "Dot", "DotArrow", "DotDot"}}]

名前付きのポインタスタイル：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"Drop", "BackwardPointer", "Pointer", "Toothpick"}}]

名前付きのダーツスタイル：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"Dart", "PinDart", "DoubleDart"}}]

StreamPoints  (6)

流線の最大数を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 10]

流線の数の指定に記号的な名前を使う：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> p, PlotLabel -> p], {p, {Automatic, Coarse, Fine}}]

明示的にシードされた流線のスタイルに自動的なシードと明示的なシードの両方を使う：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamPoints -> {{{{1, 0}, Red}, {{-1, -1}, Green}, Automatic}}]

流線間の最短距離を指定する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> d, StreamPoints -> {Automatic, d}], {d, {Automatic, 1, Scaled[0.05]}}]

流線間の最短距離を流線の先頭と末尾で指定する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> d, StreamPoints -> {Automatic, d}], {d, {Automatic, {Scaled[0.1], Scaled[0.5]}}}]

各流線が取り得る最長の長さを制御する：

Wolfram Language code: points = Tuples[{-2, 0, 2}, 2]
Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> {points, Automatic, maxlen}, Epilog -> Point[points]], {maxlen, {2.5, Scaled[0.5]}}]

StreamScale  (9)

分割されていない完全な流線を作る：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, StreamScale -> Full]

流線に曲線を使う：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, StreamScale -> None]

流線の長さを制御するのに記号的な名前を使う：

Wolfram Language code: Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> s, StreamScale -> s], {s, {Tiny, Large}}]

断片の長さを指定する：

Wolfram Language code: Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> s, StreamScale -> s], {s, {0.1, 0.2, 0.4}}]

流線の明示的な破線のパターンを指定する：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamScale -> {{0.1, 0.1}, Automatic}]

各流線の断片について描画する点の数を指定する：

Wolfram Language code: Table[StreamDensityPlot[{y, -x}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> n, StreamScale -> {Full, n}], {n, {12, 24, All}}]

最長の線分と相対的な絶対縦横比を指定する：

Wolfram Language code: Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, PlotLabel -> a, StreamScale -> {Automatic, Automatic, a}], {a, {.02, .04}}]

各線分と相対的な相対的縦横比を指定する：

Wolfram Language code: Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, PlotLabel -> a, StreamScale -> {Automatic, Automatic, a}], {a, {Scaled[0.5], Scaled[1], Scaled[1.5]}}]

座標によって矢印の長さをスケールする：

Wolfram Language code: StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamScale -> {Automatic, 2, Automatic, Function[{x, y, vx, vy, n}, y]}]

StreamStyle  (5)

StreamStyleでは，StreamColorFunctionは色より優先順位が高い：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamStyle -> Black]

StreamColorFunctionNoneと設定してStreamStyleで色を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamStyle -> Black, StreamColorFunction -> None]

流線にさまざまなスタイルを適用する：

Wolfram Language code: Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> s, StreamColorFunction -> None], {s, {Black, Thick, Directive[Black, Dashed]}}]

カスタム鏃を指定する：

Wolfram Language code: StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> Arrowheads[{{0.03, Automatic, Graphics[Circle[]]}}]]

複数のベクトル場のスタイルを設定する：

Wolfram Language code: StreamDensityPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {-(1 + x - y ^ 2), -1 - x ^ 2 + y}}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 30, StreamStyle -> {Red, Black}, StreamColorFunction -> None]

アプリケーション  (16)

ベクトル場を場の発散に基づいた背景で可視化する：

Wolfram Language code: f = {Sin[x] ^ 3, -Cos[y] ^ 2}; StreamDensityPlot[Evaluate@{f, Div[f, {x, y}]}, {x, -3, 3}, {y, -3, 3}]

ベクトル場を場の回転の大きさに基づいた背景で可視化する：

Wolfram Language code: f = {Sin[y], -Sin[x] - y / 4}; StreamDensityPlot[Evaluate@{f, Norm[{0, 0, Curl[f, {x, y}]}]}, {x, -3, 3}, {y, -3, 3}]

2Dハミルトン(Hamilton)系のハミルトン方程式に重ね合わされた流線を示す：

Wolfram Language code: H[x_, y_] = y ^ 2 / 2 + x ^ 2( x ^ 2 - 2) / 4; V[x_, y_] = Expand[-Curl[H[x, y], {x, y}]]
Wolfram Language code: StreamDensityPlot[{V[x, y], H[x, y]}, {x, -2, 2}, {y, -2, 2}]

NDSolveがいかに不変量を保存するかを検証する：

Wolfram Language code: sol = First[NDSolve[{x'[t] == y[t], y'[t] == x[t] - x[t] ^ 3, Thread[{x[0], y[0]} == RandomReal[{-2, 2}, {2}]]}, {x, y}, {t, 0, 10}, InterpolationOrder -> All]]; Plot[Evaluate[(H[x[t], y[t]] - H[x[0], y[0]]) /. sol], {t, 0, 10}]

線形平面系の特性をインタラクティブに明らかにする：

Wolfram Language code: Manipulate[Row[{Text["m"] == MatrixForm[m], StreamDensityPlot[Evaluate[m.{x, y}], {x, -1, 1}, {y, -1, 1}, StreamScale -> Large, StreamColorFunction -> "Rainbow" ]}], {{m, (| | | | - | - | | 1 | 0 | | 0 | 2 |)}, {(| | | | - | - | | 1 | 0 | | 0 | 2 |) -> "Nodal source", (| | | | - | - | | 1 | 1 | | 0 | 1 |) -> "Degenerate source", (| | | | -- | - | | 0 | 1 | | -1 | 1 |) -> "Spiral source", (| | | | -- | -- | | -1 | 0 | | 0 | -2 |) -> "Nodal sink", (| | | | -- | -- | | -1 | 1 | | 0 | -1 |) -> "Degenerate sink", (| | | | -- | -- | | 0 | 1 | | -1 | -1 |) -> "Spiral sink", (| | | | -- | - | | 0 | 1 | | -1 | 0 |) -> "Center", (| | | | - | -- | | 1 | 0 | | 0 | -2 |) -> "Saddle"}}]

流線プロットをインタラクティブな微分方程式のデモの背景として使う：

Wolfram Language code: Manipulate[ splot = StreamDensityPlot[{y, -Sin[x] - .25 y}, {x, -4, 4}, {y, -3, 3}]; Dynamic[Show[splot, ParametricPlot[Evaluate[First[{x[t], y[t]} /. NDSolve[{x'[t] == y[t], y'[t] == -Sin[x[t]] - .25y[t], Thread[{x[0], y[0]} == point]}, {x, y}, {t, 0, T}]]], {t, 0, T}, PlotStyle -> Red]]], {{T, 10}, 1, 100}, {{point, {1, 0}}, Locator}]

いくつかの例題を一つのタブ付きビューにまとめる：

Wolfram Language code: fields = | | | | ---------------------------- | --------------------------------------------------- | | "positive invariant set" | {y, -x + y(1 - x ^ 2 - 2y ^ 2)} | | "structurally stable system" | {2x + y - x(x ^ 2 + y ^ 2), -y - y(x ^ 2 + y ^ 2)} | | "transcritical bifurcation" | {x ^ 2, -y} | | "reaction-diffusion" | {2(y - x) + x(1 - x ^ 2), -2(y - x) + y(1 - y ^ 2)} | | "Duffing's equation" | {y, x - x ^ 3} |;
Wolfram Language code: fieldIcon[f_] := Image[StreamDensityPlot[f, {x, -3, 3}, {y, -3, 3}, Axes -> False, Frame -> False, ColorFunction -> Hue, StreamPoints -> 20], ImageSize -> 40]

タブの上にマウスを置いて場の説明を見る：

Wolfram Language code: TabView[Table[Tooltip[fieldIcon[f[[2]]], f[[1]]] -> StreamDensityPlot[f[[2]], {x, -3, 3}, {y, -3, 3}, StreamScale -> 0.2, ColorFunction -> Hue, PlotLabel -> TraditionalForm[Column@f[[2]]]], {f, fields}]]

2つの極限サイクルを持つ二次系：

Wolfram Language code: p[x_, y_] := 169(x - 1) ^ 2 - 16(y - 1) ^ 2 - 153; q[x_, y_] := 144(x - 1) ^ 2 - 9(y - 1) ^ 2 - 135;
Wolfram Language code: With[{λ = 0.8}, StreamDensityPlot[Evaluate@{p[x, y]Cos[λ] - q[x, y]Sin[λ], p[x, y]Sin[λ] + q[x, y]Cos[λ]}, {x, -1, 3}, {y, -1, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ}]]]

ホモクリニックループ：

Wolfram Language code: Table[StreamDensityPlot[{2y, 2x - 3x ^ 2 + λ y(x ^ 2 - x ^ 2 + y ^ 2)}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> Row[{"λ = ", λ}]], {λ, {-1, 0, 1, 5}}]

奇数対称でダブルゼロの固有値を展開する：

Wolfram Language code: f1[x_, y_] := {y, λ1 x + λ2 y + x ^ 3 + x ^ 2 y};
Wolfram Language code: Grid@Table[StreamDensityPlot[Evaluate@f1[x, y], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, StreamStyle -> Black, StreamColorFunction -> None, PlotLabel -> Row[{"λ1 = ", λ1, " λ2 = ", λ2}]], {λ1, {-1, 0, 1}}, {λ2, {-1, 0, 1}}]

Manipulateを使ってパラメータ化されたベクトル場を調べる：

Wolfram Language code: Manipulate[StreamDensityPlot[{y, λ + μ x - x ^ 3}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> {λ, μ}], {λ, -1, 1}, {μ, -1, 1}]

振動膜：

Wolfram Language code: Manipulate[StreamDensityPlot[{-x ^ 2 - λ x y ^ 2 + x, -y ^ 3 - λ x ^ 2 y + y}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ}]], {λ, -5, 5}]

関数とその勾配磁場を展開する：

Wolfram Language code: Manipulate[StreamDensityPlot[Evaluate[-D[1 / 3(x ^ 3 + y ^ 3) - λ1 x y - λ2 x - λ3 y, {{x, y}}]], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> {λ1, λ2, λ3}], {λ1, -1, 1}, {λ2, -1, 1}, {λ3, -1, 1}]

アニメーションのためにラスタライズしたプロットのリストを生成する：

Wolfram Language code: labeledImage[g_, λ_] := Row[{Image[g, ImageSize -> 175], Row[{" λ = ", λ}]}]
Wolfram Language code: g = Table[labeledImage[StreamDensityPlot[{y, -1 + λ + Cos[x]}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large], λ], {λ, -5, 5, 5 / 16}];

もとのベクトルグラフィックスの代りにラスタのリストをアニメーションにした方が，メモリが少なくて済むかもしれない：

Wolfram Language code: ListAnimate[g]

流線の色をベクトルのノルムの方向にシフトするアニメーションを作成する：

Wolfram Language code: frames = Table[Image[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> 0.03, StreamColorFunction -> (Hue[k + #5]&)], ImageSize -> 175], {k, 0, 1, 0.1}];
Wolfram Language code: ListAnimate[frames]

いくつかの例題でさまざまな流線のスタイルとスケールを調べてみる：

Wolfram Language code: fields = {{x + y ^ 2 + y ^ 3, -x + y + y x ^ 2}, {x - x y ^ 2 + y ^ 3, 3y - y x ^ 2 + x ^ 3}, {(2 - x - 2y)x, (2 - 2x - y)y}, {y, (1 - x ^ 2 - y ^ 2)y / 20 - x}, {2 x y, 1 + x ^ 2 - y ^ 2}, {y, x - x ^ 2 + (1 + x)y}};
Wolfram Language code: styles = {"Arrow", "ArrowArrow", "CircleArrow", "BarDot", "Dot", "DotDot", "DotArrow", "Dart", "Drop", "BackwardPointer", "Pointer", "Toothpick", "Dart", "PinDart", "DoubleDart", "Segment", "Line"};

場の選択をグラフィカルに表すアイコンを生成する：

Wolfram Language code: icons = Table[f -> Image[StreamPlot[f, {x, -3, 3}, {y, -3, 3}, Axes -> False, Frame -> False, StreamPoints -> 20, StreamStyle -> "Line"], ImageSize -> 42], {f, fields}];

場のアイコンをクリックして場のプロットを切り換える：

Wolfram Language code: Manipulate[StreamDensityPlot[field, {x, -3, 3}, {y, -3, 3}, StreamStyle -> style, StreamScale -> scale, ColorFunction -> color, ImageSize -> 300], {style, styles}, {{color, "SandyTerrain"}, ColorData["Gradients"]}, {{scale, 0.2}, 0.05, 0.5, 0.05}, {{field, icons[[1, 1]]}, icons, Setter}]

が変化する流線プロットのリストを生成する：

Wolfram Language code: values = {-1, 0, 1}; plots = MapIndexed[Function[{λ, i}, StreamDensityPlot[{y, -1 + λ + Cos[x]}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 16, StreamScale -> 0.07, StreamStyle -> ColorData["DeepSeaColors"][0.3i[[1]]]]], values]

3Dで2D流線プロットを積み重ねる：

Wolfram Language code: make3D[GraphicsComplex[pts_, rr___], h_] := GraphicsComplex[PadRight[pts, {Length@pts, 3}, h], rr]
Wolfram Language code: make3D[Arrow[pts_, rr___], h_] := Arrow[PadRight[pts, {Length@pts, 3}, h], rr]
Wolfram Language code: stackPlots[plots2D : {__Graphics}, dh_, o : OptionsPattern[Graphics3D]] := Graphics3D[MapIndexed[Function[{g, index}, g[[1]] /. p : _GraphicsComplex | _Arrow :> make3D[p, dh index[[1]]]], plots2D], o]
Wolfram Language code: plotSpacing = 5; stackPlots[plots, plotSpacing, Axes -> True, Boxed -> False, Ticks -> {Automatic, Automatic, MapIndexed[{plotSpacing#2[[1]], Row[{"λ = ", #1}]}&, values]}]

特性と関係  (12)

データのプロットにListStreamDensityPlotを使う：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];
Wolfram Language code: ListStreamDensityPlot[data]

StreamPlotを使ってスカラー場のプロットなしで流線だけをプロットする：

Wolfram Language code: StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]

VectorDensityPlotを使って流線の代りにベクトルで関数をプロットする：

Wolfram Language code: VectorDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]

ListVectorDensityPlotを使って流線の代りにベクトルでデータをプロットする：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];
Wolfram Language code: ListVectorDensityPlot[data]

VectorPlotを使ってスカラー場のプロットなしで流線の代りにベクトルでプロットする：

Wolfram Language code: VectorPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]

VectorPlot3Dを使って3Dベクトル場を可視化する：

Wolfram Language code: VectorPlot3D[{x, y, z}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

SliceVectorPlot3Dを使って曲面上に3Dベクトル場を可視化する：

Wolfram Language code: SliceVectorPlot3D[{-y, x, z}, Sphere[], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

StreamDensityPlotは必要であればより多くの点をサンプルとして使う：

Wolfram Language code: StreamDensityPlot[{y, -x ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]

スカラー場はDensityPlotを使ってそれ自身でプロットすることができる：

Wolfram Language code: f = {-1 - x ^ 2 + y, 1 + x - y ^ 2}; s = Exp[Norm[f] / 10];
Wolfram Language code: {DensityPlot[s, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"], StreamDensityPlot[{f, s}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"]}

LineIntegralConvolutionPlotを使ってベクトル場の線形積分たたみ込みをプロットする：

Wolfram Language code: LineIntegralConvolutionPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]

複素関数をベクトル場としてプロットする：

Wolfram Language code: ComplexVectorPlot[z + 1 / z, {z, 2}]

GeoStreamPlotは地球の地図上に流線をプロットする：

Wolfram Language code: GeoStreamPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567}, {-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851}, {7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864}, { ... 904, "AngularDegrees"]}, {0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]}, {0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]}, {0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]

特性と関係  (12)

VectorDensityPlotを使って流線ではなくベクトルでプロットする：

Wolfram Language code: VectorDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]

StreamPlotまたはVectorPlotをスカラー場の密度プロットなしで関数をプロットするのに使う：

Wolfram Language code: {StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}], VectorPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]}

ListStreamDensityPlotを使ってデータをプロットする：

Wolfram Language code: data = Table[{x^2 - y^2, x + y}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}];
Wolfram Language code: ListStreamDensityPlot[data]

ListStreamPlotを密度プロットなしのデータのプロットに使う：

Wolfram Language code: ListStreamPlot[data]

ListVectorPlotを使って流線の代りにベクトルをプロットする：

Wolfram Language code: ListVectorPlot[data]

ListVectorDensityPlotを使ってベクトルに密度プロットを加える：

Wolfram Language code: ListVectorDensityPlot[data]

VectorDisplacementPlotを使って変位ベクトル場に関連付けられた領域の変形を可視化する：

Wolfram Language code: VectorDisplacementPlot[{y, x - x^3}, {x, y}∈Disk[], VectorPoints -> Automatic]

ListVectorDisplacementPlotを使って同じ変形をデータに基づいて可視化する：

Wolfram Language code: data = Table[{{x, y} = RandomReal[{-1, 1}, {2}], {y, x - x ^ 3}}, {300}];
Wolfram Language code: ListVectorDisplacementPlot[data, Disk[], VectorPoints -> Automatic]

VectorDisplacementPlot3Dを使って変位ベクトル場に関連付けられた3D領域の変形を可視化する：

Wolfram Language code: VectorDisplacementPlot3D[{y, x, -z}, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, VectorPoints -> "Boundary"]

ListVectorDisplacementPlot3Dを使って同じ変形をデータに基づいて可視化する：

Wolfram Language code: data = Table[{{x, y, z} = RandomReal[{0, 1}, {3}], {y, x, -z}}, {300}];
Wolfram Language code: ListVectorDisplacementPlot3D[data, Cuboid[], VectorPoints -> "Boundary"]

VectorPlot3DまたはStreamPlot3Dを使って3Dベクトル場を可視化する：

Wolfram Language code: {VectorPlot3D[{z, -x, y}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}], StreamPlot3D[{z, -x, y}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]}

ListVectorPlot3DまたはListStreamPlot3Dを使って同じ3Dベクトル場をデータに基づいて可視化する：

Wolfram Language code: data = Table[{z, -x, y}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}];
Wolfram Language code: {ListVectorPlot3D[data], ListStreamPlot3D[data]}

SliceVectorPlot3Dを使って曲面上に3Dベクトル場データを曲面に沿って可視化する：

Wolfram Language code: SliceVectorPlot3D[{x, y, z}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

ListSliceVectorPlot3Dを使って同じ3Dベクトル場データをデータに基づいて可視化する：

Wolfram Language code: ListSliceVectorPlot3D[Table[{x, y, z}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}]]

StreamDensityPlotは必要であればより多くの点をサンプルとして使う：

Wolfram Language code: StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]

スカラー場はListDensityPlotを使ってそれ自身でプロットすることができる：

Wolfram Language code: f = {-1 - x ^ 2 + y, 1 + x - y ^ 2}; s = Exp[Norm[f] / 10];
Wolfram Language code: data = Table[{f, s}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}]; scalarData = Table[s, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];
Wolfram Language code: {ListDensityPlot[scalarData, ColorFunction -> "Pastel"], ListStreamDensityPlot[data, ColorFunction -> "Pastel"]}

ListLineIntegralConvolutionPlotを使ってベクトル場データの線積分のたたみ込みをプロットする：

Wolfram Language code: data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, .2}, {y, -3, 3, .2}];
Wolfram Language code: ListLineIntegralConvolutionPlot[data]

ComplexVectorPlotまたはComplexStreamPlotを使って複素変数の複素関数をベクトル場としてまたは流線でプロットする：

Wolfram Language code: {ComplexVectorPlot[Sin[3z], {z, 2}], ComplexStreamPlot[Sin[3z], {z, 2}]}

GeoVectorPlotで地図上にベクトルをプロットする：

Wolfram Language code: GeoVectorPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567}, {-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851}, {7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864}, { ... 904, "AngularDegrees"]}, {0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]}, {0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]}, {0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]

GeoStreamPlotでベクトルの代りに流線をプロットする：

Wolfram Language code: GeoStreamPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567}, {-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851}, {7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864}, { ... 904, "AngularDegrees"]}, {0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]}, {0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]}, {0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]

おもしろい例題  (3)

発散を背景濃度として流線をプロットする：

Wolfram Language code: vf = {Cos[x + y ^ 3], Sin[y + x ^ 3]}; StreamDensityPlot[Evaluate[{vf, Div[vf, {x, y}]}], {x, -3, 3}, {y, -3, 3}, StreamPoints -> Fine, StreamScale -> Large, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None]
Wolfram Language code: vf = { 1, Sin[x^3 + y^3]};StreamDensityPlot[Evaluate[{vf, Div[vf, {x, y}]}], {x, -3, 3}, {y, -3, 3}, StreamPoints -> Fine, StreamScale -> Large, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None]
Wolfram Language code: vf = {Sin[Cos[3 y] + Sin[3 x]], 3 Cos[Cos[3 y] + 3 x]};StreamDensityPlot[Evaluate[{vf, Div[vf, {x, y}]}], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None]

渦度の絶対値を背景濃度として流線をプロットする：

Wolfram Language code: vf = {Cos[x + y ^ 3], Sin[y + x ^ 3]}; StreamDensityPlot[Evaluate[{vf, Abs[Curl[vf, {x, y}]]}], {x, -2, 2}, {y, -2, 2}, StreamPoints -> Fine, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamScale -> Large, StreamColorFunction -> None]
Wolfram Language code: vf = { 1, Sin[x^3 + y^3]};StreamDensityPlot[Evaluate[{vf, Abs[Curl[vf, {x, y}]]}], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Rainbow", MaxRecursion -> 3, StreamStyle -> Black, StreamColorFunction -> None, StreamPoints -> Fine]
Wolfram Language code: vf = {Sin[Cos[3 y] + Sin[3 x]], 3 Cos[Cos[3 y] + 3 x]}; StreamDensityPlot[Evaluate[{vf, Abs[Curl[vf, {x, y}]]}], {x, -3, 3}, {y, -3, 3}, StreamPoints -> Fine, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None, StreamScale -> Large]

流線プロットをさまざまな領域に制限する：

Wolfram Language code: StreamDensityPlot[{y, -x}, {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y}, 0.55 < x ^ 2 + y ^ 2 < 4.2], ColorFunction -> "RedBlueTones", Frame -> False, StreamScale -> Medium, BoundaryStyle -> {Cyan, Thick}]
Wolfram Language code: StreamDensityPlot[{Cos[x ^ 2 + y], 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BeachColors", StreamColorFunction -> "DeepSeaColors", StreamScale -> {Automatic, Automatic, Scaled[0.8]}, Frame -> False, RegionFunction -> Function[(#1 + 3) ≥ 0.45 #2 ^ 2], BoundaryStyle -> {Blue, Thick}]
Wolfram Research (2008), StreamDensityPlot, Wolfram言語関数， https://reference.wolfram.com/language/ref/StreamDensityPlot.html （2022年に更新）.

テキスト

Wolfram Research (2008), StreamDensityPlot, Wolfram言語関数， https://reference.wolfram.com/language/ref/StreamDensityPlot.html （2022年に更新）.

CMS

Wolfram Language. 2008. "StreamDensityPlot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/StreamDensityPlot.html.

APA

Wolfram Language. (2008). StreamDensityPlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StreamDensityPlot.html

BibTeX

@misc{reference.wolfram_2026_streamdensityplot, author="Wolfram Research", title="{StreamDensityPlot}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/StreamDensityPlot.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_streamdensityplot, organization={Wolfram Research}, title={StreamDensityPlot}, year={2022}, url={https://reference.wolfram.com/language/ref/StreamDensityPlot.html}, note=[Accessed: 03-November-2026]}