Wolfram 语言与系统参考资料中心

ContourPlot3D

ContourPlot3D[f,{x,x_min,x_max},{y,y_min,y_max},{z,z_min,z_max}]

生成关于 x、y 和 z 的函数 f 的三维等高图.

ContourPlot3D[f==g,{x,x_min,x_max},{y,y_min,y_max},{z,z_min,z_max}]

绘制的等值面.

ContourPlot3D[…,{x,y,z}∈reg]

将变量 {x,y,z} 置于几何区域 reg 中.

范例

打开所有单元关闭所有单元

基本范例 (4)

绘制一个三维等值面：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

绘制数个等值面：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

在半径为三的球上绘制轮廓：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, y, z}∈Ball[{0, 0, 0}, 3]]

用样式来突出特征：

Wolfram Language code:

ContourPlot3D[x ^ 4 + y ^ 4 + z ^ 4 - (x ^ 2 + y ^ 2 + z ^ 2) ^ 2 + 3(x ^ 2 + y ^ 2 + z ^ 2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, ContourStyle -> Directive[Orange, Opacity[0.8], Specularity[White, 30]]]

范围 (16)

取样 (6)

绘制几何区域：

Wolfram Language code: ContourPlot3D[x + y + z, {x, y, z}∈Ball[]]

绘制一个隐式定义的区域：

Wolfram Language code: ContourPlot3D[x y z, {x, y, z}∈ImplicitRegion[x + y <= z, {x, y, z}]]

对于函数值变化较快的区域，选择较多的取样点：

Wolfram Language code: ContourPlot3D[Sin[x y] == z, {x, 0, 2}, {y, 0, 2}, {z, -1, 1}, Mesh -> All, MaxRecursion -> 1]

排除函数值非实数的区域：

Wolfram Language code: ContourPlot3D[Sqrt[x y z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

用 PlotPoints 和 MaxRecursion 控制自适应取样：

Wolfram Language code:

Grid[Table[ContourPlot3D[Sin[3x]Sin[3y]Sin[3z] == 1 / 2, {x, 0, 3}, {y, 0, 3}, {z, -1, 1}, Mesh -> None, BoxRatios -> Automatic, PlotPoints -> pp, MaxRecursion -> mr], {mr, {0, 1}}, {pp, {5, 10}}]]

用 RegionFunction 显示内部特征：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> 5, RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], ContourStyle -> {Red, Orange, Yellow, Green, Blue}, Mesh -> None]

演示 (10)

添加标签：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesEdge -> {{-1, -1}, {1, -1}, {-1, -1}}, Ticks -> None, Mesh -> 5, AxesLabel -> {x, y, z}, PlotLabel -> x ^ 2 + y ^ 2 - z ^ 2 == 1]

根据高度对曲面着色：

Wolfram Language code:

ContourPlot3D[16x ^ 3 + 16y ^ 3 - 31z ^ 3 + 24x ^ 2z - 48x ^ 2y - 48x y ^ 2 + 24y ^ 2z - 93.5307z ^ 2 - 72z == 0, {x, -2, 2}, {y, -2, 2}, {z, -2.3, 2}, ColorFunction -> Function[{x, y, z, f}, ColorData["Rainbow"][z]], Mesh -> 4]

应用样式到等值面上：

Wolfram Language code:

ContourPlot3D[x ^ 4 + y ^ 4 + z ^ 4 - x ^ 2 - y ^ 2 - z ^ 2 + 0.5 == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, PlotPoints -> 35, ContourStyle -> Directive[Specularity[White, 50], Orange], Lighting -> "Neutral"]

用显式样式来显示多重隐式表面：

Wolfram Language code:

ContourPlot3D[{Abs[Sin[x]Sin[y]Sin[z]] == 0.5, Abs[Cos[x]Cos[y]Cos[z]] == 0.5}, {x, 0, 3}, {y, 0, 3}, {z, 0, 3}, ContourStyle -> {Red, Blue}, Mesh -> None]

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, Contours -> {-3, 0, 3}, ContourStyle -> {Purple, Green, Cyan}, Mesh -> 5, MeshStyle -> GrayLevel[0.3], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0]]

用透明度表现内部特征：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ContourStyle -> Opacity[0.5], Mesh -> None, ColorFunction -> (Hue[#4 / 4]&)]

使用一个迭加的网格线：

Wolfram Language code:

ContourPlot3D[x ^ 2 - y ^ 2 == z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, MeshFunctions -> {#1 - #2&, #1 + #2&}, MeshStyle -> {Purple, Orange}, Lighting -> "Neutral", ContourStyle -> Gray]

在网格线中填充不同的颜色：

Wolfram Language code:

ContourPlot3D[x ^ 2 - y ^ 2 == z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, MeshFunctions -> {#1 - #2&, #1 + #2&}, MeshShading -> {{Yellow, Blue}, {Green, Cyan}}]

自动具有等高值的图例样式：

Wolfram Language code:

ContourPlot3D[Sqrt[x y z], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ContourStyle -> {Red, Blue, Green}, PlotLegends -> Automatic]

带有表达式的图例等高线：

Wolfram Language code:

ContourPlot3D[{Abs[Sin[x]Sin[y]Sin[z]] == 0.5, Abs[Cos[x]Cos[y]Cos[z]] == 0.5}, {x, 0, 3}, {y, 0, 3}, {z, 0, 3}, ContourStyle -> {Green, Orange}, Mesh -> None, PlotLegends -> "Expressions"]

使用高对比色彩方案中具有深色背景的主题：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotTheme -> "Marketing"]

反转轴上的标尺：

Wolfram Language code:

ContourPlot3D[x ^ 2 + x y - z ^ 2, {x, -10, 10}, {y, -10, 10}, {z, -10, 10}, ScalingFunctions -> {"Reverse", None, None}]

选项 (102)

Axes (2)

默认情况下，ContourPlot3D 绘制 Axes：

Wolfram Language code: ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

用 AxesFalse 关闭坐标轴：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> False]

绘制 ContourPlot3D，依次单独显示各个坐标轴：

Wolfram Language code:

{ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> {True, False, False}], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> {False, True, False}], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> {False, False, True}]}

AxesLabel (4)

默认情况下不显示坐标轴的标签：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> True]

在轴上放置标签：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> True, AxesLabel -> z]

指定坐标轴的标签：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> True, AxesLabel -> {X, Y, Z}]

根据 ContourPlot3D 中指定的变量设定标签：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Axes -> True, AxesLabel -> Automatic]

AxesOrigin (2)

自动确定坐标轴的位置：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == z ^ 4, {x, -10, 10}, {y, -10, 10}, {z, -2, 2}]

指定坐标轴的原点：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == z ^ 4, {x, -10, 10}, {y, -10, 10}, {z, -2, 2}, AxesOrigin -> {0, 0, 0}]

AxesStyle (4)

改变坐标轴的样式：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesStyle -> StandardRed]

指定每个轴的样式：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesStyle -> {{Thick, StandardBrown}, {Thick, StandardBlue}, {Thick, StandardGreen}}]

为坐标轴和刻度指定不同的样式：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesStyle -> StandardGreen, TicksStyle -> StandardGray]

为坐标轴和标签指定不同的样式：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesStyle -> StandardGreen, LabelStyle -> StandardGray]

BoundaryStyle (3)

在等值面周边使用一个红色的边界线：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, BoundaryStyle -> Red, Mesh -> None]

用 None 省略边界：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, BoundaryStyle -> None, Mesh -> None]

BoundaryStyle 应用于 RegionFunction 切割的洞：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, BoundaryStyle -> Red, Mesh -> None, RegionFunction -> Function[{x, y, z, w}, x ^ 2 + y ^ 2 + z ^ 2 ≤ 4]]

BoxRatios (1)

用 Automatic 显示曲面的自然尺度：

Wolfram Language code: ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -1, 1}]

Wolfram Language code: ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -1, 1}, BoxRatios -> Automatic]

ColorFunction (5)

根据、、，或的值，对等值面着色：

Wolfram Language code:

Table[ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ColorFunction -> Function[{x, y, z, f}, Evaluate[c]], PlotLabel -> c, Axes -> None], {c, {Hue[x], Hue[y], Hue[z], Hue[f]}}]

用一个预定义的颜色梯度：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Contours -> 4, ColorFunction -> "DarkRainbow"]

ColorFunction 具有比 ContourStyle 更高的优先级：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Contours -> 4, ColorFunction -> "DarkRainbow", ContourStyle -> Directive[Opacity[0.5], Red]]

当时用红色：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ColorFunction -> Function[{x, y, z, f}, If[z < 0, Red, Green]], ColorFunctionScaling -> False]

ColorFunction 具有比 MeshShading 更低的优先级：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ColorFunction -> Function[{x, y, z, f}, Hue[z]], MeshFunctions -> {#3&}, MeshShading -> {Automatic, StandardGray}]

ColorFunctionScaling (2)

用尺度不缩放的值对等值面着色：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, Contours -> 4, ColorFunction -> Function[{x, y, z, f}, Hue[f / 5]], ColorFunctionScaling -> False]

使用基于坐标值的叠加密度：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 == z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ColorFunction -> Function[{x, y, z, f}, Hue[Sin[x]Sin[y]]], ColorFunctionScaling -> False, Mesh -> None]

Contours (4)

用 5 个等间距的等值面：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> 5, Mesh -> None]

自动选择等值面：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> Automatic, Mesh -> None]

用指定等值面：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> {-2, 2}, Mesh -> None]

用指定样式的指定等值面：

Wolfram Language code:

ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> {{-2, Red}, {2, Blue}}, Mesh -> None]

ContourStyle (8)

用透明的等值面：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, ContourStyle -> Opacity[0.5]]

各等值面使用不同的颜色：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, ContourStyle -> {Red, Green, Blue}]

用 FaceForm 在里面和外面设置不同的颜色：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> 5, ContourStyle -> {FaceForm[Yellow, Blue]}]

对等值面选择交替的样式：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> 4, Mesh -> None, ContourStyle -> {Blue, Opacity[0.5]}]

对所有等式使用相同的样式：

Wolfram Language code:

ContourPlot3D[Evaluate[Table[x ^ 2 + y ^ 2 + z ^ 2 == i, {i, 1, 9, 1.5}]], {x, 0, 2}, {y, 0, 2}, {z, 0, 2}, Contours -> 6, Mesh -> None, ContourStyle -> Directive[Opacity[0.5], Orange]]

对不同的等式使用不同的样式：

Wolfram Language code:

ContourPlot3D[{x ^ 2 + y ^ 2 + z ^ 2 == 2, x ^ 2 + y ^ 2 == z ^ 2}, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, ContourStyle -> {Red, Yellow}]

ColorFunction 具有比 ContourStyle 更高的优先级：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2 == 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, ContourStyle -> Directive[Opacity[0.5], Red], ColorFunction -> Function[{x, y, z, f}, Hue[z]]]

MeshShading 具有比 ContourStyle 更高的优先级：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2 == 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, MeshFunctions -> {#3&}, ContourStyle -> Directive[Opacity[0.5], Yellow], MeshShading -> {Red, Automatic}]

EvaluationMonitor (2)

显示 ContourPlot3D 对一个函数取样的位置：

Wolfram Language code:

ListPointPlot3D[Reap[ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, EvaluationMonitor :> Sow[{x, y, z}], PlotPoints -> 5]][[-1, 1]], BoxRatios -> Automatic, PlotStyle -> PointSize[Tiny]]

统计对进行计算的次数：

Wolfram Language code: Block[{k = 0}, ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, EvaluationMonitor :> k++];k]

ImageSize (7)

使用已命名尺寸，如 Tiny、Small、Medium 和 Large：

Wolfram Language code:

{ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> Tiny], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> Small]}

指定绘图的高度：

Wolfram Language code:

{ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> 150], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AspectRatio -> 1.5, ImageSize -> 150]}

为不同高宽比的图形指定相同的高度：

Wolfram Language code:

{ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> {Automatic, 150}], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AspectRatio -> .75, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定的大小：

Wolfram Language code:

{ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> UpTo[200]], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AspectRatio -> .75, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> {200, 200}, Background -> StandardBlue]

设置 AspectRatioFull 将填充可用空间：

Wolfram Language code:

ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AspectRatio -> Full, ImageSize -> {200, 200}, Background -> StandardBlue]

使用允许的最大宽度和高度：

Wolfram Language code:

{ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> {UpTo[150], UpTo[100]}], ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

用 ImageSizeFull 填充对象中的可用空间：

Wolfram Language code:

Framed[Pane[ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ImageSize -> Full, Background -> StandardBlue], {200, 100}]]

以可用空间的比例指定图像的大小：

Wolfram Language code:

Framed[Pane[ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardBlue], {200, 200}]]

MaxRecursion (1)

细化等值面中值变化较快的区域：

Wolfram Language code: Table[ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> All, MaxRecursion -> r], {r, {0, 1}}]

Mesh (6)

显示最初和最终的取样网格线：

Wolfram Language code:

{ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -1, 1}, Mesh -> Full, MaxRecursion -> 1], ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -1, 1}, Mesh -> All, MaxRecursion -> 1]}

用 None 不绘制任何网格线：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None]

每个方向绘制 5 个网格层：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> 5, MeshFunctions -> {#1&, #2&, #3&}]

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> 5, MeshFunctions -> {#1&, #2&, #3&}]

在方向绘制 5 个网格层，在方向绘制 10 个网格层：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> {5, 10}, MeshFunctions -> {#1&, #2&}]

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> {5, 10}, MeshFunctions -> {#1&, #2&}]

在指定值处使用网格线：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> {{0}, {0}}, MeshFunctions -> {#1&, #2&}]

不同的网格线使用不同的样式：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> {{{0, Thick}}, {{0, Red}}}]

MeshFunctions (2)

在、和方向使用等间隔的网格：

Wolfram Language code:

Table[ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2 == 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotLabel -> f, MeshFunctions -> {Function[{x, y, z}, f]}, Axes -> None], {f, {x, y, z}}]

根据径向距离设置的网格：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshFunctions -> (Norm[{#1, #2, #3}]&)]

MeshShading (5)

在方向交替使用红色和蓝色：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshFunctions -> {#3&}, MeshShading -> {Red, Blue}]

在样式设置时，MeshShading 具有比 ContourStyle 更高的优先级：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshFunctions -> {#3&}, MeshShading -> {None, Blue}]

通过设置 MeshShading 为 Automatic，用 ContourStyle 作用某些部分：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshFunctions -> {#3&}, MeshShading -> {Red, Automatic}, ContourStyle -> Directive[Opacity[0.5], Yellow]]

MeshShading 可以同 ColorFunction 连用：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshFunctions -> {#3&}, MeshShading -> {StandardGray, Automatic}, ColorFunction -> Function[{x, y, z, f}, Hue[z]]]

填充多重网格函数定义的区域：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshShading -> Table[RGBColor[r, g, b], {r, 0, 1, 1 / 5}, {g, 0, 1, 1 / 5}, {b, 0, 1, 1 / 5}], Mesh -> 5, Lighting -> "Neutral"]

MeshStyle (2)

在方向使用虚线网格：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, MeshFunctions -> {#1&}, MeshStyle -> Dashed, Mesh -> 5]

在方向使用虚线网格，在方向使用蓝色网格：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> 5, MeshFunctions -> {#1&, #2&}, MeshStyle -> {Dashed, Blue}]

NormalsFunction (3)

自动计算法线：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None]

对所有多边形，用 None 获得平面阴影：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, NormalsFunction -> None, Mesh -> None]

改变曲面上的实际法线：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, NormalsFunction -> Function[{x, y, z, u, v}, RandomReal[{-1, 1}, {3}]]]

PerformanceGoal (2)

生成一个高质量的图形：

Wolfram Language code: Timing[ContourPlot3D[Sin[x ^ 2 + y ^ 2] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PerformanceGoal -> "Quality"]]

强调性能，可能会牺牲质量：

Wolfram Language code: Timing[ContourPlot3D[Sin[x ^ 2 + y ^ 2] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PerformanceGoal -> "Speed"]]

PlotLegends (3)

用表达式作为图例：

Wolfram Language code:

ContourPlot3D[{x ^ 2 + y ^ 2 - z ^ 2 == 1, x ^ 2 + y ^ 2 + z ^ 2 == 2}, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ContourStyle -> {Yellow, Red}, PlotLegends -> "Expressions"]

使用 Placed 改变图例放置的位置：

Wolfram Language code:

ContourPlot3D[{x ^ 2 + y ^ 2 - z ^ 2 == 1, x ^ 2 + y ^ 2 + z ^ 2 == 2}, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ContourStyle -> {Yellow, Red}, PlotLegends -> Placed["Expressions", Below]]

用 SwatchLegend 来修改图例：

Wolfram Language code:

ContourPlot3D[{x ^ 2 + y ^ 2 - z ^ 2 == 1, x ^ 2 + y ^ 2 + z ^ 2 == 2}, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, ContourStyle -> {Yellow, Red}, PlotLegends -> SwatchLegend["Expressions", LegendFunction -> "Frame"]]

PlotPoints (1)

用较多的初始点获得一个更平滑的等值面：

Wolfram Language code:

Table[ContourPlot3D[Sin[x ^ 2 + y ^ 2] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, MaxRecursion -> 0, PlotPoints -> pp], {pp, {5, 10, 15, 20}}]

PlotRange (2)

在 Full 的、、范围上显示等值面：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2 == 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

自动计算、、的范围：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2 == 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotRange -> Automatic]

PlotTheme (4)

使用带有细节网格线、刻度和图例的主题：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotTheme -> "Detailed"]

关闭网格线：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotTheme -> "Detailed", FaceGrids -> None]

使用带有最小样式化的主题：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, PlotTheme -> "Minimal"]

生成有厚度的曲面于三维打印：

Wolfram Language code:

ContourPlot3D[x ^ 4 + y ^ 4 + z ^ 4 - (x ^ 2 + y ^ 2 + z ^ 2) ^ 2 + 3(x ^ 2 + y ^ 2 + z ^ 2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotTheme -> "ThickSurface"]

RegionFunction (2)

选择、和的区域：

Wolfram Language code:

Table[ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, Axes -> None, Contours -> 4, RegionFunction -> Function[{x, y, z}, Evaluate[f]], PlotLabel -> f], {f, {-1 / 2 < x < 1 / 2, -1 / 2 < y < 1 / 2, -1 / 2 < z < 1 / 2}}]

移除楔可以看到隐藏的特征：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 + z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Contours -> 4, Mesh -> None, Axes -> None, RegionBoundaryStyle -> None, RegionFunction -> Function[{x, y, z}, x < 0 || y > 0]]

RegionBoundaryStyle (4)

显示正在绘制的区域：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2 == 0, {x, y, z}∈Ball[]]

显示区域功能定义的区域：

Wolfram Language code:

ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2 == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, RegionFunction -> Function[{x, y, z, f}, x + y > 0]]

用 None 不绘制区域：

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2 == 0, {x, y, z}∈Ball[], RegionBoundaryStyle -> None]

用自定义 RegionBoundaryStyle:

Wolfram Language code: ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2 == 0, {x, y, z}∈Ball[], RegionBoundaryStyle -> Directive[Yellow, Opacity[.8]]]

ScalingFunctions (4)

默认情况下，ContourPlot3D 在所有方向上使用线性比例：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == 1 / z, {x, -2, 2}, {y, -2, 2}, {z, 0, 20}]

在方向使用对数标尺：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 == 1 / z, {x, -2, 2}, {y, -2, 2}, {z, 0, 20}, ScalingFunctions -> {None, None, "Log"}, PlotRange -> All]

反转轴的坐标方向：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == 1 / z, {x, -2, 2}, {y, -2, 2}, {z, 0, 20}, ScalingFunctions -> {None, None, "Reverse"}]

使用由函数定义的缩放比例，指定函数及其逆函数：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 == 1 / z, {x, -2, 2}, {y, -2, 2}, {z, 0, 10}, ScalingFunctions -> {None, None, {-Log[#]&, Exp[-#]&}}]

TextureCoordinateFunction (5)

默认情况下，纹理使用经过缩放的和坐标：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Lighting -> "Neutral", ContourStyle -> Texture[ExampleData[{"ColorTexture", "WavesPattern"}]]]

使用和坐标：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Lighting -> "Neutral", TextureCoordinateFunction -> ({#1, #3}&), ContourStyle -> Texture[ExampleData[{"ColorTexture", "WavesPattern"}]]]

对不同的曲面使用不同的纹理：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Lighting -> "Neutral", ContourStyle -> {Texture[ExampleData[{"ColorTexture", "Ash"}]], Texture[ExampleData[{"ColorTexture", "Amboyna"}]], Texture[ExampleData[{"ColorTexture", "Laurel"}]]}]

使用未经缩放的坐标：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Lighting -> "Neutral", TextureCoordinateScaling -> False, ContourStyle -> Texture[ExampleData[{"ColorTexture", "WavesPattern"}]]]

使用纹理突出显示参数如何映射到一个曲面上：

Wolfram Language code:

texture = ArrayPlot[{{1, 1, 1, 2, 1, 1}, {2, 0, 0, 2, 0, 0}, {2, 0, 0, 2, 0, 0}, {2, 1, 1, 1, 1, 1}, {2, 0, 0, 2, 0, 0}, {2, 0, 0, 2, 0, 0}}, ColorRules -> {1 -> Red, 2 -> Blue, 0 -> White}, Frame -> False, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 100]

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Lighting -> "Neutral", ContourStyle -> Texture[texture]]

TextureCoordinateScaling (1)

对于纹理，使用已缩放或者未缩放的坐标：

Wolfram Language code:

texture = ArrayPlot[{{1, 1, 1, 2, 1, 1}, {2, 0, 0, 2, 0, 0}, {2, 0, 0, 2, 0, 0}, {2, 1, 1, 1, 1, 1}, {2, 0, 0, 2, 0, 0}, {2, 0, 0, 2, 0, 0}}, ColorRules -> {1 -> Red, 2 -> Blue, 0 -> White}, Frame -> False, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 100]

Wolfram Language code:

Table[ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 2 == 1, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, Lighting -> "Neutral", ContourStyle -> Texture[texture], TextureCoordinateScaling -> s, PlotLabel -> s], {s, {True, False}}]

Ticks (6)

自动为每幅图标出刻度：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

用 TicksNone 绘制坐标轴，但不显示刻度：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> None]

在特定位置放置刻度线：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{-2, .5, 2}, {-2, 0, 2}, {-2, 1, 2}}]

在指定位置绘制刻度线，并显示指定的标签：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{{-2, -a}, {.5, b}, {2, a}}, {{-2, -a}, {0, c}, {2, a}}, {{-2, -a}, {1, d}, {2, a}}}]

用缩放长度指定刻度线：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{{-2, -a, .1}, {.5, b, .1}, {2, a, .1}}, {{-2, -a, .08}, {0, c, .08}, {2, a, .08}}, {{-2, -a, .05}, {1, d, .05}, {2, a, .05}}}]

通过指定位置、长度、标签和样式自定义每个刻度：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Ticks -> {{{-2, -a, .05, Directive[Thick, Red]}, {.5, b, .05, Directive[Thick, Red]}, {2, a, .01, Directive[Thick, Red]}}, {{-2, -a, .05, Directive[Blue]}, {0, c, .05, Directive[Blue]}, {2, a, .05, Directive[Blue]}}, {{-2, -a, .1, Directive[Thick, Green]}, {1, d, .1, Directive[Thick, Green]}, {2, a, .1, Directive[Thick, Darker@Green]}}}]

TicksStyle (3)

默认情况下，刻度和刻度标签使用与坐标轴相同的样式：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, AxesStyle -> Directive[StandardRed, Thick]]

指定刻度的整体样式，包括标签：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, TicksStyle -> Directive[StandardRed, Thick]]

指定每个轴的刻度的样式：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, TicksStyle -> {Directive[StandardRed, Thick], Directive[StandardBlue], Directive[StandardGray, Thick]}]

WorkingPrecision (2)

用机器精度的算法计算函数：

Wolfram Language code: ContourPlot3D[Sin[x y + 10 ^ 16] == z, {x, -2, 2}, {y, -2, 2}, {z, -1, 1}]

用任意精度的算法计算函数：

Wolfram Language code: ContourPlot3D[Sin[x y + 10 ^ 16] == z, {x, -2, 2}, {y, -2, 2}, {z, -1, 1}, WorkingPrecision -> 20]

应用 (5)

椭球表面 [更多信息]：

Wolfram Language code:

Table[ContourPlot3D[Evaluate[e], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, AxesLabel -> Automatic, Ticks -> None, PlotLabel -> e], {e, {(x / 2) ^ 2 + y ^ 2 + z ^ 2 == 1, x ^ 2 + (y / 2) ^ 2 + z ^ 2 == 1, x ^ 2 + y ^ 2 + (z / 2) ^ 2 == 1}}]

计算它们的体积：

Wolfram Language code: Integrate[Boole[(x / 2) ^ 2 + y ^ 2 + z ^ 2 ≤ 1], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

Wolfram Language code: NIntegrate[Boole[(x / 2) ^ 2 + y ^ 2 + z ^ 2 ≤ 1], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

圆锥表面 [更多信息]：

Wolfram Language code:

Table[ContourPlot3D[Evaluate[e], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, AxesLabel -> Automatic, Ticks -> None, PlotLabel -> e], {e, {-x ^ 2 + y ^ 2 + z ^ 2 == 0, x ^ 2 - y ^ 2 + z ^ 2 == 0, x ^ 2 + y ^ 2 - z ^ 2 == 0}}]

显示一个球体及双曲抛物面和单叶双曲面：

Wolfram Language code:

ContourPlot3D[{x ^ 2 + y ^ 2 - z ^ 2 == 1, x ^ 2 + y ^ 2 + z ^ 2 == 1, x ^ 2 + y ^ 2 - z ^ 2 == -1}, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, BoxRatios -> Automatic, RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], ContourStyle -> {Yellow, Magenta, Cyan}, Mesh -> 3]

用 Mesh 表明一个双曲抛物面是一个双直纹面：

Wolfram Language code:

ContourPlot3D[x ^ 2 - y ^ 2 == z, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, MeshFunctions -> {#1 - #2&, #1 + #2&}, MeshStyle -> {Purple, Orange}, Lighting -> "Neutral", ContourStyle -> Gray]

一个隐式定义的圆环 [更多信息]：

Wolfram Language code: torus[{R_, r_}, {x_, y_, z_}] := (x^2 + y^2 + z^2 + R^2 - r^2)^2 == 4R^2(x^2 + z^2);

Wolfram Language code: torus[{2, 1}, {x, y, z}]

Wolfram Language code:

ContourPlot3D[ Evaluate[torus[{3, 1}, {x, y, z}]], {x, -5, 5}, {y, -5, 5}, {z, -5, 5}, Mesh -> None, ContourStyle -> Directive[Orange, Specularity[White, 20]], PlotPoints -> 25, PlotRange -> Automatic, BoxRatios -> Automatic]

由一组在位置处的点电荷构成的静电势：

Wolfram Language code: ElectroStaticPotential[q_, p_, r_] := Sum[ (q[[i]]/Norm[r - p[[i]]]), {i, Length[q]}]

Wolfram Language code:

ElectroStaticPotential[{Subscript[q, 1], Subscript[q, 2]}, {{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, {x, y, z}]//TraditionalForm

两个电荷和：

Wolfram Language code:

ContourPlot3D[Evaluate[ElectroStaticPotential[{1, -1}, {{-1, 0, 0}, {1, 0, 0}}, {x, y, z}]], {x, -6, 6}, {y, 0, 4}, {z, -4, 4}, Contours -> {-0.75, -0.25, -0.1, 0, 0.1, 0.25, 0.75},   ContourStyle -> Table[Hue[i / 7], {i, 0, 6}], Mesh -> None]

两个电荷和：

Wolfram Language code:

ContourPlot3D[Evaluate[ElectroStaticPotential[{1, 1}, {{-1, 0, 0}, {1, 0, 0}}, {x, y, z}]], {x, -3, 3}, {y, 0, 2}, {z, -2, 2}, Contours  -> {1, 1.5, 2}, ContourStyle -> Table[Hue[i / 3], {i, 0, 2}], Mesh -> None]

三个电荷、和：

Wolfram Language code:

ContourPlot3D[Evaluate[ElectroStaticPotential[{2, -1, -1}, {{0, 0, 0}, {1, 0, -1}, {-1, 0, -1}}, {x, y, z}]], {x, -4, 4}, {y, 0, 4}, {z, -6, 6}, Contours -> {-0.75, -0.25, -0.1, 0, 0.1, 0.25, 0.75}, ContourStyle -> Table[Hue[i / 7], {i, 0, 6}], Mesh -> None ]

属性和关系 (8)

ContourPlot3D 在需要的位置对更多的点取样：

Wolfram Language code: ContourPlot3D[Sin[x y] == z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> All, MaxRecursion -> 1]

绘制一个隐式的表面，等价于求出一个相关函数的零值等值面：

Wolfram Language code:

{ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> {0}], ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]}

根据输入形式的等值面的方向：

Wolfram Language code:

ContourPlot3D[x ^ 2 + y ^ 2 == z ^ 4, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, ContourStyle -> FaceForm[Red, Yellow]]

Wolfram Language code:

ContourPlot3D[z ^ 4 == x ^ 2 + y ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, ContourStyle -> FaceForm[Red, Yellow]]

用 ListContourPlot3D 绘制数据：

Wolfram Language code: data = Flatten[Table[{x, y, z, Sin[x y] - z}, {x, -2, 2, 0.2}, {y, -2, 2, 0.2}, {z, -2, 2, 0.2}], 2];

Wolfram Language code: ListContourPlot3D[data]

对于三维空间的隐式区域用 RegionPlot3D：

Wolfram Language code: RegionPlot3D[Sin[x y] ≥ z, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]

对曲面用 Plot3D：

Wolfram Language code: Plot3D[Sin[x y], {x, -2, 2}, {y, -2, 2}]

对三维空间的参数曲线和区域，用 ParametricPlot3D：

Wolfram Language code:

{ParametricPlot3D[{Cos[u], Sin[u], u / (6Pi)}, {u, 0, 6Pi}], ParametricPlot3D[{u + v, u - v, u ^ 2 - v ^ 2}, {u, -2, 2}, {v, -2, 2}]}

对于二维空间的等值面和密度面，用 ContourPlot 和 DensityPlot：

Wolfram Language code:

{ContourPlot[Sin[x y], {x, -2, 2}, {y, -2, 2}], 
	DensityPlot[Sin[x y], {x, -2, 2}, {y, -2, 2}]}

可能存在的问题 (3)

提高对 PlotPoints 或 MaxRecursion 的设置值以捕捉一个曲面的特征：

Wolfram Language code: ContourPlot3D[z ^ 2 + x z == x ^ 2z, {x, -0.5, 1.5}, {y, -1, 1}, {z, -1, 1}, Mesh -> None]

Wolfram Language code: ContourPlot3D[z ^ 2 + x z == x ^ 2z, {x, -0.5, 1.5}, {y, -1, 1}, {z, -1, 1}, Mesh -> None, MaxRecursion -> 4]

用更多的初始点来捕捉等值面内的更多部分：

Wolfram Language code:

ContourPlot3D[Sin[3x]Sin[3y]Sin[3z] == 1 / 2, {x, 0, 3}, {y, 0, 3}, {z, -1, 1}, Mesh -> None, BoxRatios -> Automatic, PlotPoints -> 5]

Wolfram Language code:

ContourPlot3D[Sin[3x]Sin[3y]Sin[3z] == 1 / 2, {x, 0, 3}, {y, 0, 3}, {z, -1, 1}, Mesh -> None, BoxRatios -> Automatic, PlotPoints -> 10]

对于总是非负的函数, 找到0值等值面是不可能的：

Wolfram Language code: ContourPlot3D[(x ^ 2 + y ^ 2 + z ^ 2 - 1) ^ 2 == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

巧妙范例 (1)

一个隐式的超越周期曲面：

Wolfram Language code:

ContourPlot3D[ Cos[x]Sin[y] + Cos[y]Sin[z] + Cos[z]Sin[x] == 0, {x, -2π, 2π}, {y, -2π, 2π}, {z, -2π, 2π}, ContourStyle -> Directive[FaceForm[Orange, Red], Specularity[White, 30]], Mesh -> None]

Top

	s_f	缩放 f 等高值
	{s_x,s_y,s_z}	缩放 x，y 和 z 轴
	{s_x,s_y,s_z,s_f}	缩放 x，y 和 z 轴及 f 等高值

	"Log"		带有自动刻度标记的对数刻度
	"Log10"		以 10 为底的对数标尺，其中刻度为 10 的幂
	"SignedLog"		包含 0 和负数的类对数标尺
	"Reverse"		反转坐标方向
	"Infinite"		无限标尺

		"DarkMesh"	暗色网格线
		"GrayMesh"	灰色网格线
		"LightMesh"	浅色网格线
		"ZMesh"	垂直分布的网格线
		"ThickSurface"	令曲面有厚度

AlignmentPoint	Center	在图形内对齐的缺省点
AspectRatio	Automatic	高与宽的比
Axes	True	是否绘制坐标轴
AxesEdge	Automatic	在哪条边上放置轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴交叉的位置
AxesStyle	{}	指定坐标轴样式的图形指令
Background	None	图形背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
BoundaryStyle	Automatic	如何绘制区域的边界
Boxed	True	是否绘制边框
BoxRatios	{1,1,1}	三维边界框的比例
BoxStyle	{}	盒框的样式指定
ClipPlanes	None	剪切平面
ClipPlanesStyle	Automatic	剪切平面的样式指定
ColorFunction	Automatic	如何对等值面着色
ColorFunctionScaling	True	是否缩放传递给 ColorFunction 的参数
ContentSelectable	Automatic	是否允许内容选择
Contours	Automatic	显示多少个等值面或哪几个等值面
ContourStyle	White	等值面的样式
ControllerLinking	False	连接到外部旋转控制器的时间
ControllerPath	Automatic	尝试使用的外部控制器
Epilog	{}	在主图形显示后显示的二维图形基元
EvaluationMonitor	None	每个函数计算时运行的表达式
FaceGrids	None	在边框上绘制的网格线
FaceGridsStyle	{}	网格面的样式指定
FormatType	TraditionalForm	文本的缺省格式类型
ImageMargins	0.	图形周围预留的边幅
ImagePadding	All	允许为标签等设置的填充范围
ImageSize	Automatic	渲染图形的绝对尺寸
LabelStyle	{}	标签的样式指定
Lighting	Automatic	使用的模拟光照
MaxRecursion	Automatic	递归子划分所允许的最大次数
Mesh	Automatic	每个方向绘制的网格线的数量
MeshFunctions	{#1&,#2&,#3&}	如何确定网格分区的位置
MeshShading	None	如何绘制网格分区之间的阴影
MeshStyle	Automatic	网格线的样式
Method	Automatic	用于细化等值面的方式
NormalsFunction	Automatic	如何确定曲面的有效法线
PerformanceGoal	$PerformanceGoal	优化的目标
PlotLabel	None	图形的标签
PlotLegends	None	曲面的图例
PlotPoints	Automatic	每个方向样本点的初始数量
PlotRange	{Full,Full,Full,Automatic}	包括值的范围
PlotRangePadding	Automatic	值域范围填充的程度
PlotRegion	Automatic	要填充的最终显示区域
PlotTheme	$PlotTheme	图形的整体主题
PreserveImageOptions	Automatic	当显示相同图形的一个新版本时，是否保留图像选项
Prolog	{}	在主图形之前渲染的二维图形基元
RegionBoundaryStyle	Automatic	区域边界的样式
RegionFunction	(True&)	如何确定是否包含一个点
RotationAction	"Fit"	互动旋转后渲染的方式
ScalingFunctions	None	如何缩放单个坐标
SphericalRegion	Automatic	是否将外切球体调整适合最后显示区域
TextureCoordinateFunction	Automatic	如何确定纹理坐标
TextureCoordinateScaling	True	是否缩放传递给 TextureCoordinateFunction 的参数
Ticks	Automatic	指定刻度
TicksStyle	{}	刻度的样式指定
TouchscreenAutoZoom	False	当在一个触摸屏上激活时，是否放大为全屏
ViewAngle	Automatic	视图的角度
ViewCenter	Automatic	在中心显示的点
ViewMatrix	Automatic	显式转换矩阵
ViewPoint	{1.3,-2.4,2.}	观察位置
ViewProjection	Automatic	用于渲染远离观察者的对象的投影方法
ViewRange	All	要包含的观察距离范围
ViewVector	Automatic	模拟相机的位置和方向
ViewVertical	{0,0,1}	垂直的方向
WorkingPrecision	MachinePrecision	内部计算的精度

ContourPlot3D

更多信息和选项

所有选项的列表

范例

基本范例 (4)

范围 (16)

取样 (6)

演示 (10)

选项 (102)

Axes (2)

AxesLabel (4)

AxesOrigin (2)

AxesStyle (4)

BoundaryStyle (3)

BoxRatios (1)

ColorFunction (5)

ColorFunctionScaling (2)

Contours (4)

ContourStyle (8)

EvaluationMonitor (2)

ImageSize (7)

MaxRecursion (1)

Mesh (6)

MeshFunctions (2)

MeshShading (5)

MeshStyle (2)

NormalsFunction (3)

PerformanceGoal (2)

PlotLegends (3)

PlotPoints (1)

PlotRange (2)

PlotTheme (4)

RegionFunction (2)

RegionBoundaryStyle (4)

ScalingFunctions (4)

TextureCoordinateFunction (5)

TextureCoordinateScaling (1)

Ticks (6)

TicksStyle (3)

WorkingPrecision (2)

应用 (5)

属性和关系 (8)

可能存在的问题 (3)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX