BetaDistribution
BetaDistribution
BetaDistribution[α,β]
表示一种形状参数为 α 和 β 的连续 β 分布.
更多信息
- 在一个贝塔分布中，
值的概率密度当 
时与 
成正比，当 
或 
时等于零. » - BetaDistribution 允许 α 和 β 为任意正实数.
- BetaDistribution 允许 α 和 β 为无量纲的量. »
- BetaDistribution 可与 Mean、CDF 和 RandomVariate 等函数一起使用. »
背景
- BetaDistribution[α,β] 表示一个定义在区间
上的连续统计分布，称为贝塔分布. 该分布有两个正的“形状参数” α、β，粗略的讲，控制了其概率密度函数（PDF）左右两端的“肥胖程度”. 根据 α 和 β 的值，贝塔分布的 PDF 可能是单调递增或单调递减，也可能是在定义域最左侧逼近潜在奇点的单峰形状. 此外，PDF 的尾部是“胖的”，意思是在 
值较大时 PDF 的衰减不是指数的而是代数的.（这一行为可通过研究分布的 SurvivalFunction 做精确的定量分析.） - 贝塔分布作为二项式比例的先验分布出现在贝叶斯分析中. 它通常也被用来模拟限制在有限区间上的随机变量. 例如，
个连续独立均匀分布的样本中第 
小的元素的分布可以通过 OrderDistribution[{UniformDistribution[],n},k] 计算，结果恰恰等于 BetaDistribution[k,n-k+1]. 除了统计显著性之外，贝塔分布在许多科学领域也起着基础性的作用，包括等位基因频率分布、土壤性状变异、地质矿产比例以及艾滋病传播行为等. - RandomVariate 可被用于给出贝塔分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,BetaDistribution[α,β]]，更简洁的写法是 xBetaDistribution[α,β]，可被用于声明随机变量 x 是贝塔分布的. 这一声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
- 概率密度函数和累积分布函数可用 PDF[BetaDistribution[α,β],x] 和 CDF[BetaDistribution[α,β],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
- DistributionFitTest 可被用于测试给定的数据集是否与贝塔分布一致，EstimatedDistribution 可被用于根据给定数据估算贝塔参数化分布，而 FindDistributionParameters 可拟合数据和贝塔分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号贝塔分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号贝塔分布的分位数的图线.
- TransformedDistribution 可被用于表示转换的贝塔分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了贝塔分布的高维分布，而 ProductDistribution 可被用于计算包括贝塔分布在内的，若干个独立分量的联合分布.
- 贝塔分布与许多其它分布密切相关. 例如，BetaDistribution 是许多其它分布参数的“共轭先验”分布，包括 BernoulliDistribution、BinomialDistribution、NegativeBinomialDistribution 和 GeometricDistribution. 此外，BetaDistribution 在包括了端点
和 
的模的意义下，推广了 UniformDistribution 和 PowerDistribution，PDF[BetaDistribution[1,1],x] 等于 PDF[UniformDistribution[],x] 和 PDF[PowerDistribution[1,1],x]. BetaDistribution 也可通过 KumaraswamyDistribution 和 NoncentralBetaDistribution 变换得到，并与 PERTDistribution、PearsonDistribution、ChiSquareDistribution、GammaDistribution、FRatioDistribution 和 BetaPrimeDistribution 密切相关.
范例
打开所有单元 关闭所有单元基本范例 (4)
Plot[Table[PDF[BetaDistribution[2, β], x], {β, {1 / 4, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]Plot[Table[PDF[BetaDistribution[α, 1.5], x], {α, {1 / 2, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]PDF[BetaDistribution[α, β], x]Plot[Table[CDF[BetaDistribution[2, β], x], {β, {1 / 4, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]Plot[Table[CDF[BetaDistribution[α, 1.5], x], {α, {1 / 2, 2, 4}}]//Evaluate, {x, 0, 1}, Filling -> Axis]CDF[BetaDistribution[α, β], x]Mean[BetaDistribution[α, β]]Variance[BetaDistribution[α, β]]Median[BetaDistribution[α, β]]范围 (8)
data = RandomVariate[BetaDistribution[3, 2.5], 10 ^ 4];Show[Histogram[data, 15, "PDF"], Plot[PDF[BetaDistribution[3, 2.5], x], {x, 0, 1}, PlotStyle -> Thick]]sample = RandomVariate[BetaDistribution[2, 3], 10 ^ 3];edist = EstimatedDistribution[sample, BetaDistribution[a, b]]Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 1}, PlotStyle -> Thick]]Plot3D[Skewness[BetaDistribution[α, β]], {α, 0, 4}, {β, 0, 4}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]Skewness[BetaDistribution[α, β]]
Limit[Limit[Skewness[BetaDistribution[α, β]], α -> ∞], β -> ∞]Plot3D[Kurtosis[BetaDistribution[α, β]], {α, 0, 1}, {β, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {.5, -2.3, 1.2}]Kurtosis[BetaDistribution[α, β]]在极限情况下，峰度与 NormalDistribution 相同：
Limit[Limit[Kurtosis[BetaDistribution[α, β]], β -> ∞], α -> ∞]Kurtosis[NormalDistribution[μ, σ]]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[BetaDistribution[α, β], k]//FullSimplify, {k, 5}], M]FormulaGrid[Table[CentralMoment[BetaDistribution[α, β], k]//Simplify, {k, 5}], CM]FormulaGrid[Table[FactorialMoment[BetaDistribution[α, β], k]//Simplify, {k, 5}], FM]FormulaGrid[Table[Cumulant[BetaDistribution[α, β], k]//Simplify, {k, 5}], C]Plot[Table[HazardFunction[BetaDistribution[α, 1 / 20], x], {α, {0.1, 0.5, 2}}]//Evaluate, {x, 0, 1}, Filling -> Axis]Plot[Table[HazardFunction[BetaDistribution[1 / 20, β], x], {β, {0.1, 0.5, 2}}]//Evaluate, {x, 0, 1}, Filling -> Axis]HazardFunction[BetaDistribution[α, β], x]Plot[Table[Quantile[BetaDistribution[α, 2], q], {α, {1, 3, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Plot[Table[Quantile[BetaDistribution[2, β], q], {β, {1, 3, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[BetaDistribution[α, β], q]Quantity 在参数中的一致性使用将它们扩展至数字值：
prob𝒟 = BetaDistribution[Quantity[6, "dozens"], Quantity[7, "dozens"]]Mean[prob𝒟]//N应用 (3)
对于一个特定地点，云量近似服从参数为0.3和0.4的贝塔分布. 求多云天气多于半天的概率：
Probability[x > 0.5, xBetaDistribution[0.3, 0.4]]month = RandomVariate[BetaDistribution[0.3, 0.4], 30];ListPlot[month, Filling -> Axis]Mean[BetaDistribution[0.3, 0.4]]p = Probability[x < 0.1, xBetaDistribution[0.3, 0.4]];Probability[k == 20, kBinomialDistribution[30, p]]Probability[k ≥ 20, kBinomialDistribution[30, p]]β 分布可用于模拟某一给定日期价格上涨的股票所占的比例. 用 β 分布拟合道琼斯工业股票数据：
dji = EntityList[EntityClass["Financial", "DowJonesIndustrialAverageComponents"]]Clear[djichange];djichange = DeleteMissing @Table[FinancialData[tick, "FractionalChange", {{2009, 3, 1}, {2013, 3, 1}, "Day"}, "Value"], {tick, dji}];days = First[djichange]["PathLength"]djichangevals = Normal /@ Values /@ djichange;ArrayQ[djichangevals]MatrixPlot[djichangevals, AspectRatio -> 1, FrameLabel -> {"Company", "Day"}]ratios = Table[Count[djichangevals[[All, i]], _ ? Positive] / Length[dji], {i, days}];edist = EstimatedDistribution[Select[ratios, (0 < # < 1&)], BetaDistribution[α, β]]Show[Histogram[ratios, 10, "PDF"], Plot[PDF[edist, x], {x, 0, 1}, PlotStyle -> Thick]]NProbability[x ≥ .6, xedist]Mean[edist] 100ListPlot[RandomVariate[edist, 30], Joined -> True]离散时间马科夫链 
，其中 
是独立同分布（iid）标准均匀随机变量数列，
是独立同分布伯努力随机变量数列，其中成功概率 
对于任意满足 
的初始条件 
收敛至稳态分布 BetaDistribution[p,1-p]：
mcPath = Compile[{{x0, _Real}, {zvec, _Integer, 1}, {uvec, _Real, 1}},
Module[{path = Table[x0, {Length[zvec]}], i = 1, x = x0},
Do[path[[i]] = If[zvec[[i]] == 0, x *= uvec[[i]], x += uvec[[i]](1 - x)], {i, Length[zvec]}];path]];x0 = 0.2;p = 0.3;len = 10 ^ 5 + 100;
path = mcPath[x0, RandomVariate[BernoulliDistribution[p], len], RandomReal[1, len]];
pathTail = Drop[path, 100];iidSamples = RandomVariate[BetaDistribution[p, 1 - p], Length[pathTail]];
vizopts = {ImageSize -> 200, PlotStyle -> PointSize[Tiny], AspectRatio -> 1, PlotTheme -> "Scientific"};
Row[{Legended[ListPlot[Partition[pathTail, 2, 2], vizopts], Placed[Style["MC samples", Bold], Below]], Legended[ListPlot[Partition[iidSamples, 2, 2], vizopts], Placed[Style["iid samples", Bold], Below]]}]比较路径值的直方图与马科夫链稳态分布的 PDF：
Show[Histogram[pathTail, {0, 1, 0.01}, "LogPDF"], LogPlot[PDF[BetaDistribution[p, 1 - p], x], {x, 0, 1}, PlotRange -> All], ImageSize -> 250, PlotRange -> {-2, 3}]Mean[Log[# / (1 - #)]&[pathTail]]NExpectation[Log[x / (1 - x)], xBetaDistribution[p, 1 - p]]属性和关系 (21)
TransformedDistribution[1 - u, uBetaDistribution[α, β]]
BetaDistribution[1,1] 等价于 UniformDistribution[{0,1}]：
PDF[BetaDistribution[1, 1], x]PDF[UniformDistribution[{0, 1}], x]BetaDistribution 是 UniformDistribution 的一个转换：
TransformedDistribution[u ^ a, uUniformDistribution[]]UniformDistribution 是 BetaDistribution 的一个转换：
TransformedDistribution[u ^ a, uBetaDistribution[a, 1]]BetaDistribution 是 NoncentralBetaDistribution 的一个极限情况:
Limit[PDF[NoncentralBetaDistribution[α, β, δ], x], δ -> 0]PDF[BetaDistribution[α, β], x]Simplify[% - %%]BetaPrimeDistribution 可以从 β 分布变量的转换获得：
TransformedDistribution[u / (1 - u), uBetaDistribution[α, β]]TransformedDistribution[(1 - u) / u, uBetaDistribution[α, β]]贝塔分布是第1类 PearsonDistribution 的一个特例：
CDF[PearsonDistribution[1, 1, (α/-α - β), (1/-α - β), (-1/-α - β), 0], x]//FullSimplifyCDF[BetaDistribution[1 + α, 1 + β], x]% - %%β 分布可以作为 GammaDistribution 的一个变换得到：
TransformedDistribution[u / (u + v), {uGammaDistribution[p1, b], vGammaDistribution[p2, b]}]β 分布可以作为 ChiSquareDistribution 的一个变换得到：
TransformedDistribution[u / (u + v), uChiSquareDistribution[n1] && vChiSquareDistribution[n2]]FRatioDistribution 可以从贝塔分布得到：
𝒟 = Assuming[{m > 0 && n > 0}, TransformedDistribution[m u / (n (1 - u)), uBetaDistribution[n / 2, m / 2]]];CDF[𝒟, x]//FullSimplify[#, m > 0 && n > 0 && n x + m > 0]&CDF[FRatioDistribution[n, m], x]//SimplifyFullSimplify[% - %%]β 分布是 UniformDistribution 变量的一个顺序分布：
OrderDistribution[{UniformDistribution[{0, 1}], n}, k]ExponentialDistribution 是按一定比例缩放后的贝塔分布的一个极限情况：
𝒟 = TransformedDistribution[u n, uBetaDistribution[1, n]];PDF[𝒟, x]Limit[%, n -> ∞]PDF[ExponentialDistribution[1], x]FullSimplify[% - %%, x ≠ 0]ExponentialDistribution 是 β 分布的一个转换：
TransformedDistribution[-Log[u], uBetaDistribution[α, 1]]TransformedDistribution[-Log[1 - u], uBetaDistribution[1, β]]KumaraswamyDistribution 是 β 分布的一个转换：
TransformedDistribution[x^1 / α, xBetaDistribution[1, β]]KumaraswamyDistribution 简化为 β 分布的一个特例：
PDF[KumaraswamyDistribution[α, 1], x]PDF[BetaDistribution[α, 1], x]//FullSimplify% - %%//SimplifyPERTDistribution 是 β 分布的一个转换：
𝒟 = TransformedDistribution[min + z(max - min), zBetaDistribution[1 + λ(c - min) / (max - min), 1 + λ(max - c) / (max - min)]];CDF[𝒟, x]//FullSimplify[#, min < c < max]&CDF[PERTDistribution[{min, max}, c, λ], x]FullSimplify[% - %%, min < c < max && λ ≥ 0]WignerSemicircleDistribution 是特殊 β 分布的一个转换：
𝒟 = TransformedDistribution[r(2 X - 1), XBetaDistribution[3 / 2, 3 / 2], Assumptions -> r > 0];PDF[𝒟, x]//FullSimplify[#, r > 0]&PDF[WignerSemicircleDistribution[r], x]//FullSimplify[#, r > 0]&%% - %//FullSimplify[#, r > 0]&DirichletDistribution 的单变量边缘分布是 β 分布：
MarginalDistribution[DirichletDistribution[{α1, α2, α3}], 1]MarginalDistribution[DirichletDistribution[{α1, α2, α3}], 2]BetaBinomialDistribution 是 BinomialDistribution 和 BetaDistribution 的混合分布：
ParameterMixtureDistribution[BinomialDistribution[n, p], pBetaDistribution[α, β]]BetaNegativeBinomialDistribution 是 NegativeBinomialDistribution 和BetaDistribution 的混合分布:
ParameterMixtureDistribution[NegativeBinomialDistribution[n, p], pBetaDistribution[α, β]]可能存在的问题 (2)
当 α 或 β 不是正实数时，BetaDistribution 没有定义：
Mean[BetaDistribution[0, 2]]
Mean[BetaDistribution[α, β]] /. {α -> I, β -> 3}
Wolfram Research (2007)，BetaDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaDistribution.html （更新于 2016 年）.
文本
Wolfram Research (2007)，BetaDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaDistribution.html （更新于 2016 年）.
CMS
Wolfram 语言. 2007. "BetaDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/BetaDistribution.html.
APA
Wolfram 语言. (2007). BetaDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BetaDistribution.html 年