BetaDistribution
BetaDistribution
BetaDistribution[α,β]
形状母数 α と β の連続型のベータ分布を表す．
詳細
- ベータ分布における値
の確率密度は，
では 
に比例し，
または 
の場合はゼロとなる． » - BetaDistributionでは，α および β は任意の正の実数でよい．
- BetaDistributionでは，α と β は無次元量でよい． »
- BetaDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »
予備知識
- BetaDistribution[α,β]は，区間
上で定義され，「形状母数」として知られる2つの正の値 α および β でパラメータ化される統計分布を表す．この形状母数が確率密度関数(PDF)の右裾部と左裾部のいわゆる「太り具合」を決定する．ベータ分布のPDFは，α と β の値によって，単調増加であったり，単調減少であったり，潜在的な特異値がその領域の境界に接近する，単一の「峰」を持ったりする． - ベータ分布は，ベイズ解析における二項比率についての事前分布として起る．これは，一般に，有限区間に限定された確率変数をモデル化するためにも使われる．例えば，連続独立一様分布に従うサイズ
のサンプルの 
番目に小さい要素の分布は，OrderDistribution[{UniformDistribution[],n},k]を使って計算することができ，BetaDistribution[k,n-k+1]と厳密に等しい．ベータ分布は，その統計的有意性に加え，対立遺伝子頻度分布に関連する現象，土質の変動性，地質学における鉱物含有率，HIVの感染挙動等，数多くの科学分野で基本的な役割を果たす． - RandomVariateを使って，ベータ分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BetaDistribution[α,β]]（より簡略な表記では xBetaDistribution[α,β]）を使って，確率変数 x がベータ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
- 確率密度関数および累積分布関数は，PDF[BetaDistribution[α,β],x]およびCDF[BetaDistribution[α,β],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
- DistributionFitTestを使って，与えられたデータ集合がベータ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックベータ分布を推定することが，FindDistributionParametersを使ってデータをベータ分布にフィットすることができる．ProbabilityPlotを使って記号ベータ分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ベータ分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
- TransformedDistributionを使って変換されたベータ分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってベータ分布を含む高次元分布を構築することが，ProductDistributionを使ってベータ分布を含む独立成分分布の結合分布を計算することができる．
- ベータ分布は他の数多くの分布と関連している．例えば，BetaDistributionは，BernoulliDistribution，BinomialDistribution，NegativeBinomialDistribution，GeometricDistributionを含む他の多くの分布についてのいわゆる「共役事前確率分布」である．さらに，BetaDistributionは，PDF[BetaDistribution[1,1],x]がPDF[UniformDistribution[],x]とPDF[PowerDistribution[1,1],x]の両方と等しいという意味（端点
および 
を含んで法として）において，UniformDistributionとPowerDistributionの両方を一般化する．BetaDistributionはKumaraswamyDistributionおよびNoncentralBetaDistributionの変換としても得ることができ，PERTDistribution，PearsonDistribution，ChiSquareDistribution，GammaDistribution，FRatioDistribution，BetaPrimeDistributionと密接な関係がある．
例題
すべて開く すべて閉じる例 (4)
Plot[Table[PDF[BetaDistribution[2, β], x], {β, {1 / 4, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]Plot[Table[PDF[BetaDistribution[α, 1.5], x], {α, {1 / 2, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]PDF[BetaDistribution[α, β], x]Plot[Table[CDF[BetaDistribution[2, β], x], {β, {1 / 4, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]Plot[Table[CDF[BetaDistribution[α, 1.5], x], {α, {1 / 2, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]CDF[BetaDistribution[α, β], x]Mean[BetaDistribution[α, β]]Variance[BetaDistribution[α, β]]Median[BetaDistribution[α, β]]スコープ (8)
data = RandomVariate[BetaDistribution[3, 2.5], 10 ^ 4];Show[Histogram[data, 15, "PDF"], Plot[PDF[BetaDistribution[3, 2.5], x], {x, 0, 1}, PlotStyle -> Thick]]sample = RandomVariate[BetaDistribution[2, 3], 10 ^ 3];edist = EstimatedDistribution[sample, BetaDistribution[a, b]]サンプルの密度ヒストグラムを推定された分布の確率密度関数と比較する：
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 1}, PlotStyle -> Thick]]Plot3D[Skewness[BetaDistribution[α, β]], {α, 0, 4}, {β, 0, 4}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]Skewness[BetaDistribution[α, β]]
Limit[Limit[Skewness[BetaDistribution[α, β]], α -> ∞], β -> ∞]Plot3D[Kurtosis[BetaDistribution[α, β]], {α, 0, 1}, {β, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {.5, -2.3, 1.2}]Kurtosis[BetaDistribution[α, β]]極限では，尖度はNormalDistributionのものと同じになる：
Limit[Limit[Kurtosis[BetaDistribution[α, β]], β -> ∞], α -> ∞]Kurtosis[NormalDistribution[μ, σ]]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[BetaDistribution[α, β], k]//FullSimplify, {k, 5}], M]FormulaGrid[Table[CentralMoment[BetaDistribution[α, β], k]//Simplify, {k, 5}], CM]FormulaGrid[Table[FactorialMoment[BetaDistribution[α, β], k]//Simplify, {k, 5}], FM]FormulaGrid[Table[Cumulant[BetaDistribution[α, β], k]//Simplify, {k, 5}], C]Plot[Table[HazardFunction[BetaDistribution[α, 1 / 20], x], {α, {0.1, 0.5, 2}}]//Evaluate, {x, 0, 1}, Filling -> Axis]Plot[Table[HazardFunction[BetaDistribution[1 / 20, β], x], {β, {0.1, 0.5, 2}}]//Evaluate, {x, 0, 1}, Filling -> Axis]HazardFunction[BetaDistribution[α, β], x]Plot[Table[Quantile[BetaDistribution[α, 2], q], {α, {1, 3, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Plot[Table[Quantile[BetaDistribution[2, β], q], {β, {1, 3, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[BetaDistribution[α, β], q]母数でQuantityを一貫して用いると，母数がその数値に拡張される：
prob𝒟 = BetaDistribution[Quantity[6, "dozens"], Quantity[7, "dozens"]]Mean[prob𝒟]//Nアプリケーション (3)
ある特定の地域では，曇っている時間が母数を0.3と0.4としたベータ分布にほぼ従う．曇りが半日以上続く確率を求める：
Probability[x > 0.5, xBetaDistribution[0.3, 0.4]]1日のうちの曇っている時間の割合のシミュレーションを30日間分行う：
month = RandomVariate[BetaDistribution[0.3, 0.4], 30];ListPlot[month, Filling -> Axis]Mean[BetaDistribution[0.3, 0.4]]1ヶ月間で曇っている時間が10%より少ない日がちょうど20日間になる確率を求める：
p = Probability[x < 0.1, xBetaDistribution[0.3, 0.4]];Probability[k == 20, kBinomialDistribution[30, p]]1ヶ月間で曇っている時間が10%より少ない日が少なくとも20日になる確率を求める：
Probability[k ≥ 20, kBinomialDistribution[30, p]]ベータ分布は指定の1日に株価が上昇した株の割合のモデルに使うことができる．ベータ分布をダウ平均株価にフィットする：
dji = EntityList[EntityClass["Financial", "DowJonesIndustrialAverageComponents"]]Clear[djichange];djichange = DeleteMissing @Table[FinancialData[tick, "FractionalChange", {{2009, 3, 1}, {2013, 3, 1}, "Day"}, "Value"], {tick, dji}];days = First[djichange]["PathLength"]djichangevals = Normal /@ Values /@ djichange;ArrayQ[djichangevals]MatrixPlot[djichangevals, AspectRatio -> 1, FrameLabel -> {"Company", "Day"}]ratios = Table[Count[djichangevals[[All, i]], _ ? Positive] / Length[dji], {i, days}];edist = EstimatedDistribution[Select[ratios, (0 < # < 1&)], BetaDistribution[α, β]]Show[Histogram[ratios, 10, "PDF"], Plot[PDF[edist, x], {x, 0, 1}, PlotStyle -> Thick]]ダウ平均株価の株式の少なくとも60%の株価が上昇する確率を求める：
NProbability[x ≥ .6, xedist]Mean[edist] 100ダウ平均株価の株式で30日間に渡って株価が上昇するものの割合のシミュレーションを行う：
ListPlot[RandomVariate[edist, 30], Joined -> True]離散時間マルコフ連鎖 
（ただし，
は同一同分布に従う一連の標準一様確率変数で，
は独立同分布に従う成功確率が 
のベルヌーイ確率変数）は，
である任意の初期条件 
について定常分布BetaDistribution[p,1-p]に収束する：
mcPath = Compile[{{x0, _Real}, {zvec, _Integer, 1}, {uvec, _Real, 1}},
Module[{path = Table[x0, {Length[zvec]}], i = 1, x = x0},
Do[path[[i]] = If[zvec[[i]] == 0, x *= uvec[[i]], x += uvec[[i]](1 - x)], {i, Length[zvec]}];path]];このマルコフ連鎖の実現からサンプルを取り，経路のバーンイン部分を除去する：
x0 = 0.2;p = 0.3;len = 10 ^ 5 + 100;
path = mcPath[x0, RandomVariate[BernoulliDistribution[p], len], RandomReal[1, len]];
pathTail = Drop[path, 100];マルコフ連鎖からのサンプルは独立ではなく，内部構造を示している：
iidSamples = RandomVariate[BetaDistribution[p, 1 - p], Length[pathTail]];
vizopts = {ImageSize -> 200, PlotStyle -> PointSize[Tiny], AspectRatio -> 1, PlotTheme -> "Scientific"};
Row[{Legended[ListPlot[Partition[pathTail, 2, 2], vizopts], Placed[Style["MC samples", Bold], Below]], Legended[ListPlot[Partition[iidSamples, 2, 2], vizopts], Placed[Style["iid samples", Bold], Below]]}]経路の値のヒストグラムをマルコフ連鎖の定常分布PDFと比較する：
Show[Histogram[pathTail, {0, 1, 0.01}, "LogPDF"], LogPlot[PDF[BetaDistribution[p, 1 - p], x], {x, 0, 1}, PlotRange -> All], ImageSize -> 250, PlotRange -> {-2, 3}]Mean[Log[# / (1 - #)]&[pathTail]]NExpectation[Log[x / (1 - x)], xBetaDistribution[p, 1 - p]]特性と関係 (21)
TransformedDistribution[1 - u, uBetaDistribution[α, β]]
BetaDistribution[1,1]はUniformDistribution[{0,1}]に等しい：
PDF[BetaDistribution[1, 1], x]PDF[UniformDistribution[{0, 1}], x]BetaDistributionはUniformDistributionを変換したものである：
TransformedDistribution[u ^ a, uUniformDistribution[]]UniformDistributionはBetaDistributionを変換したものである：
TransformedDistribution[u ^ a, uBetaDistribution[a, 1]]BetaDistributionはNoncentralBetaDistributionの極限のケースである：
Limit[PDF[NoncentralBetaDistribution[α, β, δ], x], δ -> 0]PDF[BetaDistribution[α, β], x]Simplify[% - %%]BetaPrimeDistributionはベータ分布に従う変数を変換して得ることができる：
TransformedDistribution[u / (1 - u), uBetaDistribution[α, β]]TransformedDistribution[(1 - u) / u, uBetaDistribution[α, β]]ベータ分布はタイプ1のPearsonDistributionの特殊ケースである：
CDF[PearsonDistribution[1, 1, (α/-α - β), (1/-α - β), (-1/-α - β), 0], x]//FullSimplifyCDF[BetaDistribution[1 + α, 1 + β], x]% - %%ベータ分布はGammaDistributionの変換として得ることができる：
TransformedDistribution[u / (u + v), {uGammaDistribution[p1, b], vGammaDistribution[p2, b]}]ベータ分布はChiSquareDistributionを変換したものとして求めることができる：
TransformedDistribution[u / (u + v), uChiSquareDistribution[n1] && vChiSquareDistribution[n2]]FRatioDistributionはベータ分布から求めることができる：
𝒟 = Assuming[{m > 0 && n > 0}, TransformedDistribution[m u / (n (1 - u)), uBetaDistribution[n / 2, m / 2]]];CDF[𝒟, x]//FullSimplify[#, m > 0 && n > 0 && n x + m > 0]&CDF[FRatioDistribution[n, m], x]//SimplifyFullSimplify[% - %%]ベータ分布はUniformDistributionに従っている変数の次数分布である：
OrderDistribution[{UniformDistribution[{0, 1}], n}, k]ExponentialDistributionはスケールされたベータ分布の極限である：
𝒟 = TransformedDistribution[u n, uBetaDistribution[1, n]];PDF[𝒟, x]Limit[%, n -> ∞]PDF[ExponentialDistribution[1], x]FullSimplify[% - %%, x ≠ 0]ExponentialDistributionはベータ分布を変換したものである：
TransformedDistribution[-Log[u], uBetaDistribution[α, 1]]TransformedDistribution[-Log[1 - u], uBetaDistribution[1, β]]KumaraswamyDistributionはベータ分布を変換したものである：
TransformedDistribution[x^1 / α, xBetaDistribution[1, β]]KumaraswamyDistributionを簡約するとベータ分布の特殊なケースになる：
PDF[KumaraswamyDistribution[α, 1], x]PDF[BetaDistribution[α, 1], x]//FullSimplify% - %%//SimplifyPERTDistributionはベータ分布を変換したものである：
𝒟 = TransformedDistribution[min + z(max - min), zBetaDistribution[1 + λ(c - min) / (max - min), 1 + λ(max - c) / (max - min)]];CDF[𝒟, x]//FullSimplify[#, min < c < max]&CDF[PERTDistribution[{min, max}, c, λ], x]FullSimplify[% - %%, min < c < max && λ ≥ 0]WignerSemicircleDistributionは特殊ベータ分布の変換である：
𝒟 = TransformedDistribution[r(2 X - 1), XBetaDistribution[3 / 2, 3 / 2], Assumptions -> r > 0];PDF[𝒟, x]//FullSimplify[#, r > 0]&PDF[WignerSemicircleDistribution[r], x]//FullSimplify[#, r > 0]&%% - %//FullSimplify[#, r > 0]&DirichletDistributionの一変量周辺分布はベータ分布である：
MarginalDistribution[DirichletDistribution[{α1, α2, α3}], 1]MarginalDistribution[DirichletDistribution[{α1, α2, α3}], 2]BetaBinomialDistributionはBinomialDistributionとBetaDistributionを混合したものである：
ParameterMixtureDistribution[BinomialDistribution[n, p], pBetaDistribution[α, β]]BetaNegativeBinomialDistributionはNegativeBinomialDistributionとBetaDistributionを混合したものである：
ParameterMixtureDistribution[NegativeBinomialDistribution[n, p], pBetaDistribution[α, β]]考えられる問題 (2)
BetaDistributionは α か β のいずれかが正の実数でない場合は定義されない：
Mean[BetaDistribution[0, 2]]
Mean[BetaDistribution[α, β]] /. {α -> I, β -> 3}
Wolfram Research (2007), BetaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BetaDistribution.html （2016年に更新）.
テキスト
Wolfram Research (2007), BetaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BetaDistribution.html （2016年に更新）.
CMS
Wolfram Language. 2007. "BetaDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/BetaDistribution.html.
APA
Wolfram Language. (2007). BetaDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BetaDistribution.html