NormalDistribution
NormalDistribution
NormalDistribution[μ,σ]
平均 μ，標準偏差 σ の正規(ガウス)分布を表す．
平均がゼロで標準偏差が1である正規分布を表す．
詳細
- 正規分布における値
の確率密度は 
に比例する． » - NormalDistributionでは μ は任意の実数，σ は任意の正の実数でよい．
- NormalDistributionでは，μ と σ は単位次元が等しい任意の数量でよい． »
- NormalDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »
予備知識
- NormalDistribution[μ,σ]は，実領域上で定義される，いわゆる「正規」統計分布を表す．この分布は，実数 μ および正の実数 σ でパラメータ化される．ただし，μ は分布の平均，σ は標準偏差，σ2は分散として知られている．正規分布の確率密度関数(PDF)は単峰で，その峰は平均
にあり，パラメータ σ はPDFの高さとその裾部の「厚さ」の両方を決定する．正規分布のPDFは，その最大値について対称であり，そのPDFの裾部はPDFが 
の大きい値について指数的に減少するという意味で「薄い」．（この動作は，分布のSurvivalFunctionを分析することで数量的に正確にすることができる．） 引数0の形式であるNormalDistribution[]はNormalDistribution[0,1]に等しく，標準正規分布と呼ばれることがある． - 正規分布は，そのPDFにガウス関数
が現れることから，ガウス分布と呼ばれることがある．非公式ではあるが，正規分布はそのPDFがベルのような形になることから，「ベル曲線」と言われることもある，しかし，CauchyDistribution，StudentTDistribution，LogisticDistribution等の他の分布も数量的に「ベル」の形に似て表示される点に注意が必要である． - 正規分布に従う確率変数は標準変量と呼ばれることがあり，標準正規分布は単位正規分布と呼ばれることもある．
- 正規分布は，最も広く見られる確率分布の1つであり，多くの分野に応用されている．例えば，正規分布に従う値はモンテカルロ法の応用において基本的な重要性を持つ．さらに，正規分布は，独立の増分
からなるいわゆるウィナー過程，連続時間確率過程 
の定義においても基本的な役割を果たしている．それぞれの増分は，独立で，
，かつ
について 
である同一正規分布に従う，また，パーセンタイル順位や 
スコアおよび 
スコアを含む確率値および統計値の多くが，正規分布から導かれている．さらに，中心極限定理のために，十分な数がある独立確率変数の平均は，ある種の仮定が満たされるならば，値を表現するもとの分布には無関係に，正規分布の近似となる．正規分布は，また，理想気体分子の速度，拡散中の粒子の位置，長期間に渡る温度ランプの動作等，数多くの物理現象をモデル化する際に自然に現れる．加えて，生体組織の大きさや空腹時の血糖レベルや血圧等の数量等多くの生物学現象に見られる変数も，その対数が正規分布に従うことが多い． - RandomVariateを使って，正規分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,NormalDistribution[μ,σ]]（より簡略すると xNormalDistribution[μ,σ]）を使って，確率変数 x が正規分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
- 確率密度関数および累積分布関数は，PDF[NormalDistribution[μ,σ],x]およびCDF[NormalDistribution[μ,σ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
- DistributionFitTestを使って，与えられたデータ集合が正規分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータから正規パラメトリック分布を推定することが，FindDistributionParametersを使ってデータを正規分布にフィットすることができる．ProbabilityPlotを使って記号正規分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号正規分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
- TransformedDistributionを使って変換された正規分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使って正規分布を含む高次元分布を構築することが，ProductDistributionを使って正規分布を含む独立成分分布の結合分布を計算することができる．
- NormalDistributionは他の多くの分布と密接に関係している．LogNormalDistribution，HalfNormalDistribution，NoncentralChiSquareDistribution，LevyDistributionを含む数多くの分布が，NormalDistributionを変換した形であると見ることができる．また，NormalDistributionはHyperbolicDistribution，StudentTDistribution，PoissonDistribution，BinomialDistributionを含む多くの関数の極限のケースであると考えることができる．加えて，NormalDistributionはExponentialPowerDistribution（PDF[NormalDistribution[μ,σ],x]はPDF[ExponentialPowerDistribution[2,μ,σ],x]に等しい），SkewNormalDistribution（PDF[NormalDistribution[μ,σ],x]はPDF[SkewNormalDistribution[μ,σ,0],x]に等しい），PearsonDistribution（PDF[NormalDistribution[μ,σ],x]はPDF[PearsonDistribution[3,σ-2,-μ σ-2,0,0,1],x]に等しい，ただし σ>0のとき）の特殊ケースであり，BinormalDistributionおよびMultinormalDistributionの周辺分布である．NormalDistributionは，StableDistribution，RiceDistribution，RayleighDistribution，MaxwellDistribution，LevyDistribution，LaplaceDistribution，JohnsonDistribution，ChiDistribution，ChiSquareDistributionと密接な関係がある．
例題
すべて開く すべて閉じる例 (4)
Plot[Table[PDF[NormalDistribution[0, σ], x], {σ, {.75, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]Plot[Table[PDF[NormalDistribution[μ, 1.5], x], {μ, {-1, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]PDF[NormalDistribution[μ, σ], x]Plot[Table[CDF[NormalDistribution[0, σ], x], {σ, {.75, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]Plot[Table[CDF[NormalDistribution[μ, 1.5], x], {μ, {-1, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]CDF[NormalDistribution[μ, σ], x]Mean[NormalDistribution[μ, σ]]Variance[NormalDistribution[μ, σ]]Median[NormalDistribution[μ, σ]]スコープ (7)
data = RandomVariate[NormalDistribution[1, 3], 10 ^ 4];Show[
Histogram[data, 20, "PDF"],
Plot[PDF[NormalDistribution[1, 3], x], {x, -9, 9}, PlotStyle -> Thick]]sample = RandomVariate[NormalDistribution[2, 3], 10 ^ 3];edist = EstimatedDistribution[sample, NormalDistribution[μ, σ]]サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, -6, 11}, PlotStyle -> Thick]]Skewness[NormalDistribution[μ, σ]]Kurtosis[NormalDistribution[μ, σ]]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[NormalDistribution[μ, σ], k]//Expand, {k, 5}], M]Moment[NormalDistribution[μ, σ], r]FormulaGrid[Table[CentralMoment[NormalDistribution[μ, σ], k], {k, 5}], CM]CentralMoment[NormalDistribution[μ, σ], r]FormulaGrid[Table[FactorialMoment[NormalDistribution[μ, σ], k]//Expand, {k, 5}], FM]FormulaGrid[Table[Cumulant[NormalDistribution[μ, σ], k], {k, 5}], C]Cumulant[NormalDistribution[μ, σ], r]Plot[Table[HazardFunction[NormalDistribution[-1, σ], x], {σ, {2, 3, 4}}]//Evaluate, {x, -8, -2}, Filling -> Axis]Plot[Table[HazardFunction[NormalDistribution[μ, 2], x], {μ, {-2, 0, 1}}]//Evaluate, {x, -4, 4}, Filling -> Axis]HazardFunction[NormalDistribution[μ, σ], x]Plot[Table[Quantile[NormalDistribution[-2, σ], q], {σ, {1 / 2, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Median[NormalDistribution[-2, σ]]]Plot[Table[Quantile[NormalDistribution[μ, 2], q], {μ, {-1, 1, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[NormalDistribution[μ, σ], q]母数でQuantityを一貫して使うとQuantityDistributionが与えられる：
height𝒟 = NormalDistribution[Quantity[MixedMagnitude[{5, 9}], MixedUnit[{"Feet", "Inches"}]], Quantity[5., "Inches"]]Quartiles[%]アプリケーション (11)
Probability[μ - σ < x < μ + σ, x NormalDistribution[μ, σ]]
Probability[μ - 2 σ < x < μ + 2σ, x NormalDistribution[μ, σ]]
Probability[μ - 3 σ < x < μ + 3σ, x NormalDistribution[μ, σ]]percentage[n_] := Probability[μ - n σ < x < μ + n σ, x NormalDistribution[μ, σ]]Table[N[percentage[n], 10], {n, 6}]
CDF[NormalDistribution[], z]
1 - CDF[NormalDistribution[], z]
2 CDF[NormalDistribution[], -Abs[z]]寿命が平均1000時間，標準偏差50時間でほぼ正規分布に従う電池がある．寿命が800時間から1000時間までに入る割合を求める：
p = Probability[Quantity[800, "Hours"] < x < Quantity[1000, "Hours"], xNormalDistribution[Quantity[1000, "Hours"], Quantity[50, "Hours"]]]100個の電池の中で寿命が800時間から1000時間までに入る個数を計算する：
Mean[BinomialDistribution[100, p]]N[%]一袋5ポンドで売られているコーヒー豆がある．この実際の重さは，平均5ポンド，分散0.01平方ポンド(lb
)の正規分布に従うとする．任意の袋の重さが少なくとも4ポンド15オンスになる確率を求める：
Probability[x > Quantity[MixedMagnitude[{4, 15}], MixedUnit[{"Pounds", "Ounces"}]], xNormalDistribution[Quantity[5, "Pounds"], Sqrt[Quantity[0.01, "Pounds"^2]]]]これは，直接SurvivalFunctionを使って求めることもできる：
SurvivalFunction[NormalDistribution[Quantity[5, "Pounds"], Sqrt[Quantity[0.01, "Pounds"^2]]], Quantity[MixedMagnitude[{4, 15}], MixedUnit[{"Pounds", "Ounces"}]]]ある会社が釘を製造している．この釘の長さは平均0.497インチ，標準偏差0.002インチで正規分布に従うとする．長さが0.5インチプラスマイナス0.004インチの仕様を満たす割合を求める：
len𝒟 = NormalDistribution[["0.497 in"], ["0.002 in"]]minlen = [".5 in"] - ["0.004 in"];maxlen = [".5 in"] + ["0.004 in"];Probability[minlen < len < maxlen, len len𝒟]CDFを使った直接計算：
CDF[ len𝒟, maxlen] - CDF[ len𝒟, minlen]ある会社が釘を製造している．この釘の長さは平均0.5インチで正規分布に従う．製造した釘の50%の長さが0.495インチより長く0.505インチより短い場合の標準偏差を求める：
Probability[Quantity[0.495, "Inches"] < x < Quantity[0.505, "Inches"], xNormalDistribution[Quantity[0.5, "Inches"], Quantity[σ, "Inches"]], Assumptions -> σ > 0]FindRoot[% == 0.5, {σ, 1.5}]平均5で標準偏差1.5の分布からサンプルを選ぶ．確率0.97でサンプルの平均が分布の平均の0.8以内になるためのサンプルの最小サイズ 
を求める：
prob = Probability[-0.8 + 5 < m < 0.8 + 5, mNormalDistribution[5, 1.5 / Sqrt[n]]]DiscretePlot[prob, {n, 1, 30}]
NMinimize[{n, prob ≥ 0.97}, {n, 12, 25}]乗客の体重と手荷物の重さを合わせたものは平均225ポンド，標準偏差50ポンドの正規分布に従う．ある飛行機の積載量の上限は1万ポンドで旅客定員は44名である．満席の場合に飛行機が過積載となる確率を求める：
totalWeightDist = TransformedDistribution[Subsuperscript[∑, k = 1, 44]Subscript[x, k], Table[Subscript[x, k]NormalDistribution[Quantity[225, "Pounds"], Quantity[50, "Pounds"]], {k, 44}]]Probability[x > Quantity[10000, "Pounds"], xtotalWeightDist]N[%]Graphics[{AbsolutePointSize[1], Point[RandomVariate[NormalDistribution[], {10 ^ 4, 2}]]}]Graphics3D[{AbsolutePointSize[1], Point[RandomVariate[NormalDistribution[], {10 ^ 4, 3}]]}]伝統的に，正規分布は前日終値からの株価変動率の分析に使われてきた．スタンダード＆プアーズ(S&P)500種指数の2000年1月1日から2009年1月1日までの日々の株価変動率の推定分布を求める：
sp500 = FinancialData["SP500", "FractionalChange",
{{2000, 1, 1}, {2009, 1, 1}, "Day"}]MinMax[sp500]edist = EstimatedDistribution[sp500, NormalDistribution[μ, σ]]hist = Histogram[sp500, Automatic, "PDF"];
Show[hist, Plot[PDF[edist, Quantity[x, "%"]], {x, -10, 12}, PlotStyle -> Thick, PlotRange -> All]]NProbability[x > 0.5, xedist]Mean[edist]ListLinePlot[RandomVariate[edist, 30], AxesLabel -> Automatic]LogisticDistributionは正規分布よりもよいフィットを与えることを示す：
LogisticEstimate = EstimatedDistribution[sp500, LogisticDistribution[μ, β]]Show[hist, Plot[{PDF[edist, Quantity[x, "%"]], PDF[LogisticEstimate, Quantity[x, "%"]]}, {x, -10, 12}, PlotStyle -> Thick, PlotRange -> All, PlotLegends -> {"Fit with normal distribution", "Fit with logistic distribution"}]]𝒫 = WhiteNoiseProcess[]data = RandomFunction[𝒫, {0, 40}];ListPlot[data, Filling -> Axis]特性と関係 (36)
TransformedDistribution[a z + b, zNormalDistribution[μ, σ]]TransformedDistribution[a1 z1 + a2 z2 + c, {z1NormalDistribution[μ1, σ1], z2NormalDistribution[μ2, σ2]}]TransformedDistribution[x + y, {xNormalDistribution[Subscript[μ, 1], Subscript[σ, 1]], yNormalDistribution[Subscript[μ, 2], Subscript[σ, 2]]}]Probability[u < -x + Mean[NormalDistribution[μ, σ]], uNormalDistribution[μ, σ]]Probability[u > x + Mean[NormalDistribution[μ, σ]], uNormalDistribution[μ, σ]]% - %%ParameterMixtureDistribution[NormalDistribution[p, Subscript[σ, 1]], pNormalDistribution[μ, Subscript[σ, 2]]]
正規(SN)JohnsonDistributionは正規分布である：
PDF[JohnsonDistribution["SN", μ, σ, γ, δ], x]PDF[NormalDistribution[γ - μ δ / σ, δ / σ], x]% - %%//FullSimplify[#, σ > 0 && δ > 0]&
が 
に近付くにつれ，StudentTDistributionは正規分布に近付く：
Limit[PDF[StudentTDistribution[ν], x], ν -> ∞]PDF[NormalDistribution[0, 1], x]% - %%正規分布はLogNormalDistributionを変換したものである：
TransformedDistribution[Log[u], uLogNormalDistribution[μ, σ]]正規分布の逆変換はLogNormalDistributionを与える：
TransformedDistribution[Exp[u], uNormalDistribution[μ, σ]]HalfNormalDistributionは切断正規分布である：
PDF[HalfNormalDistribution[θ], x]PDF[TruncatedDistribution[{0, ∞}, NormalDistribution[0, 1 / (θSqrt[2 / π])]], x]FullSimplify[%% - %]Block[{θ = 1}, Plot[{Legended[PDF[NormalDistribution[0, 1 / (θSqrt[2 / π])], x], "normal"], Legended[PDF[HalfNormalDistribution[θ], x], "half-normal"]}, {x, -3, 3}, Filling -> Axis]]HalfNormalDistributionは正規分布を変換したものである：
TransformedDistribution[Abs[x], xNormalDistribution[0, Sqrt[π / 2] / θ]]HalfNormalDistributionは正規分布を変換したものである：
TransformedDistribution[Abs[x - μ], xNormalDistribution[μ, Sqrt[π / 2] / θ]]NormalDistributionはExponentialPowerDistributionの特殊ケースである：
PDF[ExponentialPowerDistribution[2, μ, σ], x]PDF[NormalDistribution[μ, σ], x]% - %%//FullSimplify正規分布はSkewNormalDistributionの特殊ケースで形状母数が 
である：
PDF[SkewNormalDistribution[0, σ, 0], x]PDF[NormalDistribution[0, σ], x]% - %%SkewNormalDistributionは正規分布を変換したものである：
TransformedDistribution[α Abs[u] + v, {u, v}ProductDistribution[{NormalDistribution[0, σ / Sqrt[1 + α ^ 2] ], 2}]]標準正規分布に従う 
個の変数の平方和はChiSquareDistributionに従う：
𝒟 = TransformedDistribution[x ^ 2 + y ^ 2 + w ^ 2 + z ^ 2, {x, y, w, z}ProductDistribution[{NormalDistribution[], 4}]]正規分布に従う変数の平方和はNoncentralChiSquareDistributionに従う：
TransformedDistribution[u ^ 2 + v ^ 2 + w ^ 2, {uNormalDistribution[μ1, 1], vNormalDistribution[μ2, 1], wNormalDistribution[μ3, 1]}]標準正規分布に従う 
個の変数のノルムはChiDistributionに従う：
TransformedDistribution[Norm[{x, y, w, z}], {x, y, w, z}ProductDistribution[{NormalDistribution[], 4}]]標準正規分布に従う3個の変数のノルムはChiDistributionの一つ，MaxwellDistributionに従う：
𝒟 = TransformedDistribution[Norm[{x, y, z}], {x, y, z}ProductDistribution[{NormalDistribution[], 3}]]PDF[𝒟, x]PDF[MaxwellDistribution[1], x]% - %%標準正規分布に従う2個の変数のノルムはRayleighDistribution分布に従う：
TransformedDistribution[Norm[{x, y}], {x, y}ProductDistribution[{NormalDistribution[], 2}]]正規分布に従う2つの変数のノルムはRiceDistributionに従う：
𝒟 = TransformedDistribution[Norm[{u, v}], {u, v}ProductDistribution[{NormalDistribution[α / Sqrt[2], β], 2}]];Block[{α = .3, β = 2}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[RiceDistribution[α , β], x], {x, 0, 12}, PlotStyle -> Thick]]]NormalDistributionは，
と
について 
のHyperbolicDistributionの極限のケースである：
Limit[With[{β = 0, δ = σ^2α}, PDF[HyperbolicDistribution[λ, α, β, δ, μ], x]], α -> Infinity, Assumptions -> σ > 0 && {λ, μ, x}∈Reals]PDF[NormalDistribution[μ, σ], x]% - %%
，
，
，
が独立で正規分布に従うなら，
はLaplaceDistributionに従う：
𝒟 = TransformedDistribution[x y + u v, {x, y, u, v}ProductDistribution[{NormalDistribution[], 4}]];Show[Histogram[RandomVariate[𝒟, 10 ^ 4], {-5, 5, 0.5}, "PDF"], Plot[PDF[TruncatedDistribution[{-5, 5}, LaplaceDistribution[0, 1]], x], {x, -6, 6}, PlotStyle -> Thick]]CharacteristicFunctionの等価性を使って確かめる：
CharacteristicFunction[𝒟, t] == CharacteristicFunction[LaplaceDistribution[], t]
，
，
，
が独立で正規分布に従うなら，
はLaplaceDistributionに従う：
𝒟 = TransformedDistribution[w z - u v, {w, z, u, v}ProductDistribution[{NormalDistribution[], 4}]];Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 30, "PDF"], Plot[PDF[LaplaceDistribution[0, 1], x], {x, -6, 6}, PlotRange -> All, PlotStyle -> Thick]]CharacteristicFunctionの等価性を使って確かめる：
CharacteristicFunction[𝒟, t] == CharacteristicFunction[LaplaceDistribution[], t]正規分布に従う2つの変数の比はCauchyDistributionを示す：
TransformedDistribution[u / v, {u, v}ProductDistribution[{NormalDistribution[], 2}]]正規分布に従う変数の平方はGammaDistributionの特殊ケースであり，ChiSquareDistributionの特殊ケースでもある：
𝒟 = TransformedDistribution[u ^ 2, uNormalDistribution[]]PDF[𝒟, x]PDF[GammaDistribution[1 / 2, 2], x]Simplify[% - %%]LaplaceDistributionは正規分布とRayleighDistributionの母数混合分布である：
𝒟 = ParameterMixtureDistribution[NormalDistribution[μ, σ], σRayleighDistribution[ν]]StudentTDistributionは正規分布とGammaDistributionの母数混合分布である：
ParameterMixtureDistribution[NormalDistribution[μ, 1 / Sqrt[λ2]], λ2GammaDistribution[ν / 2, 2 / ν / σ^2], Assumptions -> σ > 0]LevyDistributionは正規分布を変換したものである：
TransformedDistribution[(1/x^2), xNormalDistribution[]]TransformedDistribution[(x - μ) ^ -2, xNormalDistribution[μ, σ]]正規分布はタイプ3のピアソン分布(PearsonDistribution)の特殊ケースである：
PDF[PearsonDistribution[3, σ^-2, -μ σ^-2, 0, 0, 1], x]//FullSimplify[#, σ > 0]&PDF[NormalDistribution[μ, σ], x]% - %%正規分布はStableDistributionである：
PDF[NormalDistribution[μ, σ], x]PDF[StableDistribution[0, 2, 0, μ, σ / Sqrt[2]], x]% - %%//Simplify正規分布はBinormalDistributionの周辺分布である：
MarginalDistribution[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], 1]MarginalDistribution[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], 2]正規分布はMultinormalDistributionの周辺分布である：
Σ = (| | | |
| --------- | --------- | --------- |
| σ1^2 | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2 | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2 |);MarginalDistribution[MultinormalDistribution[{μ1, μ2, μ3}, Σ], 1]MarginalDistribution[MultinormalDistribution[{μ1, μ2, μ3}, Σ], 2]MarginalDistribution[MultinormalDistribution[{μ1, μ2, μ3}, Σ], 3]NormalDistributionはMultinormalDistributionから得ることができる：
Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};TransformedDistribution[u + v, {u, v}MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]StudentTDistributionはNormalDistributionとChiSquareDistributionから得られる：
𝒟 = TransformedDistribution[z Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];PDF[𝒟, x]//FullSimplify[#, ν > 0]&PDF[StudentTDistribution[ν], x]//FunctionExpand//PowerExpandFullSimplify[% - %%, x ≠ 0]NoncentralStudentTDistributionはNormalDistributionとChiSquareDistributionから得られる：
𝒟 = TransformedDistribution[(z + δ)Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];Block[{δ = 3, ν = 15}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[NoncentralStudentTDistribution[ν, δ], x], {x, -10, 10}, PlotStyle -> Thick]]]VarianceGammaDistributionはGammaDistributionと正規分布から得ることができる：
dist = TransformedDistribution[μ + β * v + Sqrt[v] * u, {uNormalDistribution[0, 1], vGammaDistribution[λ, 2 / (α - β) / (α + β)]}];MomentGeneratingFunction[dist, x]E^x μ(1 / (1 + (2 x β/-α^2 + β^2)) / (1 + (x^2/-α^2 + β (2 x + β))))^λ//SimplifyMomentGeneratingFunction[VarianceGammaDistribution[λ, α, β, μ], x]//Simplify%% / %//FullSimplify[#, λ > 0 && β > 0]&考えられる問題 (2)
NormalDistributionは，μ が実数でないときは定義されない：
Mean[NormalDistribution[3 + I, 6]]
NormalDistributionは，σ が正の実数でないときは定義されない：
Mean[NormalDistribution[3, -6]]
Mean[NormalDistribution[μ, σ]] /. {μ -> I, σ -> -1}おもしろい例題 (1)
累積分布関数の等高線を持つ σ のさまざまな値についての確率密度関数：
cdf = Function[{x, σ}, Evaluate[CDF[NormalDistribution[0, σ], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[NormalDistribution[0, σ], x], {x, -5, 5}, {σ, 1, 5}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 100, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All, Exclusions -> None], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
An Elementary Introduction to the Wolfram Language
Wolfram Research (2007), NormalDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/NormalDistribution.html （2016年に更新）.
テキスト
Wolfram Research (2007), NormalDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/NormalDistribution.html （2016年に更新）.
CMS
Wolfram Language. 2007. "NormalDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/NormalDistribution.html.
APA
Wolfram Language. (2007). NormalDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NormalDistribution.html