Wolfram 语言与系统参考资料中心

ComplexRegionPlot

ComplexRegionPlot[pred,{z,z_min,z_max}]

绘制复平面上 pred 为 True 的区域.

ComplexRegionPlot[{pred₁,pred₂,…},{z,z_min,z_max}]

绘制由多个谓词 pred_i 给定的区域.

范例

打开所有单元关闭所有单元

基本范例 (5)

绘制复平面上由不等式定义的区域：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}]

用 {z,1} 指定域等价于 {z,-1-,1+}：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, 1}]

绘制由不等式的逻辑组合定义的区域：

Wolfram Language code: ComplexRegionPlot[0 < Arg[z] < 2π / 3, {z, 5}]

绘制多个区域：

Wolfram Language code: ComplexRegionPlot[{Re[z ^ 2] < 1, Im[z ^ 2] < 1}, {z, 2}]

设置区域的样式：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1 && Abs[Arg[z]] > π / 4, {z, -1 - I, 1 + I}, PlotStyle -> Yellow]

范围 (23)

采样 (3)

在区域的边界附近取更多采样点：

Wolfram Language code: ComplexRegionPlot[Abs[Nest[(# ^ 2 + z)&, z, 8]] < 2, {z, -2 - 1.5I, 1 + 1.5I}, Mesh -> All]

用 PlotPoints 和 MaxRecursion 控制自适应采样：

Wolfram Language code:

Table[ComplexRegionPlot[1 < Abs[Sin[2 z] Cosh[2 z]] < 4, {z, -2 - 2I, 2 + 2I}, PlotPoints -> pp, MaxRecursion -> mr, Mesh -> None], {mr, {0, 2}}, {pp, {5, 15}}]

区域的逻辑组合：

Wolfram Language code: ComplexRegionPlot[Re[z^2] ≤ 2 && Im[z^2] > 1, {z, -3 - 3I, 3 + 3I}]

添加标签和图例 (9)

用 Labeled 标记区域：

Wolfram Language code: ComplexRegionPlot[Labeled[Abs[z] < 1, "disk", Above], {z, -1.5 - 1.5I, 1.5 + 1.5I}]

标记多个区域：

Wolfram Language code:

ComplexRegionPlot[{Labeled[Abs[z] < 1, "disk", Right], Labeled[Re[z] < 1, "rectangle", Below]}, {z, -1.5 - 1.5I, 1.5 + 1.5I}]

将标签放置在不同的位置：

Wolfram Language code:

Table[ComplexRegionPlot[Labeled[Abs[z] < 1, "disk", pos], {z, -1.5 - 1.5I, 1.5 + 1.5I}, PlotLabel -> pos], {pos, {Top, Bottom, Left, Right}}]

用 Callout 标记区域：

Wolfram Language code: ComplexRegionPlot[Callout[1 < Abs[Sin[2 z] Sinh[2 z]] < 6, "region", {1, 1}], {z, -2 - 2I, 2 + 2I}]

标记多个区域：

Wolfram Language code:

ComplexRegionPlot[{Callout[1 < Abs[Sin[2 z] Sinh[2 z]] < 6, "region", {1, 1}], Callout[Abs[z] < 2, "disk", {1, -1}]}, {z, -2 - 2I, 2 + 2I}]

标签位于区域内时，不显示标注的引线：

Wolfram Language code: ComplexRegionPlot[Callout[Abs[Sin[2 z] Sinh[2 z]] < 6, "region", {0, 0}], {z, -2 - 2I, 2 + 2I}]

用 PlotLegends 添加图例：

Wolfram Language code: ComplexRegionPlot[{1 < Abs[Sin[2 z] Sinh[2 z]] < 6, Abs[z] < 2}, {z, -2 - 2I, 2 + 2I}, PlotLegends -> "Expressions"]

在图例中使用可编辑的占位符：

Wolfram Language code: ComplexRegionPlot[{1 < Abs[Sin[2 z] Sinh[2 z]] < 6, Abs[z] < 2}, {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

用 Legended 添加图例：

Wolfram Language code:

ComplexRegionPlot[{Legended[1 < Abs[Sin[2 z] Sinh[2 z]] < 6, "region"], Legended[Abs[z] < 2, "disk"]}, {z, -2 - 2I, 2 + 2I}]

演示 (11)

为区域设置明确的 PlotStyle：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1 && Abs[Arg[z]] > π / 4, {z, -1 - I, 1 + I}, PlotStyle -> Yellow]

为区域的边界设置明确的 BoundaryStyle：

Wolfram Language code:

ComplexRegionPlot[Abs[z] ≤ 1 && Abs[Arg[z]] > π / 4, {z, -1 - I, 1 + I}, PlotStyle -> Yellow, BoundaryStyle -> Dashed]

为绘图、坐标轴和区域添加描述性标签：

Wolfram Language code:

ComplexRegionPlot[{3 ≤ Abs[z] ≤ 4, Abs[z] < 2}, {z, -4 - 4I, 4 + 4I}, FrameLabel -> {"real", "imaginary"}, PlotLabel -> "shapes", PlotLabels -> {"annulus", "disk"}]

用不同方法的组合来标记区域：

Wolfram Language code: ComplexRegionPlot[{Callout[3 ≤ Abs[z] ≤ 4, "annulus"], Labeled[Abs[z] < 2, "disk", Below]}, {z, -4 - 4I, 4 + 4I}]

显示多个区域的图例：

Wolfram Language code: ComplexRegionPlot[{3 ≤ Abs[z] ≤ 4, Abs[z] < 2}, {z, -4 - 4I, 4 + 4I}, PlotLegends -> "Expressions"]

生成含有可编辑占位符的图例：

Wolfram Language code: ComplexRegionPlot[{3 ≤ Abs[z] ≤ 4, Abs[z] < 2}, {z, -4 - 4I, 4 + 4I}, PlotLegends -> Automatic]

显示着色区域的图例：

Wolfram Language code: ComplexRegionPlot[2 ≤ Abs[z] ≤ 4, {z, -4 - 4I, 4 + 4I}, ColorFunction -> Hue, PlotLegends -> Automatic]

显示叠加的网格线：

Wolfram Language code: ComplexRegionPlot[2 ≤ Abs[z] ≤ 4, {z, -4 - 4I, 4 + 4I}, Mesh -> 8, MeshStyle -> Directive[Red, Dashed]]

设置网格线之间区域的样式：

Wolfram Language code: ComplexRegionPlot[2 ≤ Abs[z] ≤ 4, {z, -4 - 4I, 4 + 4I}, Mesh -> 8, MeshShading -> {{Yellow, Orange}, {Pink, Red}}]

用密度为区域着色：

Wolfram Language code:

ComplexRegionPlot[Abs[Nest[(# ^ 2 + z)&, z, 8]] < 2, {z, -2 - 1.5I, 1 + 1.5I}, ColorFunction -> Function[{re, im, abs, arg}, Hue[Nest[(# ^ 2 + re)&, re, 8]]], ColorFunctionScaling -> False, PlotPoints -> 50]

使用绘图主题：

Wolfram Language code: ComplexRegionPlot[2 ≤ Abs[z] ≤ 4, {z, -4 - 4I, 4 + 4I}, PlotTheme -> "Scientific"]

选项 (59)

BoundaryStyle (4)

区域的边界为蓝色：

Wolfram Language code: ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}]

用 None 显示没有边界的区域：

Wolfram Language code: ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}, BoundaryStyle -> None]

使用红色的边界：

Wolfram Language code: ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}, BoundaryStyle -> Red]

使用较粗的虚线作为边界：

Wolfram Language code: ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}, BoundaryStyle -> Directive[Thickness[Medium], Dashed]]

ColorFunction (5)

用缩放过的 Re[z]、Im[z]、Abs[z] 或 Arg[z] 为区域着色：

Wolfram Language code:

{
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#1]&)], 
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#2]&)], 
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#3]&)], 
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#4]&)]
	}

已命名颜色函数沿缩放过的 Arg[z] 方向进行着色：

Wolfram Language code: ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, ColorFunction -> "Rainbow"]

根据的函数为区域着色：

Wolfram Language code:

ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}, ColorFunction -> Function[{z}, ColorData["SolarColors"][Abs[z]]], ColorFunctionScaling -> False]

ColorFunction 比 PlotStyle 的优先级高：

Wolfram Language code:

ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}, ColorFunction -> "DarkRainbow", PlotStyle -> Directive[Opacity[0.5], Red]]

ColorFunction 比 MeshShading 的优先级低：

Wolfram Language code:

ComplexRegionPlot[Abs[z^4 - z / 5 + 1] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 30, MeshShading -> {{Gray, Automatic}, {Automatic, Gray}}, ColorFunction -> "DarkRainbow"]

ColorFunctionScaling (1)

用未经缩放的 Re[z]、Im[z]、Abs[z] 或 Arg[z] 为区域着色：

Wolfram Language code:

{
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#1]&), ColorFunctionScaling -> False], 
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#2]&), ColorFunctionScaling -> False], 
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#3]&), ColorFunctionScaling -> False], 
	ComplexRegionPlot[Abs[z] < 2, {z, -2 - 2I, 2 + 2I}, ColorFunction -> (Hue[#4]&), ColorFunctionScaling -> False]
	}

LabelingSize (2)

以实际大小显示文字标签：

Wolfram Language code: ComplexRegionPlot[Callout[Abs[z] ≤ 1 && Abs[Arg[z]] > π / 4, "region"], {z, -1 - I, 1 + I}, PlotStyle -> Yellow]

指定文字的大小：

Wolfram Language code:

ComplexRegionPlot[Callout[Abs[z] ≤ 1 && Abs[Arg[z]] > π / 4, "region"], {z, -1 - I, 1 + I}, PlotStyle -> Yellow, LabelingSize -> 25]

MaxRecursion (1)

细化变化较快的区域：

Wolfram Language code:

Table[ComplexRegionPlot[Abs[Nest[(# ^ 2 + z)&, z, 8]] < 2, {z, -2 - 1.5I, 1 + 1.5I}, MaxRecursion -> r, Mesh -> All], {r, {0, 5}}]

Mesh (7)

不显示网格：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}]

显示最初和最后的采样网格线：

Wolfram Language code:

{ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> Full], 
	ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> All]}

在每个方向上显示 10 条网格线：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10]

在 Re[z] 方向上显示 3 条网格线，在 Im[z] 方向上显示 6 条网格线：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> {3, 6}]

在指定的数值处显示网格线：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> {{-1 / 2, 1 / 2}, {0}}]

对不同的网格线使用不同的样式：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> {{{-1 / 2, Red}, {1 / 2, Red}}, {{0, Dashed}}}]

网格线适用于整个区域，而不是每个分量：

Wolfram Language code: ComplexRegionPlot[Abs[z] > 1 && Pi / 4 < Abs[Arg[z]] < 3Pi / 4, {z, -2 - 2I, 2 + 2I}, Mesh -> 10]

MeshFunctions (2)

在 Re[z] 和 Im[z] 方向上显示网格线：

Wolfram Language code:

{ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10, MeshFunctions -> {Re[#]&}], ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10, MeshFunctions -> {Im[#]&}]}

从原点起以固定半径划分的网格线：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10, MeshFunctions -> {Abs[#]&}]

MeshShading (4)

用 None 移除区域：

Wolfram Language code:

ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 8, MeshFunctions -> {Re[#] - Im[#]&}, MeshShading -> {Red, None}]

在区域上放置棋盘图案：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10, MeshShading -> {{Red, Yellow}, {Pink, Orange}}]

MeshShading 比 PlotStyle 的优先级高：

Wolfram Language code:

ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10, PlotStyle -> Blue, MeshShading -> {{Automatic, Green}, {Green, Automatic}}]

MeshShading 比 ColorFunction 的优先级高：

Wolfram Language code:

ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 10, PlotStyle -> Blue, MeshShading -> {{Automatic, None}, {None, Automatic}}, ColorFunction -> "DarkRainbow"]

MeshStyle (2)

使用红色的网格线：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 5, MeshStyle -> Red]

在 Re[z] 方向上显示红色的网格线，在 Im[z] 方向上显示虚线：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, Mesh -> 5, MeshStyle -> {Red, Dashed}]

PerformanceGoal (2)

生成高质量的绘图：

Wolfram Language code: Timing[ComplexRegionPlot[1 < Abs[Sin[2 z] Cosh[2 z]] < 3, {z, -2 - 2I, 2 + 2I}, PerformanceGoal -> "Quality"]]

强调性能，可能会以牺牲质量为代价：

Wolfram Language code: Timing[ComplexRegionPlot[1 < Abs[Sin[2 z] Cosh[2 z]] < 3, {z, -2 - 2I, 2 + 2I}, PerformanceGoal -> "Speed"]]

PlotLabels (5)

标记区域：

Wolfram Language code: ComplexRegionPlot[1 < Abs[Sin[5 z] Cosh[2z]] < 3, {z, -1 - I, 1 + I}, PlotLabels -> "label"]

将标签放置在区域的上面：

Wolfram Language code: ComplexRegionPlot[1 < Abs[Sin[5 z] Cosh[2z]] < 3, {z, -1 - I, 1 + I}, PlotLabels -> Placed["island", Above]]

将标签放置在区域内部：

Wolfram Language code: ComplexRegionPlot[1 < Abs[Sin[5 z] Cosh[2z]] < 3, {z, -1 - I, 1 + I}, PlotLabels -> Placed["hole", Center]]

用 Callout 放置标签：

Wolfram Language code: ComplexRegionPlot[{1 < Abs[Sin[5 z] Cosh[2z]] < 3}, {z, -1 - I, 1 + I}, PlotLabels -> Callout["label", {0.5, 0.5}]]

标记多个区域：

Wolfram Language code:

ComplexRegionPlot[{1 < Abs[Sin[5 z] Cosh[2z]] < 3, Abs[z ^ 2 + 1] > 1}, {z, -1 - I, 1 + I}, PlotLabels -> {Callout["label1", Below], Callout["label2", After]}]

PlotLegends (8)

使用图例：

Wolfram Language code: ComplexRegionPlot[Abs[Nest[(# ^ 2 + z)&, z, 8]] < 2, {z, -2 - 1.5I, 1 + 1.5I}, PlotLegends -> All]

显示多个区域的图例：

Wolfram Language code: ComplexRegionPlot[{1 < Abs[Sin[5 z] Cosh[2z]] < 3, Abs[z ^ 2 + 1] > 1}, {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

对渐变的着色区域使用自动图例：

Wolfram Language code: ComplexRegionPlot[Abs[z] ≤ 1, {z, -1 - I, 1 + I}, ColorFunction -> "GreenPinkTones", PlotLegends -> Automatic]

PlotLegends 自动选取样式：

Wolfram Language code:

ComplexRegionPlot[{1 < Abs[Sin[5 z] Cosh[2z]] < 3, Abs[z ^ 2 + 1] > 1}, {z, -1 - I, 1 + I}, PlotStyle -> 96, PlotLegends -> Automatic]

用函数作为图例的文字：

Wolfram Language code:

ComplexRegionPlot[{1 < Abs[Sin[5 z] Cosh[2z]] < 3, Abs[z ^ 2 + 1] > 1}, {z, -1 - I, 1 + I}, PlotLegends -> "Expressions"]

指定图例的文字：

Wolfram Language code: ComplexRegionPlot[{Abs[z - 1] < 1, Abs[z + 1] < 1}, {z, -2 - 2I, 2 + 2I}, PlotLegends -> {"left", "right"}]

用 Placed 改变图例的位置：

Wolfram Language code:

Table[ComplexRegionPlot[{Abs[z - 1] < 1, Abs[z + 1] < 1}, {z, -2 - 2I, 2 + 2I}, PlotLegends -> Placed[Automatic, pos], PlotLabel -> pos], {pos, {Before, After, Above, Below}}]

用 SwatchLegend 改变图例的外观：

Wolfram Language code:

ComplexRegionPlot[{Abs[z - 1] < 1, Abs[z + 1] < 1}, {z, -2 - 2I, 2 + 2I}, PlotLegends -> SwatchLegend[Automatic, {"right", "left"}, LegendFunction -> "Frame", LegendLabel -> "ℛ"]]

PlotPoints (1)

使用更多的初始点，获得更平滑的区域：

Wolfram Language code:

Table[ComplexRegionPlot[1 < Abs[Sin[2 z] Cosh[2 z]] < 4, {z, -2 - 2I, 2 + 2I}, PlotPoints -> pp, MaxRecursion -> 0, Mesh -> None], {pp, {5, 10, 20, 50}}]

PlotRange (2)

在 Re[z] 和 Im[z] 的所有值上绘制区域：

Wolfram Language code: ComplexRegionPlot[Abs[Nest[(# ^ 2 + z)&, z, 8]] < 2, {z, -2 - 1.5I, 1 + 1.5I}]

自动计算 Re[z] 和 Im[z] 的范围：

Wolfram Language code: ComplexRegionPlot[Abs[Nest[(# ^ 2 + z)&, z, 8]] < 2, {z, -2 - 1.5I, 1 + 1.5I}, PlotRange -> Automatic]

PlotStyle (5)

用淡蓝色显示区域：

Wolfram Language code: ComplexRegionPlot[Abs[z - 1] < 2 || Abs[z + 1] < 2, {z, -3 - 3I, 3 + 3I}]

用 None 只显示区域的边界：

Wolfram Language code: RegionPlot[(x + 1) ^ 2 + y ^ 2 < 2 || (x - 1) ^ 2 + y ^ 2 < 2, {x, -3, 3}, {y, -3, 3}, PlotStyle -> None]

使用浅橘色：

Wolfram Language code: RegionPlot[(x + 1) ^ 2 + y ^ 2 < 2 || (x - 1) ^ 2 + y ^ 2 < 2, {x, -3, 3}, {y, -3, 3}, PlotStyle -> LightOrange]

对不同的区域使用不同的颜色：

Wolfram Language code: ComplexRegionPlot[{Abs[z - 1] < 2, Abs[z + 1] < 2}, {z, -3 - 3I, 3 + 3I}]

对不同的区域使用透明的颜色：

Wolfram Language code:

ComplexRegionPlot[{Abs[z - 1] < 2, Abs[z + 1] < 2}, {z, -3 - 3I, 3 + 3I}, PlotStyle -> {Directive[Blue, Opacity[0.4]], Directive[Red, Opacity[0.4]]}]

PlotTheme (2)

使用已命名主题：

Wolfram Language code: ComplexRegionPlot[Abs[z - 1] < 2 || Abs[z + 1] < 2, {z, -3 - 3I, 3 + 3I}, PlotTheme -> "Marketing"]

改变颜色方案：

Wolfram Language code: ComplexRegionPlot[Abs[z - 1] < 2 || Abs[z + 1] < 2, {z, -3 - 3I, 3 + 3I}, PlotTheme -> "Marketing", PlotStyle -> 47]

TextureCoordinateFunction (4)

默认情况下，纹理坐标与 Re[z] 和 Im[z] 对齐：

Wolfram Language code:

ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, PlotStyle -> Texture[[image]], TextureCoordinateFunction -> ({#1, #2}&)]

按对角线翻转纹理：

Wolfram Language code:

ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, PlotStyle -> Texture[[image]], TextureCoordinateFunction -> ({#2, #1}&)]

拉伸图像：

Wolfram Language code:

ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, PlotStyle -> Texture[[image]], TextureCoordinateFunction -> ({2#1, #2}&)]

将图像坐标与 Im[z] 和 Abs[z] 对齐：

Wolfram Language code:

ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, PlotStyle -> Texture[[image]], TextureCoordinateFunction -> ({#2, #3}&)]

TextureCoordinateScaling (2)

使用未经缩放的 Re[z] 和 Im[z] 坐标：

Wolfram Language code: ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, PlotStyle -> Texture[[image]], TextureCoordinateScaling -> False]

使用未经缩放的 Abs[z] 和 Arg[z] 坐标：

Wolfram Language code:

ComplexRegionPlot[Abs[z] < 1, {z, -1 - I, 1 + I}, PlotStyle -> Texture[[image]], TextureCoordinateFunction -> ({#3, #4}&), TextureCoordinateScaling -> False, PlotPoints -> 100]

应用 (25)

基本形状 (5)

用 Arg 绘制上半平面：

Wolfram Language code: ComplexRegionPlot[Arg[z] ≥ 0, {z, -2 - 2I, 2 + 2I}]

用 Im 绘制相同的半平面：

Wolfram Language code: ComplexRegionPlot[Im[z] ≥ 0, {z, -2 - 2I, 2 + 2I}]

在复平面上绘制条带：

Wolfram Language code: ComplexRegionPlot[-1 ≤ Re[z] + Im[z] ≤ 1, {z, -2 - 2I, 2 + 2I}]

将条带向右移动一个单位：

Wolfram Language code: ComplexRegionPlot[-1 ≤ Re[z - 1] + Im[z - 1] ≤ 1, {z, -2 - 2I, 2 + 2I}]

绘制复平面的一个象限：

Wolfram Language code: ComplexRegionPlot[0 < Arg[z] ≤ (π/2), {z, -2 - 2I, 2 + 2I}]

绘制角度为的扇区：

Wolfram Language code: ComplexRegionPlot[0 < Arg[z] ≤ (π/4), {z, -2 - 2I, 2 + 2I}]

绘制半径为 2 的圆盘：

Wolfram Language code: ComplexRegionPlot[Abs[z] < 2, {z, -3 - 3I, 3 + 3I}]

将圆盘的圆心置于：

Wolfram Language code: ComplexRegionPlot[Abs[z - (1 + I)] < 2, {z, -3 - 3I, 3 + 3I}]

用两个不等式绘制圆环：

Wolfram Language code: ComplexRegionPlot[1 < Abs[z] < 2, {z, -3 - 3I, 3 + 3I}]

将圆环的圆心置于：

Wolfram Language code: ComplexRegionPlot[1 < Abs[z - (1 + I)] < 2, {z, -3 - 3I, 3 + 3I}]

复杂形状 (2)

用不等式的逻辑组合来绘制两个基本形状的并集：

Wolfram Language code: ComplexRegionPlot[Abs[z - 1] < 2 || Abs[z + 1] < 2, {z, -3 - 3I, 3 + 3I}]

绘制相交的部分：

Wolfram Language code: ComplexRegionPlot[Abs[z - 1] < 2 && Abs[z + 1] < 2, {z, -3 - 3I, 3 + 3I}]

绘制心形图：

Wolfram Language code: ComplexRegionPlot[(Abs[z]^2 - Re[z])^2 ≤ Abs[z]^2, {z, -2 - 2I, 2 + 2I}]

蜗形图：

Wolfram Language code: ComplexRegionPlot[(Abs[z]^2 + 2 Re[z])^2 ≤ Abs[z]^2, {z, -3 - 3I, 3 + 3I}]

双纽图：

Wolfram Language code: ComplexRegionPlot[Abs[z]^4 ≤ 2Im[z]Re[z], {z, -1 - I, 1 + I}]

将双纽图旋转 45 度：

Wolfram Language code: ComplexRegionPlot[Abs[(1 + I) / Sqrt[2]z]^4 ≤ 2Im[(1 + I) / Sqrt[2]z]Re[(1 + I) / Sqrt[2]z], {z, -1 - I, 1 + I}]

数学恒等式 (1)

代数中的常用则并不总是适用于复变量. 例如，对于复数，并不总是等于 . 用试一下：

Wolfram Language code: {((-1.0)^2)^1 / 3, (-1.0)^2 / 3}

绘制的区域：

Wolfram Language code: ComplexRegionPlot[(z^2)^1 / 3 == z^2 / 3, {z, -1 - I, 1 + I}]

绘制的区域：

Wolfram Language code: ComplexRegionPlot[Log[z^3] == 3Log[z], {z, -1 - I, 1 + I}]

绘制的区域：

Wolfram Language code: ComplexRegionPlot[LogGamma[z] == Log[Gamma[z]], {z, -15 - 15I, 15 + 15I}]

收敛区域 (6)

绘制几何级数的收敛区域：

Wolfram Language code: region = SumConvergence[z^n, n]

Wolfram Language code: ComplexRegionPlot[region, {z, -1 - I, 1 + I}]

绘制 Laurent 级数的收敛区域：

Wolfram Language code: region = SumConvergence[(1/(2z)^n) + z^n, n]

Wolfram Language code: ComplexRegionPlot[region, {z, -1 - I, 1 + I}]

绘制无穷级数的收敛区域：

Wolfram Language code: region = SumConvergence[(1/(4z^2 + 1)^n) + Sin[6z]^n, n]

Wolfram Language code: ComplexRegionPlot[region, {z, -(π/2) - I, (π/2) + I}]

绘制相关幂级数的收敛区间：

Wolfram Language code:

summands = Table[(1/c)(1 - (z/c))^n, {c, {1, I, -1, -I}}]
regions = SumConvergence[#, n]& /@ summands

Wolfram Language code: ComplexRegionPlot[regions, {z, -2 - 2I, 2 + 2I}]

对于所有的复数，无穷和为，可在整个复平面上解析连续：

Wolfram Language code: Sum[summands, {n, 0, ∞}]

计算拉普拉斯变换：

Wolfram Language code: int = Integrate[Sin[t]E^-s t, {t, 0, ∞}]

提取收敛条件并绘图：

Wolfram Language code: Last[int]

Wolfram Language code: ComplexRegionPlot[%, {s, -3 - 3I, 3 + 3I}]

计算梅林变换：

Wolfram Language code: int = Integrate[Sin[t]t^s - 1, {t, 0, ∞}]

提取收敛条件并绘图：

Wolfram Language code: Last[int]

Wolfram Language code: ComplexRegionPlot[%, {s, -3 - 3I, 3 + 3I}]

映射复区域 (7)

定义一个复常数：

Wolfram Language code: b = 1 + I;

定义一个加性函数，将平面的区域移动，移至平面中，并保持大小、形状和方位不变：

Wolfram Language code: f[z_] := z + b

在平面中指定一个长方形：

Wolfram Language code: rect[z_] := -1 ≤ Re[z] ≤ 1 && -2 ≤ Im[z] ≤ 2

通过对应用 rect，可获得平面中区域的代数表示：

Wolfram Language code: Reduce[ComplexExpand[rect[InverseFunction[f][x + I y]]]]

绘制平面和平面中的长方形：

Wolfram Language code:

{ComplexRegionPlot[rect[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[rect[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

如果绘制 rect[f[z]]，可获得 rect[z] 的预映射：

Wolfram Language code: ComplexRegionPlot[rect[f[z]], {z, -3 - 3I, 3 + 3I}]

指定平面上的圆盘：

Wolfram Language code: disk[z_] := Abs[z] ≤ 1

绘制平面和平面上的圆盘：

Wolfram Language code:

{ComplexRegionPlot[disk[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[disk[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

定义一个复常数：

Wolfram Language code: c = (1 + I/2);

定义一个线性函数，将平面上的区域缩放和旋转至平面，保持形状不变：

Wolfram Language code: f[z_] := c z

在平面中指定一个长方形：

Wolfram Language code: rect[z_] := -1 ≤ Re[z] ≤ 1 && -2 ≤ Im[z] ≤ 2

绘制平面和平面中的长方形：

Wolfram Language code:

{ComplexRegionPlot[rect[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[rect[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

从平面到平面的缩放因子为 Abs[c]，旋转角度为 Arg[c]：

Wolfram Language code: AbsArg[c]

指定平面上的圆盘：

Wolfram Language code: disk[z_] := Abs[z] ≤ 1

绘制平面和平面上的圆盘：

Wolfram Language code:

{ComplexRegionPlot[disk[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[disk[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

定义两个复常数：

Wolfram Language code:

b = 1 + I;
c = (1 + I/2);

定义一个仿射函数，将缩放 Abs[c]、旋转 Arg[c] 和平移组合在一起：

Wolfram Language code: f[z_] := c z + b

在平面中指定一个长方形：

Wolfram Language code: rect[z_] := -1 ≤ Re[z] ≤ 1 && -2 ≤ Im[z] ≤ 2

绘制平面和平面中的长方形：

Wolfram Language code:

{ComplexRegionPlot[rect[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[rect[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

指定平面上的圆盘：

Wolfram Language code: disk[z_] := Abs[z] ≤ 1

绘制平面和平面上的圆盘：

Wolfram Language code:

{ComplexRegionPlot[disk[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[disk[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

倒数函数将圆心位于的圆的内部映射到其外部：

Wolfram Language code: f[z_] := (1/z)

指定平面上的圆盘：

Wolfram Language code: disk[z_] := Abs[z] ≤ 1

Wolfram Language code:

{ComplexRegionPlot[disk[z], {z, 3}, PlotLabel -> z], 
	Quiet@ComplexRegionPlot[disk[InverseFunction[f][z]], {z, 3}, PlotLabel -> f[z]]}

指定平面上的正方形：

Wolfram Language code: square[z_] := -1 ≤ Re[z] ≤ 1 && -1 ≤ Im[z] ≤ 1

绘制平面上的正方形及其在平面上的映射：

Wolfram Language code:

{ComplexRegionPlot[square[z], {z, 3}, PlotLabel -> z], 
	Quiet@ComplexRegionPlot[square[InverseFunction[f][z]], {z, 3}, PlotLabel -> f[z]]}

为了确定平面中边界的形状，考虑平面中正方形的上边缘，即，，显示它对应于平面中以为圆心，半径为的半圆：

Wolfram Language code:

{u, v} = Simplify[ReIm[ComplexExpand[f[x + I]]], x∈Reals]
Simplify[u^2 + (v + (1/2))^2 == (1/4)]

或者，以代数形式描述转换后的区域：

Wolfram Language code: ComplexExpand[square[f[x + I * y]]]

将复合不等式分为两个部分，说明有四个有界半圆：

Wolfram Language code: RegionPlot[{-1 ≤ (x/x^2 + y^2) ≤ 1, -1 ≤ -(y/x^2 + y^2) ≤ 1}, {x, -3, 3}, {y, -3, 3}]

线性分式变换以将圆和线映射到圆和线著名. 下面的线性分式变换将上半平面映射到单位圆盘：

Wolfram Language code: f[z_] := (I - z/I + z)

定义指定上半平面的函数：

Wolfram Language code: upper[z_] := Im[z] ≥ 0

绘制平面的上半平面及其在平面上的映射：

Wolfram Language code:

{ComplexRegionPlot[upper[z], {z, -3 - 3I, 3 + 3I}, Axes -> True, PlotLabel -> z], 
	Quiet@ComplexRegionPlot[upper[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, Axes -> True, PlotLabel -> f[z]]}

定义一个单位圆盘：

Wolfram Language code: disk[z_] := Abs[z] ≤ 1

显示单位圆盘被映射到右半平面：

Wolfram Language code:

{ComplexRegionPlot[disk[z], {z, 3}, PlotLabel -> z], 
	Quiet@ComplexRegionPlot[disk[InverseFunction[f][z]], {z, 3}, PlotLabel -> f[z]]}

定义指定右半平面的函数：

Wolfram Language code: right[z_] := Re[z] ≥ 0

显示右半平面被映射至上半平面：

Wolfram Language code:

{ComplexRegionPlot[right[z], {z, 3}, PlotLabel -> z], 
	Quiet@ComplexRegionPlot[right[InverseFunction[f][z]], {z, 3}, PlotLabel -> f[z]]}

这说明，可通过 NestList 来确认这一点：

Wolfram Language code: Simplify[NestList[f, z, 3]]

指定一个长方形：

Wolfram Language code: rect[z_] := -1 ≤ Re[z] ≤ 1 && -2 ≤ Im[z] ≤ 2

矩形的边界由线组成，其映射的边界由圆组成：

Wolfram Language code:

{ComplexRegionPlot[rect[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[rect[InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

定义一个指数函数：

Wolfram Language code: f[z_] := Exp[z / 2]

定义平面上的长方形：

Wolfram Language code: rect[z_] := 1 ≤ Re[z] ≤ 2 && 0 ≤ Im[z] ≤ π

平面上的长方形被映射至平面上一个圆盘的扇区：

Wolfram Language code:

{ComplexRegionPlot[rect[z], {z, 0, 4 + 4I}, PlotLabel -> z], 
	ComplexRegionPlot[rect[Quiet@InverseFunction[f][z]], {z, 0, 4 + 4I}, PlotLabel -> f[z]]}

定义一个平面上的单位圆盘：

Wolfram Language code: disk[z_] := Abs[z] ≤ 1

平面上的单位圆盘被映射到平面上的另一个圆盘：

Wolfram Language code:

{ComplexRegionPlot[disk[z], {z, -3 - 3I, 3 + 3I}, PlotLabel -> z], 
	ComplexRegionPlot[disk[Quiet@InverseFunction[f][z]], {z, -3 - 3I, 3 + 3I}, PlotLabel -> f[z]]}

定义一个对数函数：

Wolfram Language code: f[z_] := Log[(z - 1/z + 1)]

可以明确计算 f 的反函数：

Wolfram Language code: sol = z /. Solve[w == f[z], z][[1]]

定义一个圆环：

Wolfram Language code: annulus[z_] := 1 < Abs[z] ≤ 1.5

圆环被映射到水平条带内的椭圆的外部：

Wolfram Language code:

{ComplexRegionPlot[annulus[z], {z, -2 - 2I, 2 + 2I}, Axes -> True, PlotLabel -> z], 
	Quiet@ComplexRegionPlot[annulus[sol], {w, -4 - 4I, 4 + 4I}, Axes -> True, PlotLabel -> w, FrameTicks -> {{Range[-π, π, π / 2], Automatic}, {Range[-π, π, π / 2], Automatic}}]}

物理应用 (1)

绘制蜗形图及其内部：

Wolfram Language code: limacon[z_] := Evaluate[(Abs[z]^2 - b Re[z])^2 ≤ a^2Abs[z]^2 /. {b -> 0.2, a -> 1.7}]

Wolfram Language code: ComplexRegionPlot[limacon[z], {z, -2 - 2I, 2 + 2I}, Axes -> True]

通过 Joukowski 变换将蜗形图映射为 Joukowski 翼型：

Wolfram Language code:

c = 3 / 2;
sol = z /. Solve[w == z + (c^2/z), z]

用第一个解绘制 Re[w]<0 的翼型：

Wolfram Language code: trailingEdge = ComplexRegionPlot[Evaluate[limacon[sol[[1]]]], {w, -4 - 4 I, 4I}, PlotPoints -> 51]

用第二个解绘制 Re[w]≥0 的翼型：

Wolfram Language code: leadingEdge = ComplexRegionPlot[Evaluate[limacon[sol[[2]]]], {w, -4 I, 4 + 4 I}, PlotPoints -> 51]

显示整个翼型：

Wolfram Language code: Show[trailingEdge, leadingEdge, PlotRange -> {{-4, 4}, {-4, 4}}, AspectRatio -> Automatic, Axes -> True]

其他应用 (3)

绘制等值线积分的区域：

Wolfram Language code:

ComplexRegionPlot[0.25 < Abs[z] < 1.5 && 0 < Arg[z] < π, {z, -2, 2 + 2I}, AspectRatio -> Automatic, PlotLabels -> Callout["𝒟", Above], FrameTicks -> {{None, None}, {{{-1.5, "-*R*"}, {-0.25, "-ρ"}, 0, {0.25, "ρ"}, {1.5, "R"}}, None}}]

沿的边界对进行积分，设，，可计算以下积分：

Wolfram Language code: Integrate[(Sin[x]/x), {x, 0, ∞}]

取决于 Arg[z]，复变量的函数渐近展开式会有不同. 区域之间的边界被称为（反）斯托克斯线. 例如，复变函数渐近等价于，因此可以将虚轴视为（反）斯托克斯线：

Wolfram Language code: ComplexRegionPlot[{Re[z] > 0, Re[z] < 0}, {z, -10 - 10I, 10 + 10I}]

来看一个不同的复变函数：

Wolfram Language code: f[z_] := BesselY[3, z^2 + z]

注意级数展开式对 Arg[z] 的依赖性较复杂：

Wolfram Language code: Series[f[z], {z, 0, 1}]

绘制三个不同的渐近展开式成立的区域：

Wolfram Language code:

ComplexRegionPlot[{Floor[-(-π + Arg[z] + Arg[1 + z]/2 π)] == -1, Floor[-(-π + Arg[z] + Arg[1 + z]/2 π)] == 0, Floor[-(-π + Arg[z] + Arg[1 + z]/2 π)] == 1}, {z, -2 - 2I, 2 + 2I}]

选取一个复变函数：

Wolfram Language code: f[z_] := z^3 - 2

求的解：

Wolfram Language code: roots = z /. Solve[f[z] == 0, z]

计算牛顿法的几次迭代：

Wolfram Language code: g[z_] := Nest[# - (f[#]/f'[#])&, 1.0z, 5]

设置容差：

Wolfram Language code: tol = 0.001;

绘制牛顿法的近似吸引域：

Wolfram Language code:

Show[Quiet@ComplexRegionPlot[Evaluate[Abs[g[z] - #] < tol& /@ roots], {z, -2 - 2I, 2 + 2I}, PlotPoints -> 50], 
	ComplexListPlot[roots, PlotStyle -> Directive[Black, PointSize[Medium]]]]

属性和关系 (8)

ComplexRegionPlot 是 RegionPlot 的特例：

Wolfram Language code:

{ComplexRegionPlot[Abs[Log[z]] < 1, {z, 3}], 
	RegionPlot[Abs[Log[x + I * y]] < 1, {x, -3, 3}, {y, -3, 3}]}

ComplexContourPlot 在复平面上绘制曲线：

Wolfram Language code: ComplexContourPlot[Abs[Log[z]] == 1, {z, 3}]

ComplexPlot 用颜色显示函数的辐角和大小：

Wolfram Language code: ComplexPlot[Log[z], {z, 3}]

通过 ComplexPlot3D 用轴显示幅值：

Wolfram Language code: ComplexPlot3D[Log[z], {z, 3}]

用 ComplexArrayPlot 绘制复数数组：

Wolfram Language code: ComplexArrayPlot[Table[x ^ 3 + I y ^ 2, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}]]

用 ReImPlot 和 AbsArgPlot 在实平面上绘制复数：

Wolfram Language code: ReImPlot[Log[x], {x, -3, 3}]

Wolfram Language code: AbsArgPlot[Log[x], {x, -3, 3}]

用 ComplexListPlot 显示复数在平面上的位置：

Wolfram Language code: ComplexListPlot[RandomComplex[{-3 - 3I, 3 + 3I}, 100]]

ComplexStreamPlot 和 ComplexVectorPlot 将复数视为方向：

Wolfram Language code: ComplexStreamPlot[Log[z], {z, 3}]

Wolfram Language code: ComplexVectorPlot[Log[z], {z, 3}]

Wolfram Language code: [image]

可能存在的问题 (1)

RegionPlot 只可视化二维区域：

Wolfram Language code: ComplexRegionPlot[Abs[z] == 1, {z, -1 - I, 1 + I}]

Top

	Annotation[pred_i,label]	为 pred_i 提供注释
	Button[pred_i,action]	当 pred_i 的曲线被点击时执行 action
	Callout[pred_i,label]	用标注 (callout) 标记区域
	Callout[pred_i,label,pos]	将标注放置在相对位置 pos
	EventHandler[pred_i,events]	定义 pred_i 的通用事件处理程序
	Hyperlink[pred_i,uri]	把区域变为一个超链接
	Labeled[pred_i,label]	标记区域
	Labeled[pred_i,label,pos]	将标签放置在相对位置 pos
	Legended[pred_i,label]	在图例中标识区域
	PopupWindow[pred_i,cont]	为区域添加弹出窗口
	StatusArea[pred_i,label]	当鼠标移过时在状态栏中显示
	Style[pred_i,styles]	用指定样式显示区域
	Tooltip[pred_i,label]	为区域添加提示条
	Tooltip[pred_i]	将区域用作提示条

	w[pred_i]	封装 pred_i
	w[{pred_i,…}]	封装一组 pred_i
	w₁[w₂[…]]	使用嵌套封装

	Automatic	自动放置标签
	Above, Below, Before, After	区域周围的位置
	z	z 附近的位置
	{pos,epos}	在区域的相对位置 pos 处放置的标签中的 epos

	None	没有图例
	Automatic	自动确定图例
	"Expressions"	用 f₁、f₂、… 作为图例标签
	{lbl₁,lbl₂,…}	用 lbl₁、lbl₂、… 作为图例标签
	Placed[lspec,…]	指定图例的放置

	{sty₁,sty₂,…}	针对各个数据集的一系列样式
	<\|"key"val,…\|>	针对不同层级的数据的样式元素

	"Base"	所有 f_i 的整体样式
	"Functions"	针对每个 f_i 的样式列表 sty_i

AlignmentPoint	Center	在图形内对齐的缺省点
AspectRatio	1	高宽比
Axes	False	是否绘制轴
AxesLabel	None	坐标轴标签
AxesOrigin	Automatic	坐标轴原点
AxesStyle	{}	坐标轴样式指定
Background	None	绘图的背景色
BaselinePosition	Automatic	如何与环绕文本基线对齐
BaseStyle	{}	图形的基本样式指定
BoundaryStyle	Automatic	每个区域的边界的样式
ColorFunction	Automatic	怎样为每个区域的内部着色
ColorFunctionScaling	True	是否对 ColorFunction 的参数进行缩放
ContentSelectable	Automatic	是否允许进行内容选择
CoordinatesToolOptions	Automatic	坐标工具的详细行为
Epilog	{}	主图形之后执行的图形指令
EvaluationMonitor	None	每次运行函数时要计算的表达式
FormatType	TraditionalForm	文本的缺省样式类型
Frame	True	是否为图形绘制边框
FrameLabel	None	边框标签
FrameStyle	{}	边框的样式指定
FrameTicks	Automatic	边框刻度
FrameTicksStyle	{}	边框刻度的样式指定
GridLines	None	绘制的网格线
GridLinesStyle	{}	网格线的样式指定
ImageMargins	0.	图形周围的边幅
ImagePadding	All	为标签等额外填充内容
ImageSize	Automatic	图形的绝对尺寸
LabelingSize	Automatic	最大化标注和标签的大小
LabelStyle	{}	标签的样式指定
MaxRecursion	Automatic	递归子划分的最大数量
Mesh	None	绘制多少条网格线
MeshFunctions	{#1&,#2&}	绘制什么样的网格线
MeshShading	None	怎样处理网格线之间区域的色调
MeshStyle	Automatic	网格线的样式
Method	Automatic	细化区域所用的方法
PerformanceGoal	$PerformanceGoal	优化的目标
PlotLabel	None	图形的一个整体标签
PlotLabels	None	曲线的标签
PlotLegends	None	区域的图例
PlotPoints	Automatic	初始采样点的个数

ComplexRegionPlot

更多信息和选项

所有选项的列表

范例

基本范例 (5)

范围 (23)

采样 (3)

添加标签和图例 (9)

演示 (11)

选项 (59)

BoundaryStyle (4)

ColorFunction (5)

ColorFunctionScaling (1)

LabelingSize (2)

MaxRecursion (1)

Mesh (7)

MeshFunctions (2)

MeshShading (4)

MeshStyle (2)

PerformanceGoal (2)

PlotLabels (5)

PlotLegends (8)

PlotPoints (1)

PlotRange (2)

PlotStyle (5)

PlotTheme (2)

TextureCoordinateFunction (4)

TextureCoordinateScaling (2)

应用 (25)

基本形状 (5)

复杂形状 (2)

数学恒等式 (1)

收敛区域 (6)

映射复区域 (7)

物理应用 (1)

其他应用 (3)

属性和关系 (8)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX