WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FindDistribution[data]

data の分布にフィットする単純な関数形式を求める．

FindDistribution[data,n]

最良の分布を n 個まで求める．

FindDistribution[data,n,prop]

特性 prop と関連する最良の分布を n 個まで返す．

FindDistribution[data,n,{prop1,prop2,…}]

特性 prop1，prop2等に関連する最良の分布を n 個まで返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
TargetFunction  
PerformanceGoal  
RandomSeeding  
アプリケーション  
特定の文字で始まる単語の長さ  
テキスト頻度  
デンマークにおけるメラノーマ  
AIDSの感染時間  
カテーテルを交換してから腎感染までの時間  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

FindDistribution

FindDistribution[data]

data の分布にフィットする単純な関数形式を求める．

FindDistribution[data,n]

最良の分布を n 個まで求める．

FindDistribution[data,n,prop]

特性 prop と関連する最良の分布を n 個まで返す．

FindDistribution[data,n,{prop1,prop2,…}]

特性 prop1，prop2等に関連する最良の分布を n 個まで返す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

一様分布に従うランダムな整数のリストを作る：

Wolfram Language code: RandomInteger[10, 100]

データから，もとになっている分布を求める：

Wolfram Language code: FindDistribution[%]

指数分布からサンプリングされたでデータを生成する：

Wolfram Language code: 𝒟 = ExponentialDistribution[1]; data = RandomVariate[𝒟, 1000];

データから最良の分布を求める：

Wolfram Language code: estimated𝒟 = FindDistribution[data]

もとの分布と推定分布の確率密度関数を比較する：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[estimated𝒟, x]}, {x, 0, 10}, PlotLegends -> {"𝒟", "e𝒟"}]

最良の分布を3つ返す：

Wolfram Language code: FindDistribution[data, 3]

ベイズ情報量基準の値と赤池情報量基準の値を比較する：

Wolfram Language code: FindDistribution[data, 3, {"BIC", "AIC"}]

スコープ  (3)

混合分布からサンプルを取ってデータを生成する：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 1}, {ExponentialDistribution[1], NormalDistribution[5, 0.8]}];
Wolfram Language code: data = RandomVariate[𝒟, 1000];

このデータから最良の分布を推定する：

Wolfram Language code: e𝒟 = FindDistribution[data]

もとの分布と推定分布の確率密度関数を視覚的に比較する：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[e𝒟, x]}, {x, -8, 10}, PlotLegends -> {"𝒟", "e𝒟"}, PlotRange -> All]

特性の分布について母数を推定する：

Wolfram Language code: 𝒟 = WeibullDistribution[1, 2];
Wolfram Language code: data = RandomVariate[𝒟, 1000];

デフォルトで，FindDistributionは単純な分布を返す：

Wolfram Language code: e𝒟 = FindDistribution[data]

求める分布のタイプを指定する：

Wolfram Language code: e𝒟 = FindDistribution[data, TargetFunctions -> {WeibullDistribution}]

指数分布からサンプルを取ってデータを生成する：

Wolfram Language code: 𝒟 = ExponentialDistribution[1]; data = RandomVariate[𝒟, 1000];

上位2分布についての全特性を含むDatasetを生成する：

Wolfram Language code: report = FindDistribution[data, 2, All]

オプション  (5)

TargetFunction  (3)

混合分布からデータサンプルを生成する：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 1}, {ExponentialDistribution[1], NormalDistribution[5, 0.8]}];
Wolfram Language code: data = RandomVariate[𝒟, 1000];

特定の分布についての母数を推定する：

Wolfram Language code: e𝒟 = FindDistribution[data, TargetFunctions -> {NormalDistribution, GammaDistribution}]

もとの分布と推定分布の確率密度関数を比較する：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[e𝒟, x]}, {x, -8, 10}, PlotLegends -> {"𝒟", "e𝒟"}, PlotRange -> All]

間欠泉の噴出から次の噴出までの時間：

Wolfram Language code: waiting = ExampleData[{"Statistics", "OldFaithful"}][[All, 2]];

データの分布を推定する：

Wolfram Language code: e𝒟1 = FindDistribution[waiting]

連続的であるとして扱われた場合のデータの分布を推定する：

Wolfram Language code: e𝒟2 = FindDistribution[waiting, TargetFunctions -> "Continuous"]

連続的であるとして扱われた場合のデータの分布をGammaDistributionを使って推定する：

Wolfram Language code: e𝒟3 = FindDistribution[waiting, TargetFunctions -> {GammaDistribution}]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: legend = SwatchLegend[{Red, ColorData[97, 1], ColorData[97, 2]}, {"e𝒟1", "e𝒟2", "e𝒟3"}];
Wolfram Language code: Show[Histogram[waiting, 20, "ProbabilityDensity"], DiscretePlot[{PDF[e𝒟1, x]}, {x, 0, 100}, PlotStyle -> {PointSize[.02], Red}], Plot[{PDF[e𝒟2, x], PDF[e𝒟3, x]}, {x, 0, 100}, PlotLegends -> legend]]

特定の分布についての母数を，その分布についての事前分布を仮定して推定する：

Wolfram Language code: magnitudes = Select[ExampleData[{"Statistics", "USEarthquakes"}], #[[1]] ≥ 1935&][[All, 7]];

1935年から1989年までの米国の地震のマグニチュードには2つの峰がある：

Wolfram Language code: h = Histogram[magnitudes, 20, "ProbabilityDensity"]

TargetFunctionsを使わずに最良フィットを推定する：

Wolfram Language code: Subscript[``e𝒟``, 1] = FindDistribution[magnitudes]

分布についての事前分布を使って最良フィットを推定する：

Wolfram Language code: Subscript[``e𝒟``, 2 ] = FindDistribution[magnitudes, TargetFunctions -> {{10, 2} -> {CauchyDistribution, GammaDistribution}}]

推定分布の確率密度関数とヒストグラムを比較する：

Wolfram Language code: Show[h, Plot[{PDF[Subscript[``e𝒟``, 1], x], PDF[Subscript[``e𝒟``, 2 ], x]}, {x, 0, 10}, PlotStyle -> Thick, PlotRange -> All]]

PerformanceGoal  (1)

混合分布からデータサンプルを生成する：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 2}, {ChiDistribution[0.6], GammaDistribution[20, 1]}]
Wolfram Language code: data = RandomVariate[𝒟, 10000];

ビッグデータの集合について最良フィットを推定し，PerformanceGoalのさまざまな設定についてAbsoluteTimingを比較する：

Wolfram Language code: AbsoluteTiming[e𝒟1 = FindDistribution[data, PerformanceGoal -> "Speed"]]
Wolfram Language code: AbsoluteTiming[e𝒟2 = FindDistribution[data, PerformanceGoal -> "Quality"]]

解のLogLikelihoodを比較する：

Wolfram Language code: LogLikelihood[#, data]& /@ {e𝒟1, e𝒟2}

RandomSeeding  (1)

混合分布からデータサンプルを生成する：

Wolfram Language code: 𝒟 = MixtureDistribution[{1, 2}, {NormalDistribution[-6, 1], GammaDistribution[20, 1]}]
Wolfram Language code: data = RandomVariate[𝒟, 1000];

FindDistributionの異なるラウンドを比較し，どのように違うかを見る：

Wolfram Language code: Table[FindDistribution[data], 3]

オプションRandomSeedingを使って結果が異ならないようにする：

Wolfram Language code: Table[FindDistribution[data, RandomSeeding -> 1], 3]

アプリケーション  (5)

特定の文字で始まる単語の長さ  (1)

母音で始まる辞書中のすべての英単語の長さ：

Wolfram Language code: letters = {"a", "e", "i", "o", "u", "y"};
Wolfram Language code: worddata = Table[StringLength /@ DictionaryLookup[l ~~ ___], {l, letters}];

母音ごとの分布を推定する：

Wolfram Language code: e𝒟 = Table[FindDistribution[i, MaxItems -> 1], {i, worddata}]

もとのデータのヒストグラムと推定分布のPDを比較する：

Wolfram Language code: Partition[Table[Show[Histogram[worddata[[i]], {Range[25] - 1 / 2}, "ProbabilityDensity", PlotLabel -> letters[[i]]], DiscretePlot[PDF[e𝒟[[i]], x], {x, 0, 25}, PlotRange -> All, PlotStyle -> PointSize[.025]], ImageSize -> Small], {i, Length[letters]}], 3]//Grid

テキスト頻度  (1)

アメリカの独立宣言中の単語の出現数を数える：

Wolfram Language code: text = ExampleData[{"Text", "DeclarationOfIndependence"}, "Words"];
Wolfram Language code: wordCount = Tally[text][[All, 2]];

単語数の分布を推定する：

Wolfram Language code: e𝒟 = FindDistribution[wordCount, MaxItems -> 1]

もとのデータのヒストグラムと推定分布の確率密度関数を比較する：

Wolfram Language code: Show[Histogram[wordCount, {0.5, 9.5, 1}, "ProbabilityDensity"], DiscretePlot[PDF[e𝒟, x], {x, 1, 10}, PlotStyle -> PointSize[Medium], PlotRange -> All]]

デンマークにおけるメラノーマ  (1)

メラノーマに罹患した患者の年齢：

Wolfram Language code: melanomaAge = ExampleData[{"Statistics", "DenmarkMelanoma"}][[All, 4]];

データ分布を推定する：

Wolfram Language code: e𝒟 = FindDistribution[melanomaAge]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[melanomaAge, {4, 95, 4}, "ProbabilityDensity"], Plot[PDF[e𝒟, x], {x, 4, 95}, PlotStyle -> Thick, PlotRange -> All]]

AIDSの感染時間  (1)

AIDSの感染時間（単位：年）：

Wolfram Language code: aids = ExampleData[{"Statistics", "TimeToAIDS"}][[All, 1]];

データの分布を推定する：

Wolfram Language code: e𝒟 = FindDistribution[aids]

データのヒストグラムと推定分布の確率密度関数を比較する：

Wolfram Language code: Show[Histogram[aids, {0, 8, 0.65}, "ProbabilityDensity"], Plot[PDF[e𝒟, x], {x, 0, 8}, PlotStyle -> Thick, PlotRange -> All]]

カテーテルを交換してから腎感染までの時間  (1)

腎感染まで時間（単位：月）：

Wolfram Language code: KidneyInfection = ExampleData[{"Statistics", "KidneyInfection"}][[All, 1]];

データの分布を推定する：

Wolfram Language code: e𝒟 = FindDistribution[KidneyInfection]

データのヒストグラムと推定分布の確率密度関数を比較する：

Wolfram Language code: Show[Histogram[KidneyInfection, {0, 28, 2}, "ProbabilityDensity"], Plot[PDF[e𝒟, x], {x, 0, 28}, PlotStyle -> Thick, PlotRange -> All]]

特性と関係  (1)

デフォルトで，FindDistributionParametersは最大尤度を使って固定分布の分布母数を推定する．FindDistributionはベイズ情報量基準と事前確率と組み合せる完全なベイズ的アプローチを使って最適な分布と最適な母数の両方を求める．

StudentTDistributionからサンプルを取ってデータを生成する：

Wolfram Language code: SeedRandom[5] data = RandomVariate[StudentTDistribution[1, 1, 4], 800]; Histogram[data, {-10, 10, Automatic}, "ProbabilityDensity"]

FindDistributionを使ってこのデータに最もフィットする分布を推定する：

Wolfram Language code: dist1 = FindDistribution[data, RandomSeeding -> 1]

FindDistributionParametersを使い，StudentTDistributionを仮定して最適な母数を推定する：

Wolfram Language code: distribution = StudentTDistribution[α, β, ν]; estimatedParameters = FindDistributionParameters[data, distribution]; dist2 = distribution /. estimatedParameters

StudentTDistributionは対数尤度を最小にするが，LogisticDistributionはこれに比べて事前確率が高く複雑さは低い．

対応するLogLikelihoodと比較する：

Wolfram Language code: LogLikelihood[#, data]& /@ {dist1, dist2}

FindDistributionParametersとほぼ同じ母数を求めないなら，オプションTargetFunctionsを使うとよい：

Wolfram Language code: dist3 = FindDistribution[data, TargetFunctions -> {StudentTDistribution}]
Wolfram Research (2015), FindDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindDistribution.html （2017年に更新）.

テキスト

Wolfram Research (2015), FindDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindDistribution.html （2017年に更新）.

CMS

Wolfram Language. 2015. "FindDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/FindDistribution.html.

APA

Wolfram Language. (2015). FindDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindDistribution.html

BibTeX

@misc{reference.wolfram_2026_finddistribution, author="Wolfram Research", title="{FindDistribution}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/FindDistribution.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_finddistribution, organization={Wolfram Research}, title={FindDistribution}, year={2017}, url={https://reference.wolfram.com/language/ref/FindDistribution.html}, note=[Accessed: 14-September-2026]}