GammaDistribution
GammaDistribution
GammaDistribution[α,β]
形状母数 α，尺度母数 β のガンマ分布を表す．
GammaDistribution[α,β,γ,μ]
形状母数 α と γ，尺度母数 β，位置母数 μ の一般化されたガンマ分布を表す．
詳細
- ガンマ分布における値
の確率密度は，
のときは 
に比例し，
のときは0である． » - 一般化されたガンマ分布における値
の確率密度は，
では
に比例し，その他の場合は0である． - GammaDistributionでは，α，β，γ は任意の正の実数でよく，μ は任意の実数でよい．
- GammaDistributionでは，β と μ は単位次元が等しい任意の数量でよく，α と γ は無次元量でよい． »
- GammaDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »
予備知識
- GammaDistribution[α,β,γ,μ]は，区間
上で定義され，実数 μ （「位置母数」と呼ばれる），2つの正の実数 α と γ（「形状母数」と呼ばれる），正の実数 β （「尺度母数」と呼ばれる）でパラメータ化された連続統計分布を表す．母数 μ は，ガンマ分布の確率密度関数(PDF)の水平位置を決定する．PDFの形は，α，β，γ の取る値の組合せに完全に依存し，単峰性か潜在的な特異値が領域の下方境界に近付く単調減少のいずれかである．これに加え，PDFの裾部は，
の大きい値についてPDFが指数的に減少するという意味で「薄い」（この動作は，分布のSurvivalFunctionを分析することで数量的に正確にできる）．4母数バージョンは一般化されたガンマ分布と呼ばれることがあるのに対し，2母数形式のGammaDistribution[α,β]（GammaDistribution[α,β,1,0]に等しい）は，しばしば単にガンマ分布と呼ばれる． - （2母数の）ガンマ分布は1830年代のラプラスの業績まで遡ることができる．ラプラスは，標準変量の精度についての後方共役事前分布としてこれを得た．3母数形式および4母数形式への一般化は，ディリクレ積分公式についてのリウヴィルの業績まで遡ることができる．ガンマ分布の名称は，そのPDFにガンマ関数が存在することによる．ガンマ分布は，さまざまな分野における数量をモデル化するために使われる．統計学では，ガンマ分布は，多変量正規分布に従う変量中の独立単位正規変量の平方和と関連する分布であり，正定値二次元形式（
の形を持つもの）の分布の近似に使われる．ガンマ分布は，気象学，金融工学，統計生態学，個体群動態，ゲノミクス，神経科学，保険数理を含む他の多くの分野でも使われている． - RandomVariateを使ってガンマ分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,GammaDistribution[α,β,γ,μ]]（より簡略すると xGammaDistribution[α,β,γ,μ]）を使って，確率変数 x が，ガンマ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
- 確率密度関数および累積分布関数は，PDF[GammaDistribution[α,β,γ,μ],x]およびCDF[GammaDistribution[α,β,γ,μ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
- DistributionFitTestを使って，与えられたデータ集合がガンマ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックガンマ分布を推定することが，FindDistributionParametersを使ってデータをガンマ分布にフィットすることができる．ProbabilityPlotを使って記号ガンマ分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ガンマ分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
- TransformedDistributionを使って変換されたガンマ分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってガンマ分布を含む高次元分布を構築することが，ProductDistributionを使ってガンマ分布を含む独立成分分布の結合分布を計算することができる．
- ガンマ分布は他のいくつかの分布と関連している．先述した通り，GammaDistributionはNormalDistributionおよびMultinormalDistributionと緊密な関係があり，PoissonDistribution，NormalDistribution，ExponentialDistribution，GompertzMakehamDistributionを含む（ベイズ推論では）いくつかの分布の共役事前分布である．GammaDistributionはChiSquareDistribution（GammaDistribution[ν/2,
,2,0]のPDFはChiSquareDistribution[ν]のPDFと同じである），ExponentialDistribution（ExponentialDistribution[1/λ]のPDFはGammaDistribution[1,λ]のPDFと同じである），MaxwellDistribution（MaxwellDistribution[σ]のPDFはGammaDistribution[3/2,
σ,2,0]のPDFと厳密に等しい）に一般化される．これを変換してInverseGammaDistribution，MoyalDistribution，LogGammaDistribution等の分布を得ることができる．GammaDistributionは，PearsonDistribution，ErlangDistribution，BetaDistribution，ExpGammaDistribution，RayleighDistribution，ChiDistribution，WeibullDistribution，StudentTDistribution等とも関連している．
例題
すべて開く すべて閉じる例 (4)
Plot[Table[PDF[GammaDistribution[α, 2], x], {α, {1, 4, 6}}]//Evaluate, {x, 0, 20}, Filling -> Axis]Plot[Table[PDF[GammaDistribution[2, β], x], {β, {2, 4, 6}}]//Evaluate, {x, 0, 20}, Filling -> Axis]PDF[GammaDistribution[α, β], x]Plot[Table[CDF[GammaDistribution[α, 2], x], {α, {1, 4, 6}}]//Evaluate, {x, 0, 20}, Filling -> Axis]Plot[Table[CDF[GammaDistribution[2, β], x], {β, {2, 4, 6}}]//Evaluate, {x, 0, 20}, Filling -> Axis]CDF[GammaDistribution[α, β], x]Mean[GammaDistribution[α, β]]Variance[GammaDistribution[α, β]]Median[GammaDistribution[α, β]]スコープ (16)
基本的な用法 (9)
data = RandomVariate[GammaDistribution[3.5, 2], 10 ^ 4];Show[
Histogram[data, 15, "PDF"],
Plot[PDF[GammaDistribution[3.5, 2], x], {x, Min[data], Max[data]}, PlotStyle -> Thick]]data = RandomVariate[GammaDistribution[3.5, 2, 1.2, 1], 10 ^ 4];Show[
Histogram[data, 15, "PDF"],
Plot[PDF[GammaDistribution[3.5, 2, 1.2, 1], x], {x, Min[data], Max[data]}, PlotStyle -> Thick]]sample = RandomVariate[GammaDistribution[2, 3], 10 ^ 3];edist = EstimatedDistribution[sample, GammaDistribution[α, β]]サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 25}, PlotStyle -> Thick]]Plot[Table[Skewness[GammaDistribution[α, β, γ, μ]], {γ, {.5, .6, .7, 1, 1.5}}]//Evaluate, {α, 0, 1}, PlotLegends -> Map[TraditionalForm[γ == #]&, {.5, .6, .7, 1, 1.5}]]Skewness[GammaDistribution[α, β]]Limit[Skewness[GammaDistribution[α, β]], α -> ∞]Skewness[GammaDistribution[α, β, γ, μ]]Plot[Table[Kurtosis[GammaDistribution[α, β, γ, μ]], {γ, {.5, .6, .7, 1, 1.5}}]//Evaluate, {α, 0, 1}, PlotLegends -> Map[TraditionalForm[γ == #]&, {.5, .6, .7, 1, 1.5}]]Kurtosis[GammaDistribution[α, β]]極限では尖度はNormalDistributionのものに近付く：
Limit[Kurtosis[GammaDistribution[α, β]], α -> ∞]Kurtosis[GammaDistribution[α, β, γ, μ]]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[GammaDistribution[α, β], r]//Together, {r, 5}], M]Moment[GammaDistribution[α, β], r]FormulaGrid[Table[CentralMoment[GammaDistribution[α, β], r]//Together, {r, 5}], CM]CentralMoment[GammaDistribution[α, β], r]FormulaGrid[Table[FactorialMoment[GammaDistribution[α, β], r]//Together, {r, 5}], FM]FormulaGrid[Table[Cumulant[GammaDistribution[α, β], r], {r, 5}], C]Cumulant[GammaDistribution[α, β], r]Plot[Table[HazardFunction[GammaDistribution[α, 3], x], {α, {0.5, 1, 2}}]//Evaluate, {x, 0, 6}, Filling -> Axis]Plot[Table[HazardFunction[GammaDistribution[0.3, β], x], {β, {0.5, 1, 2}}]//Evaluate, {x, 0, 6}, Filling -> Axis]Plot[Table[HazardFunction[GammaDistribution[3, β], x], {β, {0.5, 1, 2}}]//Evaluate, {x, 0, 6}, Filling -> Axis]HazardFunction[GammaDistribution[α, β], x]Plot[Table[Quantile[GammaDistribution[α, 2], q], {α, {1, 4, 8}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Plot[Table[Quantile[GammaDistribution[2, β], q], {β, {1, 4, 8}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[GammaDistribution[α, β], q]母数でQuantityを一貫して使うとQuantityDistributionが与えられる：
arrivalTime𝒟 = GammaDistribution[1.6, Quantity[2.6, "Seconds"]]Median[arrivalTime𝒟]一般化されたガンマ分布 (7)
Plot[Table[PDF[GammaDistribution[3, 2, γ, 1], x], {γ, {1 / 4, 1 / 2, 1.5}}]//Evaluate, {x, 0.5, 6}, Filling -> Axis]Plot[Table[PDF[GammaDistribution[2.5, 1, .5, μ], x], {μ, {-1, 0.5, 1}}]//Evaluate, {x, -2, 6}, Filling -> Axis]PDF[GammaDistribution[α, β, γ, μ], x]Plot[Table[CDF[GammaDistribution[3, 2, γ, 1], x], {γ, {1 / 4, 1 / 2, 1.5}}]//Evaluate, {x, 0.5, 6}, Filling -> Axis]Plot[Table[CDF[GammaDistribution[2.5, 1, .5, μ], x], {μ, {-1, 0.5, 1}}]//Evaluate, {x, -2, 6}, Filling -> Axis]CDF[GammaDistribution[α, β, γ, μ], x]Mean[GammaDistribution[α, β, γ, μ]]Variance[GammaDistribution[α, β, γ, μ]]FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[GammaDistribution[α, β, γ, μ], k]//Simplify, {k, 3}], M]FormulaGrid[Table[CentralMoment[GammaDistribution[α, β, γ, μ], k]//Simplify, {k, 3}], CM]FormulaGrid[Table[FactorialMoment[GammaDistribution[α, β, γ, μ], k]//Simplify, {k, 3}], FM]FormulaGrid[Table[Factor[Cumulant[GammaDistribution[α, β, γ, μ], k]], {k, 3}], C]Median[GammaDistribution[α, β, γ, μ]]Plot[Table[Quantile[GammaDistribution[3, 2, γ, 1], q], {γ, {2, 4, 8}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[GammaDistribution[α, β, γ, μ], q]
Plot[Table[HazardFunction[GammaDistribution[.4, 3, γ, 1], x], {γ, {0.5, 1.5, 3}}]//Evaluate, {x, 1, 5}, Filling -> Axis]
Plot[Table[HazardFunction[GammaDistribution[5, 3, γ, 1], x], {γ, {0.5, 1.5, 3}}]//Evaluate, {x, 1, 5}, Filling -> Axis]アプリケーション (6)
寿命がガンマ分布に従うデバイスがある．このデバイスの信頼性を求める：
r = SurvivalFunction[GammaDistribution[α, β], t]
HazardFunction[GammaDistribution[α, β], t]rs = r r//PiecewiseExpandrp = 1 - (1 - r)(1 - r)//PiecewiseExpand
Block[{α = 2, β = 1.5}, Plot[{rs, rp}, {t, 0, 12}, PlotLegends -> {"in series", "in parallel"}]]寿命にA，B，Cの3段階があるデバイスがある．各段階の時間は平均が10時間の指数分布に従う．段階Cの後でこのデバイスは故障する．このデバイスの故障までの時間の分布を求める：
timeToFailure = GammaDistribution[3, Quantity[10, "Hours"]]Plot[PDF[timeToFailure, Quantity[x, "Hours"]]//Evaluate, {x, 0, 70}, AxesLabel -> Automatic, Filling -> Axis]Mean[timeToFailure]このようなデバイスが最低40時間使用可能である確率を求める：
Probability[t ≥ Quantity[40, "Hours"], ttimeToFailure]N[%]30個の独立したデバイスの故障までの時間のシミュレーションを行う：
ListPlot[{RandomVariate[timeToFailure, 30], {{0, Mean[timeToFailure]}, {30, Mean[timeToFailure]}}}, Filling -> Axis, Joined -> {False, True}, AxesLabel -> Automatic]朝の混雑する時間帯にある喫茶店に10分間に8人の客が来店する．1人の客が来店してから次の客が来店するまでの時間は指数分布に従い，
人の来店時間の間隔はGammaDistribution[k,1/λ]分布に従う．45分間に少なくとも40人が来店する確率を求める：
CDF[𝒟 = GammaDistribution[40, Quantity[1.25, "Minutes"]], Quantity[45, "Minutes"]]Mean[𝒟]40番目の客が来店するまでの時間が少なくとも1時間である確率を求める：
NProbability[x ≥ Quantity[1, "Hours"], x𝒟]朝の混雑する時間帯に40番目の客が来店するまでの時間の30日間のシミュレーションを行う：
ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Filling -> Axis, Joined -> {False, True}, AxesLabel -> Automatic]ガンマ分布の混合分布を使ってマルチモーダルデータのモデル化を行うことができる：
ExampleData[{"Statistics", "OldFaithful"}, "ColumnDescriptions"]waiting = QuantityArray[ExampleData[{"Statistics", "OldFaithful"}][[All, 2]], "Minutes"]オールド・フェイスフル・ガイザーの噴出までの待ち時間のヒストグラムは2つのモードを示している：
h = Histogram[waiting, 20, "PDF", AxesLabel -> Automatic]MixtureDistributionをデータにフィットさせる：
mdist = QuantityDistribution[MixtureDistribution[{1 / 3, 2 / 3},
{GammaDistribution[a, b], GammaDistribution[c, d]}], "Minutes"];params = FindDistributionParameters[waiting, mdist, {{a, 85}, {b, .5}, {c, 195}, {d, .4}}]edist = mdist /. paramsShow[h, Plot[PDF[edist, Quantity[x, "Minutes"]], {x, 10, 100}, PlotStyle -> Thick]]NProbability[x > Quantity[80, "Minutes"], xedist]Mean[edist]{m1, m2} = Quantity[{Mean[GammaDistribution[a, b]], Mean[GammaDistribution[c, d]]}, "Minutes"] /. paramstimes = RandomVariate[edist, 60];ListPlot[{times, {{1, m1}, {60, m1}}, {{1, m2}, {60, m2}}}, Joined -> {False, True, True}, Filling -> {1 -> Axis}, AxesOrigin -> {0, 40}]ガンマ分布を使ってLogNormalDistributionに従うデータをモデル化することができる：
sample = RandomVariate[LogNormalDistribution[2, 0.3], 10 ^ 4];edist1 = EstimatedDistribution[sample, GammaDistribution[α, β]]Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist1, x], {x, 0, 20}, PlotStyle -> Thick]]edist2 = EstimatedDistribution[sample, LogNormalDistribution[μ, σ]]{LogLikelihood[edist1, sample], LogLikelihood[edist2, sample]}Stacy分布は一般化されたGammaDistributionの特殊ケースである：
StacyDistribution = GammaDistribution[α, β, γ, 0];PDF[StacyDistribution, x]Block[{β = 1.3, γ = 0.7}, Plot[Table[PDF[StacyDistribution, x], {α, {2, 2.5, 4}}]//Evaluate, {x, 0, 12}, PlotLegends -> Map[TraditionalForm[α == #]&, {2, 2.5, 4}]]]特性と関係 (32)
TransformedDistribution[a * u, uGammaDistribution[α, β]]一般化されたガンマ分布は平行移動と正の因子によるスケーリングの下では閉じている：
TransformedDistribution[a * u + b, uGammaDistribution[α, β, γ, μ]]TransformedDistribution[u + v, {uGammaDistribution[Subscript[α, 1], β], vGammaDistribution[Subscript[α, 2], β]}]
CharacteristicFunction[GammaDistribution[α, β], t] ^ n//PowerExpandCharacteristicFunction[GammaDistribution[n α, β], t]% - %%GammaDistribution[α,β]は α->∞ の極限で正規分布に収束する：
{μ, σ} = {Mean[GammaDistribution[α, β]], Sqrt[Variance[GammaDistribution[α, β]]]}Block[{β = 0.01}, Table[Plot[{PDF[GammaDistribution[α, β], x], PDF[NormalDistribution[μ, σ], x]}, {x, μ - 2σ, μ + 2σ}, AxesOrigin -> {μ - 3σ, 0}, Ticks -> {{{μ - 2σ, HoldForm[μ - 2σ]}, {μ, HoldForm[μ]}, {μ + 2σ, HoldForm[μ + 2σ]}}, Automatic}, PlotLabel -> α], {α, {5, 10, 25, 100}}]]
ChiSquareDistributionはガンマ分布の特殊なケースである：
PDF[ChiSquareDistribution[ 2n], x]PDF[GammaDistribution[n, 2], x]% - %%スケールされたChiSquareDistributionはガンマ分布に従う：
TransformedDistribution[c * X, XChiSquareDistribution[a], Assumptions -> c > 0]ChiDistributionはGammaDistributionの特殊ケースである：
PDF[GammaDistribution[1 / 2 ν, Sqrt[2], 2, 0], x]PDF[ChiDistribution[ν], x]% - %%//SimplifyExponentialDistributionはガンマ分布の特殊なケースである：
PDF[ExponentialDistribution[1 / λ], x]PDF[GammaDistribution[1, λ], x]% - %%//FullSimplify[#, x > 0]&ExponentialDistributionに従う 
個の変量の総和はガンマ分布に従う：
CharacteristicFunction[ExponentialDistribution[λ], t] ^ kCharacteristicFunction[GammaDistribution[k, 1 / λ], t]//FullSimplify[#, Element[k, Integers]]&% - %%//FullSimplify[#, k∈Integers]&
TransformedDistribution[u + v + w, {u, v, w}ProductDistribution[{ExponentialDistribution[λ], 3}]]ガンマ分布とInverseGammaDistributionは逆分布の関係にある：
𝒟 = TransformedDistribution[1 / z, zGammaDistribution[α, 1 / β]];PDF[𝒟, x]PDF[InverseGammaDistribution[α, β], x]FullSimplify[% - %%, α > 0 && β > 0 && (x < 0 || x > 0)]PDF[GammaDistribution[α, β, 1, 0], x]PDF[GammaDistribution[α, β], x]Simplify[%% - %, α > 0 && β > 0]MaxwellDistributionはGammaDistributionの特殊ケースである：
PDF[GammaDistribution[3 / 2, Sqrt[2] σ, 2, 0], x]PDF[MaxwellDistribution[σ], x]% - %%//SimplifyMoyalDistributionはGammaDistributionを変換したものである：
𝒟 = TransformedDistribution[μ - σ * Log[u], uGammaDistribution[1 / 2, 2], Assumptions -> σ > 0];PDF[𝒟, x]//PowerExpandPDF[MoyalDistribution[μ, σ], x]% - %%//SimplifyRayleighDistributionはGammaDistributionの特殊ケースである：
PDF[GammaDistribution[1, σSqrt[2], 2, 0], x]PDF[RayleighDistribution[σ], x]% - %%NakagamiDistributionはGammaDistributionの特殊ケースである：
PDF[GammaDistribution[μ, Sqrt[ω] / Sqrt[μ], 2, 0], x]//FullSimplifyPDF[NakagamiDistribution[μ, ω], x]% - %%//Simplify[#, ω > 0 && μ > 0]&WeibullDistributionは一般化されたガンマ分布の特殊ケースである：
PDF[GammaDistribution[1, β, γ, μ], x]PDF[WeibullDistribution[γ, β, μ], x]Simplify[%% - %]HalfNormalDistributionは一般化されたガンマ分布の特殊ケースである：
PDF[GammaDistribution[1 / 2, Sqrt[π] / θ, 2, 0], x]PDF[HalfNormalDistribution[θ], x]Simplify[%% - %]一般化されたガンマ分布はガンマ分布からの変形として得ることができる：
CDF[GammaDistribution[α, 1], ((x - μ) / β) ^ γ]//FunctionExpandCDF[GammaDistribution[α, β, γ, μ], x]//FunctionExpand% - %%//FullSimplify[#, β > 0 && γ > 0 && x > μ]&ErlangDistributionはガンマ分布の特殊なケースである：
PDF[ErlangDistribution[k, 1 / λ], x]PDF[GammaDistribution[k, λ], x]Simplify[%% - %]ガンマ分布はLogGammaDistributionに関連している：
𝒟 = TransformedDistribution[Log[u + 1], uLogGammaDistribution[α, β, 0]];PDF[𝒟, x]//FullSimplify[#, x∈Reals]&PDF[GammaDistribution[α, β], x]Simplify[% - %%, x > 0]GammaDistributionはExpGammaDistributionに関連している：
𝒟 = TransformedDistribution[θ Log[u], uGammaDistribution[κ, 1], Assumptions -> θ > 0];SurvivalFunction[𝒟, x]//FunctionExpand//FullSimplify[#, x∈Reals && θ > 0]&SurvivalFunction[ExpGammaDistribution[κ, θ, 0], x]//FunctionExpand% - %%BetaPrimeDistributionは一般化されたGammaDistributionの商として得ることができる：
TransformedDistribution[u / v, {uGammaDistribution[p, 1, a, 0], vGammaDistribution[q, 1, a, 0]}]ParetoDistributionはGammaDistributionの商として得ることができる：
TransformedDistribution[u / v, {uGammaDistribution[1, a], vGammaDistribution[1, b]}]GammaDistributionはタイプ3のピアソン分布(PearsonDistribution)の特殊ケースである：
PDF[PearsonDistribution[3, 1, -α β + β, 0, β, 0], x]//FullSimplify[#, β > 0]&PDF[GammaDistribution[α, β], x]% - %%BetaDistributionは2つの独立したガンマ変数を変換したものとして得ることができる：
TransformedDistribution[u / (u + v), {uGammaDistribution[Subscript[α, 1], β], vGammaDistribution[Subscript[α, 2], β]}]KDistributionはExponentialDistributionとGammaDistributionから得ることができる：
TransformedDistribution[Sqrt[u v], {uExponentialDistribution[λ], vGammaDistribution[α, β]}]ガンマ分布の差はVarianceGammaDistributionに従う：
TransformedDistribution[u - v, {uGammaDistribution[α, Subscript[β, 1]], vGammaDistribution[α, Subscript[β, 2]]}]KDistributionはRayleighDistributionとGammaDistributionの母数混合として表すことができる：
𝒟 = ParameterMixtureDistribution[RayleighDistribution[Sqrt[σ]], σGammaDistribution[α, β / (2α)]]NegativeBinomialDistributionはPoissonDistributionとGammaDistributionを混合したものである：
ParameterMixtureDistribution[PoissonDistribution[μ], μGammaDistribution[n, (1 - p) / p]]//SimplifyGeometricDistributionはPoissonDistributionとGammaDistributionを混合したものである：
ParameterMixtureDistribution[PoissonDistribution[μ], μGammaDistribution[1, (1 - p) / p]]//SimplifyStudentTDistributionはNormalDistributionとGammaDistributionの母数混合分布である：
ParameterMixtureDistribution[NormalDistribution[μ, 1 / Sqrt[σ]], σGammaDistribution[α, β]]ParetoDistributionはExponentialDistributionとGammaDistributionの商として求めることができる：
𝒟 = TransformedDistribution[u / v, {uExponentialDistribution[λ], vGammaDistribution[n, 1 / λ]}];PDF[𝒟, x]PDF[ParetoDistribution[1, n, 0], x]FullSimplify[% - %%, x ≠ 0]考えられる問題 (2)
GammaDistributionは，α あるいは β が正の実数ではないときは定義されない：
Mean[GammaDistribution[-1, 5]]
記号出力に無効な母数値を代入すると意味のない結果が返される：
Mean[GammaDistribution[α, β]] /. {α -> 1, β -> 3 + I}おもしろい例題 (1)
累積分布関数の等高線を持つ β のさまざまな値についての確率密度関数：
cdf = Function[{x, β}, Evaluate[CDF[GammaDistribution[2, β], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[GammaDistribution[2, β], x], {x, 0, 4}, {β, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 100, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 1.8}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2007), GammaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/GammaDistribution.html （2016年に更新）.
テキスト
Wolfram Research (2007), GammaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/GammaDistribution.html （2016年に更新）.
CMS
Wolfram Language. 2007. "GammaDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/GammaDistribution.html.
APA
Wolfram Language. (2007). GammaDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GammaDistribution.html