WOLFRAM

Wolfram 语言与系统参考资料中心

FindDistribution[data]

找出一个简单的函数形式以拟合 data 的分布.

FindDistribution[data,n]

找出最多 n 个最佳分布.

FindDistribution[data,n,prop]

返回最多 n 个与属性 prop 关联的最佳分布.

FindDistribution[data,n,{prop1,prop2,…}]

返回最多 n 个与属性 prop1、prop2 等关联的最佳分布.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
TargetFunctions  
PerformanceGoal  
RandomSeeding  
应用  
以特定字母开头的单词的长度  
文字频率  
丹麦的黑色素瘤  
艾滋病的感染时间  
更换导尿管后肾脏感染的时间  
属性和关系  
参见
相关指南
历史
按以下格式引用：

FindDistribution

FindDistribution[data]

找出一个简单的函数形式以拟合 data 的分布.

FindDistribution[data,n]

找出最多 n 个最佳分布.

FindDistribution[data,n,prop]

返回最多 n 个与属性 prop 关联的最佳分布.

FindDistribution[data,n,{prop1,prop2,…}]

返回最多 n 个与属性 prop1、prop2 等关联的最佳分布.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建均匀分布的随机整数列表：

Wolfram Language code: RandomInteger[10, 100]

从数据中找出底层的分布：

Wolfram Language code: FindDistribution[%]

从指数分布生成数据样本：

Wolfram Language code: 𝒟 = ExponentialDistribution[1]; data = RandomVariate[𝒟, 1000];

找出数据的最佳分布：

Wolfram Language code: estimated𝒟 = FindDistribution[data]

比较原始分布和估计分布的 PDF：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[estimated𝒟, x]}, {x, 0, 10}, PlotLegends -> {"𝒟", "e𝒟"}]

返回最佳的三个分布：

Wolfram Language code: FindDistribution[data, 3]

比较它们的贝叶斯信息量准则值和赤池信息量准则值：

Wolfram Language code: FindDistribution[data, 3, {"BIC", "AIC"}]

范围  (3)

从混合分布生成数据样本：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 1}, {ExponentialDistribution[1], NormalDistribution[5, 0.8]}];
Wolfram Language code: data = RandomVariate[𝒟, 1000];

从这些数据估计最佳分布：

Wolfram Language code: e𝒟 = FindDistribution[data]

比较原始分布和估计分布的 PDF：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[e𝒟, x]}, {x, -8, 10}, PlotLegends -> {"𝒟", "e𝒟"}, PlotRange -> All]

估计特定分布的参数：

Wolfram Language code: 𝒟 = WeibullDistribution[1, 2];
Wolfram Language code: data = RandomVariate[𝒟, 1000];

默认情况下，FindDistribution 返回比较简单的分布：

Wolfram Language code: e𝒟 = FindDistribution[data]

指定寻找的分布类型：

Wolfram Language code: e𝒟 = FindDistribution[data, TargetFunctions -> {WeibullDistribution}]

从指数分布生成数据样本：

Wolfram Language code: 𝒟 = ExponentialDistribution[1]; data = RandomVariate[𝒟, 1000];

生成包含前两种最佳分布全部属性的 Dataset 对象：

Wolfram Language code: report = FindDistribution[data, 2, All]

选项  (5)

TargetFunctions  (3)

从混合分布生成数据样本：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 1}, {ExponentialDistribution[1], NormalDistribution[5, 0.8]}];
Wolfram Language code: data = RandomVariate[𝒟, 1000];

估计指定分布的参数：

Wolfram Language code: e𝒟 = FindDistribution[data, TargetFunctions -> {NormalDistribution, GammaDistribution}]

比较原始分布和估计分布的 PDF：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[e𝒟, x]}, {x, -8, 10}, PlotLegends -> {"𝒟", "e𝒟"}, PlotRange -> All]

间歇泉喷发之间的时间：

Wolfram Language code: waiting = ExampleData[{"Statistics", "OldFaithful"}][[All, 2]];

估计数据的分布：

Wolfram Language code: e𝒟1 = FindDistribution[waiting]

当作连续数据处理时，估计分布：

Wolfram Language code: e𝒟2 = FindDistribution[waiting, TargetFunctions -> "Continuous"]

当作连续数据处理时，用 GammaDistribution 估计数据的分布：

Wolfram Language code: e𝒟3 = FindDistribution[waiting, TargetFunctions -> {GammaDistribution}]

比较数据的直方图和估计分布的 PDF：

Wolfram Language code: legend = SwatchLegend[{Red, ColorData[97, 1], ColorData[97, 2]}, {"e𝒟1", "e𝒟2", "e𝒟3"}];
Wolfram Language code: Show[Histogram[waiting, 20, "ProbabilityDensity"], DiscretePlot[{PDF[e𝒟1, x]}, {x, 0, 100}, PlotStyle -> {PointSize[.02], Red}], Plot[{PDF[e𝒟2, x], PDF[e𝒟3, x]}, {x, 0, 100}, PlotLegends -> legend]]

估计假设先验的特定分布的参数：

Wolfram Language code: magnitudes = Select[ExampleData[{"Statistics", "USEarthquakes"}], #[[1]] ≥ 1935&][[All, 7]];

1935–1989 年间美国的地震震级有两种模式：

Wolfram Language code: h = Histogram[magnitudes, 20, "ProbabilityDensity"]

在不用 TargetFunctions 的情况下估计最佳拟合：

Wolfram Language code: Subscript[``e𝒟``, 1] = FindDistribution[magnitudes]

在使用先验分布的情况下估计最佳拟合：

Wolfram Language code: Subscript[``e𝒟``, 2 ] = FindDistribution[magnitudes, TargetFunctions -> {{10, 2} -> {CauchyDistribution, GammaDistribution}}]

比较估计分布的 PDF 和直方图：

Wolfram Language code: Show[h, Plot[{PDF[Subscript[``e𝒟``, 1], x], PDF[Subscript[``e𝒟``, 2 ], x]}, {x, 0, 10}, PlotStyle -> Thick, PlotRange -> All]]

PerformanceGoal  (1)

从混合分布生成数据样本：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 2}, {ChiDistribution[0.6], GammaDistribution[20, 1]}]
Wolfram Language code: data = RandomVariate[𝒟, 10000];

估算大数据集的最佳拟合并比较在不同 PerformanceGoal 设置下的 AbsoluteTiming：

Wolfram Language code: AbsoluteTiming[e𝒟1 = FindDistribution[data, PerformanceGoal -> "Speed"]]
Wolfram Language code: AbsoluteTiming[e𝒟2 = FindDistribution[data, PerformanceGoal -> "Quality"]]

比较解的 LogLikelihood：

Wolfram Language code: LogLikelihood[#, data]& /@ {e𝒟1, e𝒟2}

RandomSeeding  (1)

根据混合分布产生数据样本：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 2}, {NormalDistribution[-6, 1], GammaDistribution[20, 1]}]
Wolfram Language code: data = RandomVariate[𝒟, 1000];

比较 FindDistribution 的几次计算，注意它们的不同之处：

Wolfram Language code: Table[FindDistribution[data], 3]

用选项 RandomSeeding 避免不同的结果：

Wolfram Language code: Table[FindDistribution[data, RandomSeeding -> 1], 3]

应用  (5)

以特定字母开头的单词的长度  (1)

字典中以不同元音字母开头的全部英语单词的长度：

Wolfram Language code: letters = {"a", "e", "i", "o", "u", "y"};
Wolfram Language code: worddata = Table[StringLength /@ DictionaryLookup[l ~~ ___], {l, letters}];

估计不同字母的分布：

Wolfram Language code: e𝒟 = Table[FindDistribution[i, MaxItems -> 1], {i, worddata}]

比较原始数据的直方图和估计分布的 PDF：

Wolfram Language code: Partition[Table[Show[Histogram[worddata[[i]], {Range[25] - 1 / 2}, "ProbabilityDensity", PlotLabel -> letters[[i]]], DiscretePlot[PDF[e𝒟[[i]], x], {x, 0, 25}, PlotRange -> All, PlotStyle -> PointSize[.025]], ImageSize -> Small], {i, Length[letters]}], 3]//Grid

文字频率  (1)

计算独立宣言中单词的出现次数：

Wolfram Language code: text = ExampleData[{"Text", "DeclarationOfIndependence"}, "Words"];
Wolfram Language code: wordCount = Tally[text][[All, 2]];

估计字数的分布：

Wolfram Language code: e𝒟 = FindDistribution[wordCount, MaxItems -> 1]

比较原始数据的直方图和估计分布的 PDF：

Wolfram Language code: Show[Histogram[wordCount, {0.5, 9.5, 1}, "ProbabilityDensity"], DiscretePlot[PDF[e𝒟, x], {x, 1, 10}, PlotStyle -> PointSize[Medium], PlotRange -> All]]

丹麦的黑色素瘤  (1)

黑色素瘤病人的年龄：

Wolfram Language code: melanomaAge = ExampleData[{"Statistics", "DenmarkMelanoma"}][[All, 4]];

估计数据的分布：

Wolfram Language code: e𝒟 = FindDistribution[melanomaAge]

比较数据的直方图和估计分布的 PDF：

Wolfram Language code: Show[Histogram[melanomaAge, {4, 95, 4}, "ProbabilityDensity"], Plot[PDF[e𝒟, x], {x, 4, 95}, PlotStyle -> Thick, PlotRange -> All]]

艾滋病的感染时间  (1)

以年计的艾滋病感染时间：

Wolfram Language code: aids = ExampleData[{"Statistics", "TimeToAIDS"}][[All, 1]];

估计数据的分布：

Wolfram Language code: e𝒟 = FindDistribution[aids]

比较数据的直方图和估计分布的 PDF：

Wolfram Language code: Show[Histogram[aids, {0, 8, 0.65}, "ProbabilityDensity"], Plot[PDF[e𝒟, x], {x, 0, 8}, PlotStyle -> Thick, PlotRange -> All]]

更换导尿管后肾脏感染的时间  (1)

以月计的肾脏感染时间：

Wolfram Language code: KidneyInfection = ExampleData[{"Statistics", "KidneyInfection"}][[All, 1]];

估计数据的分布：

Wolfram Language code: e𝒟 = FindDistribution[KidneyInfection]

比较数据的直方图和估计分布的 PDF：

Wolfram Language code: Show[Histogram[KidneyInfection, {0, 28, 2}, "ProbabilityDensity"], Plot[PDF[e𝒟, x], {x, 0, 28}, PlotStyle -> Thick, PlotRange -> All]]

属性和关系  (1)

默认情况下，FindDistributionParameters 使用最大似然估计固定分布的分布参数. FindDistribution 则使用完整的贝叶斯方法，通过将贝叶斯信息准则与分布的先验相结合，以选择最佳分布和最佳参数.

从 StudentTDistribution 中抽样生成数据：

Wolfram Language code: SeedRandom[5] data = RandomVariate[StudentTDistribution[1, 1, 4], 800]; Histogram[data, {-10, 10, Automatic}, "ProbabilityDensity"]

用 FindDistribution 估计拟合数据的最佳分布：

Wolfram Language code: dist1 = FindDistribution[data, RandomSeeding -> 1]

用 FindDistributionParameters 估计最佳参数，假定为 StudentTDistribution：

Wolfram Language code: distribution = StudentTDistribution[α, β, ν]; estimatedParameters = FindDistributionParameters[data, distribution]; dist2 = distribution /. estimatedParameters

尽管 StudentTDistribution 将对数似然性最小化，但与之相比，LogisticDistribution 具有更大的先验概率和较小的复杂性.

比较各自的 LogLikelihood：

Wolfram Language code: LogLikelihood[#, data]& /@ {dist1, dist2}

如果想要找到与 FindDistributionParameters 大致相近的参数，可以使用选项 TargetFunctions：

Wolfram Language code: dist3 = FindDistribution[data, TargetFunctions -> {StudentTDistribution}]
Wolfram Research (2015)，FindDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindDistribution.html （更新于 2017 年）.

文本

Wolfram Research (2015)，FindDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindDistribution.html （更新于 2017 年）.

CMS

Wolfram 语言. 2015. "FindDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/FindDistribution.html.

APA

Wolfram 语言. (2015). FindDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FindDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_finddistribution, author="Wolfram Research", title="{FindDistribution}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/FindDistribution.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_finddistribution, organization={Wolfram Research}, title={FindDistribution}, year={2017}, url={https://reference.wolfram.com/language/ref/FindDistribution.html}, note=[Accessed: 01-November-2026]}