WOLFRAM

Wolfram 语言与系统参考资料中心

RectangleChart[{{x1,y1},{x2,y2},…}]

绘制一个矩形图表，其中竖条的宽度为 xi，高度为 yi.

RectangleChart[{…,wi[{xi,yi},…],…,wj[{xi,yj},…],…}]

绘制一个矩形图表，其中竖条的特性由符号封装 wk 定义.

RectangleChart[{data1,data2,…}]

根据多个数据集 datai 绘制矩形图表.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据和布局  
表格数据  
封装  
样式和外观  
标签和图例  
选项  
AspectRatio  
Axes  
AxesStyle  
Show More Show More
BarOrigin  
BarSpacing  
ChartElementFunction  
ChartElements  
ColorFunction  
ColorFunctionScaling  
ImageSize  
LabelingFunction  
LabelingSize  
PerformanceGoal  
PlotInteractivity  
PlotLabels  
PlotLayout  
PlotLegends  
PlotStyle  
PlotTheme  
TargetUnits  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

RectangleChart

RectangleChart[{{x1,y1},{x2,y2},…}]

绘制一个矩形图表，其中竖条的宽度为 xi，高度为 yi.

RectangleChart[{…,wi[{xi,yi},…],…,wj[{xi,yj},…],…}]

绘制一个矩形图表，其中竖条的特性由符号封装 wk 定义.

RectangleChart[{data1,data2,…}]

根据多个数据集 datai 绘制矩形图表.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

根据高度和宽度列表，产生一个矩形图表：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}]

多个数据集：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{3, 2}, {1, 3}, {2, 1}}}]

将多个数据集显示为一行图表：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{3, 2}, {1, 3}, {2, 1}}}, ChartLayout -> "Row"]

用分类标签：

Wolfram Language code: data = {{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}};
Wolfram Language code: RectangleChart[data, PlotLabels -> <|"Elements" -> {"a", "b", "c"}|>]

分类图例：

Wolfram Language code: RectangleChart[data, PlotLegends -> <|"Elements" -> {"a", "b", "c"}|>]

设置竖条的样式：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], PlotStyle -> {RGBColor[0.237736, 0.340215, 0.575113], RGBColor[0.33311066666666667, 0.5032283333333333, 0.26154733333333335], RGBColor[0.8562609999999999, 0.742794, 0.31908333333333333], RGBColor[0.72987, 0.239399, 0.230961]}]

绘图竖条：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {[image], {All, 1}}]

程序竖条：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElementFunction -> "GlassRectangle", PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}]

范围  (41)

数据和布局  (13)

对数据集中的项进行分组：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 1}, {1, 1}}, {{2, 2}, {2, 2}, {2, 2}}}]

数据集不需要有相同数量的茎：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}]

忽略非实数数据：

Wolfram Language code: RectangleChart[{{{1, 1}, Missing[], {1, 1}, {1, 1}}, {{2, 2}, 1 + I, {2, 2}}, {foo, {3, 3}}}]

数据可能包括单位：

Wolfram Language code: RectangleChart[{{Quantity[3, "Seconds"], Quantity[2, "Meters"]}, {Quantity[8, "Seconds"], Quantity[5, "Meters"]}, {Quantity[2, "Seconds"], Quantity[3, "Meters"]}, {Quantity[1, "Seconds"], Quantity[3, "Meters"]}, {Quantity[8, "Seconds"], Quantity[7, "Meters"]}, {Quantity[7, "Seconds"], Quantity[1, "Meters"]}}, AxesLabel -> Automatic, BarSpacing -> None, Ticks -> True]

指定使用的单位：

Wolfram Language code: RectangleChart[{{Quantity[3, "Seconds"], Quantity[2, "Meters"]}, {Quantity[8, "Seconds"], Quantity[5, "Meters"]}, {Quantity[2, "Seconds"], Quantity[3, "Meters"]}, {Quantity[1, "Seconds"], Quantity[3, "Meters"]}, {Quantity[8, "Seconds"], Quantity[7, "Meters"]}, {Quantity[7, "Seconds"], Quantity[1, "Meters"]}}, AxesLabel -> Automatic, BarSpacing -> None, Ticks -> True, TargetUnits -> {"Minutes", "Feet"}]

忽略 TimeSeries、EventSeries 和 TemporalData 中的时间戳：

Wolfram Language code: RectangleChart[TimeSeries[{{19, 16}, {9, 3}, {7, 2}, {17, 5}}, {"May 24, 1982"}]]

相关性中的数值作为条柱的维度：

Wolfram Language code: RectangleChart[<|"a" -> {1, 1}, "b" -> {1, 2}, "c" -> {2, 1}, "d" -> {2, 2}|>]

将键值作为标签使用：

Wolfram Language code: RectangleChart[<|"a" -> {1, 1}, "b" -> {1, 2}, "c" -> {2, 1}, "d" -> {2, 2}|>, PlotLabels -> Automatic]

把键作为标注 (callout)：

Wolfram Language code: RectangleChart[<|"a" -> {1, 1}, "b" -> {1, 2}, "c" -> {2, 1}, "d" -> {2, 2}|>, PlotLabels -> Callout[Automatic, Above]]

将键值作为图例使用：

Wolfram Language code: RectangleChart[<|"a" -> {1, 1}, "b" -> {1, 2}, "c" -> {2, 1}, "d" -> {2, 2}|>, PlotLegends -> Automatic, PlotStyle -> {RGBColor[0.65, 0., 0.], RGBColor[0.0504678, 0.526626, 0.627561], RGBColor[0.752461, 0.362306, 0.125339], RGBColor[0.435888, 0.259065, 0.71028]}]

相关性可以是嵌套的：

Wolfram Language code: RectangleChart[<|"group a" -> <|"a" -> {1, 2}, "b" -> {2, 1}|>, "group b" -> <|"a" -> {1, 1}, "b" -> {2, 2}|>|>, PlotLegends -> Automatic]

忽略 WeightedData 中的权值；

Wolfram Language code: RectangleChart[WeightedData[{{1, 1}, {2, 1}, {3, 2}, {4, 3}, {5, 5}}, {0.5, 0.2, 0.1, 0.2, 0.3}]]

用不同的布局显示多个数据集：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartLayout -> l], {l, {"Grouped", "Stepped"}}]

绘制一行矩形图：

Wolfram Language code: RectangleChart[{IconizedObject[«data #1»], IconizedObject[«data #2»], IconizedObject[«data #3»]}, ImageSize -> Medium, ChartLayout -> "Row"]

绘制一列矩形图：

Wolfram Language code: RectangleChart[{IconizedObject[«data #1»], IconizedObject[«data #2»], IconizedObject[«data #3»]}, ImageSize -> Medium, ChartLayout -> "Column"]

多行或多列矩形图：

Wolfram Language code: RectangleChart[{IconizedObject[«data #1»], IconizedObject[«data #2»], IconizedObject[«data #3»], IconizedObject[«data #4»]}, ImageSize -> Medium, ChartLayout -> {"Row", 2}]

控制竖条的原点：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, BarOrigin -> o, PlotLabel -> o], {o, {Bottom, Left, Top, Right}}]

调整竖条和竖条组的间距：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], BarSpacing -> s, PlotLabel -> s, PlotStyle -> Opacity[0.8]], {s, {Automatic, {0, 1}, {-0.3, 1}}}]

表格数据  (3)

获取表格数据：

Wolfram Language code: tabdata = AggregateRows[Tabular[ResourceData["Sample Data: 1993 US Cars"]], {"AvgPrice" -> (Mean[#AvgPrice]&), "TotalCars" -> (Length[#AvgPrice]&), "AvgWeight" -> (Mean[#Weight]&), "AvgFuelTankCap" -> (Mean[#FuelTankCapacity]&)}, {"Type"}]

比较每组汽车的平均价格以及汽车的数量：

Wolfram Language code: RectangleChart[tabdata -> {"TotalCars", "AvgPrice"}, PlotLabels -> Normal[tabdata[All, "Type"]]]

绘制 TimeSeries 或 EventSeries 中所有分量的值：

Wolfram Language code: RectangleChart[TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 5, "Endpoints" -> TabularColumn[Association[ "Data" -> {2, {{NumericArray[{20563, -2147483648}, "Integer32"], {}, DataStructure["BitVec ... {{TabularColumn[Association["Data" -> {{1, 1, 2, 5, 8}, {}, None}, "ElementType" -> "Integer64"]], TabularColumn[Association[ "Data" -> {{2, 2, 16, 17, 17}, {}, None}, "ElementType" -> "Integer64"]]}}]]]], Association[]]]

绘制 TimeSeries 或 EventSeries 中一组分量的值：

Wolfram Language code: ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 5, "Endpoints" -> TabularColumn[Association[ "Data" -> {2, {{NumericArray[{20563, -2147483648}, "Integer32"], {}, DataStructure["BitVec ... larColumn[Association[ "Data" -> {{2, 2, 16, 17, 17}, {}, None}, "ElementType" -> "Integer64"]], TabularColumn[Association["Data" -> {{5, 5, 4, 4, 2}, {}, None}, "ElementType" -> "Integer64"]]}}]]]], Association[]];
Wolfram Language code: RectangleChart[ts -> {"a", "b"}]

绘制多组分量的值：

Wolfram Language code: RectangleChart[ts -> {{"a", "b"}, {"a", "c"}}]

封装  (5)

对单个数据、数据集和一组数据集使用封装：

Wolfram Language code: {RectangleChart[{{{1, 1}, Style[{1, 2}, RGBColor[0.93, 0.27, 0.27]], {2, 3}}, {{1, 1}, {2, 1}}}], RectangleChart[{Style[{{1, 1}, {1, 2}, {2, 3}}, RGBColor[0.14, 0.8, 0.14]], {{1, 1}, {2, 1}}}], RectangleChart[Style[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, RGBColor[0.4, 0.6, 1]]]}

封装可以嵌套：

Wolfram Language code: {RectangleChart[{{{1, 1}, Style[{1, 2}, RGBColor[0.93, 0.27, 0.27]], {2, 3}}, {{1, 1}, {2, 1}}}], RectangleChart[{Style[{{1, 1}, Style[{1, 2}, RGBColor[0.93, 0.27, 0.27]], {2, 3}}, RGBColor[0.14, 0.8, 0.14]], {{1, 1}, {2, 1}}}], RectangleChart[Style[{Style[{{1, 1}, Style[{1, 2}, RGBColor[0.93, 0.27, 0.27]], {2, 3}}, RGBColor[0.14, 0.8, 0.14]], {{1, 1}, {2, 1}}}, RGBColor[0.4, 0.6, 1]]]}

覆盖默认的提示条：

Wolfram Language code: RectangleChart[{{1, 1}, Tooltip[{1, 2}, "median"], {2, 3}}]

在提示条中可使用任意对象：

Wolfram Language code: RectangleChart[Table[Tooltip[{CountryData[c, "Population"], CountryData[c, "GDPPerCapita"]}, CountryData[c, "Flag"]], {c, CountryData["G8"]}], BarSpacing -> 0]

用 PopupWindow 提供其它深层的信息：

Wolfram Language code: RectangleChart[{{1, 1}, PopupWindow[{1, 2}, DateListPlot[FinancialData["IBM", "Jan. 1, 2004"]]], {2, 3}}]

Button 可以用于触发任何操作：

Wolfram Language code: RectangleChart[{{1, 1}, Button[{1, 2}, Speak[2]], {2, 3}}]

样式和外观  (7)

对竖条用明确的样式列表：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

使用内置主题改变图表外观：

Wolfram Language code: {RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotTheme -> "Marketing"], RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotTheme -> "Detailed"]}

ChartBaseStyle 可以对所有图表元素设置一个初始样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotStyle -> <|"Base" -> EdgeForm[Dashed], "Elements" -> {RGBColor[0.797253, 0.904982, 0.410498], RGBColor[0.934691, 0.945708, 0.75346], RGBColor[0.769879, 0.92369, 0.977371]}|>]

Style 可以用于屏蔽样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, Style[{3, 4}, RGBColor[0.93, 0.27, 0.27]], {2, 3}}, PlotStyle -> GrayLevel[0.62]]

用任意图片作为竖条：

Wolfram Language code: {RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, ChartElements -> Graphics[Disk[]]], RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, ChartElements -> ExampleData[{"TestImage", "House"}]]}

用内置的程序产生竖条：

Wolfram Language code: ChartElementData["RectangleChart"]
Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}], {f, {"FadingRectangle", "GlassRectangle"}}]

用 面板 ▶ 图表元素方案 具体设置：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, ChartElementFunction -> ChartElementDataFunction["SegmentScaleRectangle", "Segments" -> 7, "ColorScheme" -> "SolarColors"]]

使用具有详细边框刻度和网格线的主题：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{2, 1}, {1, 2}}}, PlotTheme -> "Detailed"]

使用具有高对比度的方案和边缘褪色的矩形：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{2, 1}, {1, 2}}}, PlotTheme -> "Marketing"]

标签和图例  (13)

用 Labeled 对一个竖条增加标签：

Wolfram Language code: RectangleChart[{{1, 1}, Labeled[{1, 2}, "label"], {2, 3}}]

对标签替换用符号坐标：

Wolfram Language code: Table[RectangleChart[{{1, 1}, Labeled[{1, 2}, "label", p], {2, 3}}, PlotLabel -> p, Ticks -> None], {p, {Bottom, Center, Top}}]
Wolfram Language code: Table[RectangleChart[{{1, 1}, Labeled[{1, 2}, "label", p], {2, 3}}, BarOrigin -> Left, PlotLabel -> p, Ticks -> None], {p, {Left, Center, Right}}]

对于数据列提供分类坐标：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Elements" -> {"c1", "c2", "c3"}|>]

数据行：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Groups" -> {"r1", "r2"}|>]

两者都有：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Elements" -> {"c1", "c2", "c3"}, "Groups" -> {"r1", "r2"}|>]

用 Placed 控制标签坐标，用和 Labeled 的相同坐标：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Elements" -> Placed[{"c1", "c2", "c3"}, Center], "Groups" -> Placed[{"r1", "r2"}, Above]|>]

用 Callout 为直条添加标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, Callout[{2, 3}, "label"]}]

改变标注 (callout) 的外观：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, Callout[{2, 3}, "label", Appearance -> "Balloon"]}]

自动放置标注 (callout)：

Wolfram Language code: RectangleChart[Table[Callout[RandomReal[{1, 5}, 2], Unique["text"]], 5]]

用 LabelingFunction 对竖条提供值的标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> Above]

用 Placed 控制标签坐标和格式：

Wolfram Language code: labeler[v_, {i_, j_}, {ri_, cj_}] := Placed[Column[{v, ri[[1]], cj[[1]]}, ","], Center]
Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>, LabelingFunction -> labeler]

从数据中产生标注 (callout)：

Wolfram Language code: RectangleChart[{{1, 4}, {5, 5}, {1, 1}, {4, 1}, {2, 3}}, LabelingFunction -> (Callout[Style[Times@@#, 10 + 5Max[#]], Above]&)]

增加数据列的分组图例项：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3"}|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>]

数据行：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> {"rr1", "rr2"}, PlotStyle -> <|"Groups" -> "Pastel"|>]

用 Legended 增加其它图例项：

Wolfram Language code: RectangleChart[{{{1, 1}, Legended[{1, 2}, "extra"], {2, 3}}, {{1, 1}, {2, 1}}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>, PlotLegends -> <|"Elements" -> {"aaa", "bbb", "ccc"}|>]

用 Placed 影响图例坐标：

Wolfram Language code: Table[RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> <|"Elements" -> Placed[{"ccc1", "ccc2", "ccc3"}, p]|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>], {p, {Before, Below}}]

选项  (95)

AspectRatio  (4)

默认情况下，RectangleChart 使用固定的高宽比：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}]

用 AspectRatio1 使高度和宽度一致：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AspectRatio -> 1]

AspectRatioAutomatic 则根据数据确定高宽比：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AspectRatio -> Automatic]

AspectRatioFull 调整高度和宽度以适应其他构造：

Wolfram Language code: plot = RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AspectRatio -> Full];
Wolfram Language code: {Framed[Pane[plot, {50, 100}]], Framed[Pane[plot, {100, 100}]], Framed[Pane[plot, {100, 50}]]}

Axes  (3)

默认情况下，绘制坐标轴：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}]

用 AxesFalse 不显示坐标轴：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, Axes -> False]

显示一个坐标轴：

Wolfram Language code: {RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, Axes -> {False, True}], RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, Axes -> {True, False}]}

AxesStyle  (4)

改变坐标轴的样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AxesStyle -> RGBColor[0.93, 0.27, 0.27]]

指定每个坐标轴的样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AxesStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.4, 0.6, 1]}]

为刻度和坐标轴设置不同的样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AxesStyle -> RGBColor[0.14, 0.8, 0.14], TicksStyle -> RGBColor[0.4, 0.6, 1]]

为标签和坐标轴设置不同的样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 1}, {1, 4}, {2, 2}}, AxesStyle -> RGBColor[0.14, 0.8, 0.14], LabelStyle -> RGBColor[0.4, 0.6, 1]]

BarOrigin  (1)

改变竖条原点：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], BarOrigin -> o, PlotLabel -> o], {o, {Top, Bottom, Left, Right}}]

BarSpacing  (5)

自动确定竖条间的间距：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, BarSpacing -> Automatic]

无间距：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, BarSpacing -> None]

用符号预设值：

Wolfram Language code: Table[RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, BarSpacing -> s, PlotLabel -> s], {s, {Tiny, Small, Medium, Large}}]

在竖条间用明确的间距：

Wolfram Language code: Table[RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, BarSpacing -> s, PlotStyle -> Opacity[0.8], PlotLabel -> s], {s, {Automatic, 1, -0.3}}]

在竖条和竖条组之间用明确的间距：

Wolfram Language code: Table[RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, BarSpacing -> s, PlotLabel -> s], {s, {Automatic, {0, 1}, {0, 0.2}}}]

ChartElementFunction  (5)

获得 ChartElementFunction 的内置设置的列表：

Wolfram Language code: ChartElementData["RectangleChart"]

用 面板 ▶ 图表元素方案 处理详细的设置：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}, PlotLabel -> f], {f, {"Rectangle", "ObliqueRectangle"}}]
Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}, PlotLabel -> f], {f, {"FadingRectangle", "GlassRectangle"}}]

ChartElementFunction 适合显示全局比例：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElementFunction -> f, PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}, PlotLabel -> f], {f, {"GradientScaleRectangle", "SegmentScaleRectangle"}}]

写入一个定制的 ChartElementFunction：

Wolfram Language code: f[{{xmin_, xmax_}, {ymin_, ymax_}}, ___] := Rectangle[{xmin, ymin}, {xmax, ymax}]
Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElementFunction -> f]
Wolfram Language code: g[{{xmin_, xmax_}, {ymin_, ymax_}}, ___] := Polygon[{{xmin, ymin}, {xmax, ymax}, {xmin, ymax}, {xmax, ymin}}]
Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElementFunction -> g]

用输入传递的元数据，在此个例子中对数据绘图：

Wolfram Language code: DataDrilldownBar[{{xmin_, xmax_}, {ymin_, ymax_}}, y_, {data_List}] := PopupWindow[Polygon[{{xmin, ymin}, {xmax, ymax}, {xmin, ymax}, {xmax, ymin}}], PieChart[data]]
Wolfram Language code: DataDrilldownBar[{{xmin_, xmax_}, {ymin_, ymax_}}, y_, _] := Rectangle[{xmin, ymin}, {xmax, ymax}]
Wolfram Language code: RectangleChart[{{1, 1} -> Range[5], {1, 2}, {2, 1} -> RandomReal[1, 10]}, ChartElementFunction -> DataDrilldownBar]

ChartElements  (9)

基于 Graphics 对象的图片竖条：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> Graphics[Disk[]]]

Graphics3D：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> Graphics3D[Sphere[]]]

Image：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> ExampleData[{"TestImage", "House"}]]

用延伸的图片：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {[image], All}]

用明确的宽度和高度：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {Graphics[Disk[], AspectRatio -> Full], s}, PlotLabel -> s], {s, {{1 / 2, 1}, {1, 1 / 2}}}]

没有 AspectRatio->Full，不保存原比例：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {Graphics[Disk[]], s}, PlotLabel -> s], {s, {{1 / 2, 1}, {1, 1 / 2}}}]

高度或宽度用 All 导致竖条延伸到整个尺寸延伸：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {[image], s}, PlotLabel -> s], {s, {{1 / 2, All}, {All, 1 / 2}}}]

每个数据列用不同的图形：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, ChartElements -> {[image], [image], [image]}]

对每个数据行用不同的图形：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, ChartElements -> {{[image], [image]}, None}]

循环使用图形：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {{[image], All}, {[image], All}}]

样式可以继承 ChartStyle 等样式：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> [image], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}]

图形中明确的样式设置会屏蔽其它样式设置：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> [image], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}]

绘图图形的旋转总是从 BarOrigin 使用的设置开始：

Wolfram Language code: Table[RectangleChart[Tuples[{1, 2}, 2], ChartElements -> [image], BarOrigin -> o], {o, {Bottom, Top, Left, Right}}]

创建真实的三维阴影竖条：

Wolfram Language code: g = Graphics3D[{EdgeForm[], Specularity[White, 30], Cylinder[]}, ViewPoint -> {0, -Infinity, 0}, Boxed -> False, Lighting -> "Neutral", PlotRangePadding -> 0];
Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ChartElements -> {g, All}]

ColorFunction  (4)

按竖条高度着色：

Wolfram Language code: RectangleChart[Table[{Exp[-t ^ 2], Exp[-t ^ 2]}, {t, -2, 2, 0.25}], ColorFunction -> Function[{width, height}, ColorData["Rainbow"][height]]]

用 ColorFunctionScaling->False，得到未缩放的高度值：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ColorFunction -> (Switch[{#1, #2}, {1, 1}, RGBColor[1, 0.75, 0], {1, 2}, RGBColor[0.98, 0.56, 0.17], {2, 1}, RGBColor[0.93, 0.27, 0.27], _, RGBColor[0.4, 0.6, 1]]&), ColorFunctionScaling -> False]

按面积着色：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 1}, {2, 2}}, ColorFunction -> Function[{width, height}, ColorData["Rainbow"][width height / 4]], ColorFunctionScaling -> False]

ColorFunction 屏蔽 ChartStyle 的设置：

Wolfram Language code: ColorData["Pastel"] /@ Range[0, 1, 1 / 2]
Wolfram Language code: RectangleChart[Tuples[{1, 2, 3}, 2], PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.67, 0.54, 0.42]}, ColorFunction -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}]

用 ColorFunction 组合不同样式的效果：

Wolfram Language code: RectangleChart[Table[{Exp[-t ^ 2], Exp[-t ^ 2]}, {t, -2, 2, 0.25}], ColorFunction -> Function[{width, height}, Opacity[height]], PlotStyle -> RGBColor[0.8, 0.3, 0.8]]

ColorFunctionScaling  (2)

用 ColorFunctionScaling->False 得到未缩放的高度值：

Wolfram Language code: RectangleChart[Tuples[{1, 2}, 2], ColorFunction -> (Switch[{#1, #2}, {1, 1}, RGBColor[1, 0.75, 0], {1, 2}, RGBColor[0.98, 0.56, 0.17], {2, 1}, RGBColor[0.93, 0.27, 0.27], _, RGBColor[0.4, 0.6, 1]]&), ColorFunctionScaling -> False]

按面积着色：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 1}, {2, 2}}, ColorFunction -> Function[{width, height}, ColorData["Rainbow"][width height / 4]], ColorFunctionScaling -> False]

ImageSize  (7)

使用已命名的大小，如 Tiny、Small、Medium 和 Large：

Wolfram Language code: {RectangleChart[IconizedObject[«data»], ImageSize -> Tiny], RectangleChart[IconizedObject[«data»], ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code: {RectangleChart[IconizedObject[«data»], ImageSize -> 150], RectangleChart[IconizedObject[«data»], AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code: {RectangleChart[IconizedObject[«data»], ImageSize -> {Automatic, 150}], RectangleChart[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定大小：

Wolfram Language code: {RectangleChart[IconizedObject[«data»], ImageSize -> UpTo[200]], RectangleChart[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空格填充：

Wolfram Language code: RectangleChart[IconizedObject[«data»], ImageSize -> {200, 200}, Background -> GrayLevel[0.62]]

设置 AspectRatioFull 将会对可用空间进行填充：

Wolfram Language code: RectangleChart[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {200, 200}, Background -> GrayLevel[0.62]]

对宽度和高度使用最大尺寸：

Wolfram Language code: {RectangleChart[IconizedObject[«data»], ImageSize -> {UpTo[150], UpTo[100]}], RectangleChart[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

用 ImageSizeFull 对可用空间进行填充：

Wolfram Language code: Framed[Pane[RectangleChart[IconizedObject[«data»], ImageSize -> Full, Background -> GrayLevel[0.62]], {200, 100}]]

将图像大小指定为可用空间的一部分：

Wolfram Language code: Framed[Pane[RectangleChart[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> GrayLevel[0.62]], {200, 100}]]

LabelingFunction  (8)

在 Tooltip 和 StatusArea 中用值自动标注：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> Automatic]

无标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> None]

用 Placed 控制标签放置：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> (Placed[#, p]&), PlotLabel -> p, Ticks -> None], {p, {Bottom, Center, Top}}]

在竖条外的符号坐标：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> (Placed[#, p]&), PlotLabel -> p, Ticks -> None], {p, {Below, Above}}]
Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> (Placed[#, p]&), BarOrigin -> Left, PlotLabel -> p, Ticks -> None], {p, {Before, After}}]

基于放置的坐标与竖条相关：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> (Placed[#, p]&), BarSpacing -> 0.5, Ticks -> None, PlotLabel -> p], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

用 Callout 自动放置标签：

Wolfram Language code: RectangleChart[{{3, 5}, {8, 4}, {6, 7}}, LabelingFunction -> (Callout[Row[#, "⊗"], Automatic]&)]

用符号位置放置 Callout 标签：

Wolfram Language code: Table[RectangleChart[{{3, 5}, {8, 4}, {6, 7}}, LabelingFunction -> (Callout[#, p]&)], {p, {Above, Below}}]

控制标签的格式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, LabelingFunction -> (Placed[Row[#, "to"], Above]&)]

用给出的图表标签作为标签函数的参数：

Wolfram Language code: data = {{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}};
Wolfram Language code: RectangleChart[data, PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>, LabelingFunction -> (Placed[Column[{#3[[1, 1]], #3[[2, 1]], #1}, ","], Center]&), ImageSize -> Medium]

用完整的标签作为工具提示：

Wolfram Language code: RectangleChart[data, PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>, LabelingFunction -> (Placed[Row[{#3[[1, 1]], #3[[2, 1]], #1}, ","], Tooltip]&)]

LabelingSize  (4)

按实际尺寸显示的文本标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PlotLabels -> {"healthfulness", "obstreperous", "spectrogram", "pandemonium"}]

图像标签自动调整：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PlotLabels -> {[image], [image], [image], [image]}]

指定文本标签的最大尺寸：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PlotLabels -> {"healthfulness", "obstreperous", "spectrogram", "pandemonium"}, LabelingSize -> 50]

指定图像标签的最大尺寸：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PlotLabels -> {[image], [image], [image], [image]}, LabelingSize -> 25]

按自然大小显示图像标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PlotLabels -> Placed[{[image], [image], [image], [image]}, Above], LabelingSize -> Full, ImageSize -> Medium]

PerformanceGoal  (3)

产生具有交互式突出显示功能的条形图：

Wolfram Language code: RectangleChart[Tuples[{1, 2, 3}, 2], PerformanceGoal -> "Quality"]

禁用交互行为，专注性能的提升：

Wolfram Language code: RectangleChart[Tuples[{1, 2, 3}, 2], PerformanceGoal -> "Speed"]

通常非交互图表需要较少内存:

Wolfram Language code: Table[ByteCount@RectangleChart[Tuples[{1, 2, 3}, 2], PerformanceGoal -> p], {p, {"Quality", "Speed"}}]

PlotInteractivity  (4)

竖条数量适中时，会自动显示提示条和鼠标悬停效果：

Wolfram Language code: RectangleChart[{{1, 1}, {2, 2}, {2, 1}}]

关闭所有互动元素：

Wolfram Language code: RectangleChart[{{1, 1}, {2, 2}, {2, 1}}, PlotInteractivity -> False]

输入中提供的互动元素被禁用：

Wolfram Language code: RectangleChart[{{1, 1}, {2, 2}, Tooltip[{2, 1}, "Hello"]}, PlotInteractivity -> False]

允许使用提供的互动元素，但禁用自动生成的互动元素：

Wolfram Language code: RectangleChart[{{1, 1}, {2, 2}, Tooltip[{2, 1}, "Hello"]}, PlotInteractivity -> <|"User" -> True, "System" -> False|>]

PlotLabels  (9)

默认情况下，将标签放置于坐标轴上：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> {"a", "b", "c"}]
Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> {"a", "b"}]

默认情况下，标签会自动与数据元素或数据组相关联：

Wolfram Language code: {RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> {"c1", "c2", "c3"}], RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> {"r1", "r2", "r3"}]}

专门为数据元素指定标签：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Elements" -> {"c1", "c2", "c3"}|>]

同时标记数据组和元素：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>]

数据中的 Labeled 封装将会放置额外的标签：

Wolfram Language code: RectangleChart[{{1, 1}, Labeled[{1, 2}, "label", Center], {2, 3}}, PlotLabels -> {"a", "b", "c"}]

用 Placed 控制标签的放置：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"a", "b", "c"}, p], PlotLabel -> p, Ticks -> None], {p, {Bottom, Center, Top}}]

指定放置在直条以外的符号位置：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"a", "b", "c"}, p], PlotLabel -> p, Ticks -> None], {p, {Below, Above}}]
Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"a", "b", "c"}, p], BarOrigin -> Left, PlotLabel -> p, Ticks -> None], {p, {Before, After}}]

给出相对于直条的坐标：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"aa", "bb", "cc"}, p], BarSpacing -> 0.5, Ticks -> None, PlotLabel -> p], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

将所有标签放置于右上角，并改变标签内的坐标：

Wolfram Language code: Table[RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[Framed /@ {"aa", "bb", "cc"}, {{1, 1}, p}], BarSpacing -> 0.8, Ticks -> None, PlotLabel -> p], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]

用 Placed 的第三个参数控制格式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Rotate[#, 45Degree]&]]
Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Panel[#, FrameMargins -> 0]&]]

使用超链接标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Center, Hyperlink[#, "http://www.wolfram.com"]&]]

旋转标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc"}, Axis, Rotate[#, Pi / 4]&]]

改变数据组和元素的标签的位置：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> <|"Groups" -> Placed[{"r1", "r2"}, Above], "Elements" -> Placed[{"c1", "c2", "c3"}, Center]|>]

用 Callout 连接标签与直条：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Callout[{"c1", "c2", "c3"}]]

用 callout 标注一组直条：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLabels -> Callout[{"r1", "r2"}, Automatic]]

用 Placed 放置多个标签：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotLabels -> Placed[{{"a", "b", "c"}, {"x", "y", "z"}}, {Top, Bottom}]]

PlotLayout  (3)

PlotLayout 默认是分组的：

Wolfram Language code: data = {{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}};
Wolfram Language code: RectangleChart[data]

使用阶梯式布局：

Wolfram Language code: RectangleChart[data, PlotLayout -> "Stepped"]

单独绘制每组数据，共享刻度：

Wolfram Language code: RectangleChart[{{{1, 6}, {1, 4}, {2, 7}, {1, 6}, {2, 8}}, {{1, 4}, {2, 3}, {2, 10}, {1, 6}, {2, 4}}, {{1, 8}, {1, 3}, {2, 8}, {2, 7}, {2, 6}}}, ImageSize -> Medium, PlotLayout -> Column]

排成一行，而不是一列：

Wolfram Language code: RectangleChart[{{{1, 6}, {1, 4}, {2, 7}, {1, 6}, {2, 8}}, {{1, 4}, {2, 3}, {2, 10}, {1, 6}, {2, 4}}, {{1, 8}, {1, 3}, {2, 8}, {2, 7}, {2, 6}}}, ImageSize -> Medium, PlotLayout -> "Row"]

排成多个行或列：

Wolfram Language code: RectangleChart[{IconizedObject[«data #1»], IconizedObject[«data #2»], IconizedObject[«data #3»], IconizedObject[«data #4»], IconizedObject[«data #5»], IconizedObject[«data #6»]}, ImageSize -> Medium, PlotLayout -> {"Column", 4}]

尽量排列成完整的行或列：

Wolfram Language code: RectangleChart[{IconizedObject[«data #1»], IconizedObject[«data #2»], IconizedObject[«data #3»], IconizedObject[«data #4»], IconizedObject[«data #5»], IconizedObject[«data #6»]}, ImageSize -> Medium, PlotLayout -> {"Column", UpTo[4]}]

PlotLegends  (7)

为数据元素添加分类图例：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3"}|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>]

为数据组添加图例：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> <|"Groups" -> {"rr1", "rr2"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]

用 Legended 添加其他图例：

Wolfram Language code: RectangleChart[{{{1, 1}, Legended[Style[{1, 2}, RGBColor[0.93, 0.27, 0.27]], "aa"], {2, 3}}, {{1, 1}, {2, 1}}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3"}|>]

用 Legended 指定几个图例：

Wolfram Language code: RectangleChart[{{1, 1}, Legended[{1, 2}, "aa"], {2, 3}, Legended[{1, 1}, "bb"], {2, 1}, {2, 3}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.8750956, 0.6580038, 0.746929], RGBColor[0.9440982, 0.7955892, 0.5942686], RGBColor[0.9537862, 0.937389, 0.6180996], RGBColor[0.7952328000000001, 0.8988539999999999, 0.8302508], RGBColor[0.431296, 0.709773, 0.927077]}|>]

为数据组生成图例：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> <|"Groups" -> {"Group A", "Group B"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]

未使用的图例标签会被丢弃：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}}}, PlotLegends -> <|"Groups" -> {"Group A", "Group B", "Group C"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]

指定数据组和元素的图例：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotLegends -> <|"Groups" -> {"Test A", "Test B"}, "Elements" -> {"John", "Mary", "Bob"}|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}, "Groups" -> {EdgeForm[{Thick, RGBColor[0.93, 0.27, 0.27]}], EdgeForm[{Thick, RGBColor[0.4, 0.6, 1]}]}|>]

用 Placed 控制图例的放置：

Wolfram Language code: Table[RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotLegends -> <|"Elements" -> Placed[{"John", "Mary", "Bob"}, pos]|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>], {pos, {Below, Above, Before, After}}]

PlotStyle  (10)

给出一组样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1], RGBColor[1, 0.75, 0]}]

指定统一的样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, BarSpacing -> -0.3, PlotStyle -> Directive[Opacity[0.7], EdgeForm[Dashed], RGBColor[0.3655821205642109, 0.582006632236133, 0.0357851567943297]]]

指定数据组的颜色：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.4, 0.6, 1]}]

循环使用样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14]}|>]

为每个数据元素指定样式：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}|>]

为每个数据组指定样式：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotStyle -> <|"Groups" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14]}|>]

指定基础样式：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotStyle -> <|"Base" -> {EdgeForm[Dashed], Opacity[0.7]}|>]

设计数据元素和数据组的样式：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotStyle -> <|"Groups" -> {EdgeForm[Dotted], EdgeForm[Dashed]}, "Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}|>]

当同时为元素和数据组指定样式时，元素的样式可能会覆盖组的样式：

Wolfram Language code: RectangleChart[{{{1, 1}, {1, 2}, {2, 3}}, {{1, 1}, {2, 1}, {3, 2}}}, PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}, "Groups" -> {RGBColor[1, 0.75, 0], RGBColor[0.95, 0.43, 0.96]}|>]

PlotStyle 与 Style 一起使用：

Wolfram Language code: RectangleChart[{{1, 1}, Style[{1, 2}, Opacity[0.4]], {2, 3}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]
Wolfram Language code: RectangleChart[{{1, 1}, Style[{1, 2}, EdgeForm[Dashed]], {2, 3}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

Style 可能会覆盖 PlotStyle 的设置：

Wolfram Language code: RectangleChart[{{1, 1}, Style[{1, 2}, RGBColor[1, 0.75, 0]], {2, 3}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

可组合使用 ColorFunction 的 PlotStyle 的样式：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotStyle -> EdgeForm /@ {Dashed, Dotted, DotDashed}, ColorFunction -> (Blend[{RGBColor[0.4, 0.6, 1], RGBColor[0.93, 0.27, 0.27]}, #]&)]

ColorFunction 可能会覆盖 PlotStyle 的设置：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}, ColorFunction -> ColorData["SolarColors"]]

ChartElements 可能会覆盖 PlotStyle 的设置：

Wolfram Language code: RectangleChart[{{1, 1}, {1, 2}, {2, 3}}, ChartElements -> [image], PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}]

PlotTheme  (1)

选用带有详细刻度和网格线的主题：

Wolfram Language code: RectangleChart[{{5, 1}, {3, 3}, {2, 4}}, PlotTheme -> "Detailed"]

不显示网格线：

Wolfram Language code: RectangleChart[{{5, 1}, {3, 3}, {2, 4}}, PlotTheme -> "Detailed", GridLines -> None]

TargetUnits  (2)

自动检测单位：

Wolfram Language code: RectangleChart[{{Quantity[3, "Seconds"], Quantity[2, "Meters"]}, {Quantity[8, "Seconds"], Quantity[5, "Meters"]}, {Quantity[2, "Seconds"], Quantity[3, "Meters"]}, {Quantity[1, "Seconds"], Quantity[3, "Meters"]}, {Quantity[8, "Seconds"], Quantity[7, "Meters"]}, {Quantity[7, "Seconds"], Quantity[1, "Meters"]}}, AxesLabel -> Automatic, BarSpacing -> None, Ticks -> True]

指定在各个方向上显示的单位：

Wolfram Language code: RectangleChart[{{Quantity[3, "Seconds"], Quantity[2, "Meters"]}, {Quantity[8, "Seconds"], Quantity[5, "Meters"]}, {Quantity[2, "Seconds"], Quantity[3, "Meters"]}, {Quantity[1, "Seconds"], Quantity[3, "Meters"]}, {Quantity[8, "Seconds"], Quantity[7, "Meters"]}, {Quantity[7, "Seconds"], Quantity[1, "Meters"]}}, AxesLabel -> Automatic, BarSpacing -> None, Ticks -> True, TargetUnits -> {"Minutes", "Feet"}]

应用  (12)

鼠标指向滑尺，查看 在 [0,π] 区间内左边黎曼和如何近似于：

Wolfram Language code: Manipulate[Show[RectangleChart[{Pi / n, #}& /@ Sin[Range[0, Pi - Pi / n, Pi / n]], BarSpacing -> 0, PlotLabel -> NumberForm[Pi / n * Total[N@Sin@Range[0, Pi - Pi / n, Pi / n]], 4]], Plot[Sin[x], {x, 0, Pi}]], {n, 5, 100}]

创建一个重叠比例面积图表：

Wolfram Language code: data = {35, 28, 10};
Wolfram Language code: RectangleChart[Table[ConstantArray[Sqrt[d], 2], {d, data}], BarSpacing -> {0, 0}, ChartLayout -> "Overlapped", PlotLabels -> Placed[data, {0.94, 0.92}]]

创建一个地壳元素的原子量和丰度的矩形图：

Wolfram Language code: data = Cases[Table[Tooltip[QuantityMagnitude@{ElementData[e, "CrustAbundance"], ElementData[e, "AtomicWeight"]}, e], {e, ElementData[]}], Tooltip[{c_ ? NumericQ, a_ ? NumericQ}, _] /; c > 0.01 && a > 0.01];

把鼠标移到图表中得到元素的名称：

Wolfram Language code: RectangleChart[data, BarSpacing -> {0, 0}, ColorFunction -> Function[{x, y}, ColorData["SandyTerrain"][x]]]

比较销售和利润：

Wolfram Language code: totalSales = {38, 24, 20, 18}; profitability = {13, 23, 7, 11}; data = Transpose[{totalSales, profitability}]; options = {BarOrigin -> Left, BarSpacing -> {0, 0}, PlotLabels -> Placed[{"Product A", "Product B", "Product C", "Product D"}, Center], AxesLabel -> {"Profitability (%)", "Total Sales (%)"}};
Wolfram Language code: RectangleChart[data, options]

在 轴上标记确切的值：

Wolfram Language code: labeler[{x_, y_}, ___] := Placed[Row[{y, "%"}], Before]
Wolfram Language code: RectangleChart[data, options, LabelingFunction -> labeler, Ticks -> {Automatic, None}]

     点击条形图听取国家名称、人均 GDP 和人口数：

Wolfram Language code: countries = {"Sweden", "Luxembourg", "Estonia", "Portugal", "Bulgaria", "Slovenia", "Austria"}; properties = {"Population", "GDPPerCapita"};
Wolfram Language code: data = Table[With[{v = cp}, Button[v[[2 ;; 3]], Speak[StringJoin[ToString /@ {v[[1]], ", Population: ", Round[v[[2]]], ", GDP per capita: $", Round[v[[3]]]}]]]], {cp, Table[Prepend[Table[CountryData[c, p], {p, properties}], c], {c, countries}]}];
Wolfram Language code: RectangleChart[data, AxesLabel -> properties, PlotLabels -> Placed[countries, Tooltip], BarSpacing -> {0, 0.01}]

创建一个工程项目雇用的人员平均每小时工资的矩形图：

Wolfram Language code: data = | | | | | -- | -- | --------------------------------------- | | 13 | 40 | "goods" | | 3 | 42 | "sanitation and health" | | 34 | 46 | "highways, roads, and streets" | | 5 | 47 | "conservation" | | 4 | 48 | "miscellaneous" | | 9 | 51 | "sewer systems and other utilities" | | 2 | 52 | "airports and other transportation" | | 9 | 57 | "parks and other recreation facilities" | | 9 | 65 | "public buildings" | | 12 | 68 | "white collar" |; avgEarnings = Mean[data[[All, 2]]]; avgLine = {Dashed, Text["Average for All Types", {25, avgEarnings}, {0, -1}], Line[{{0, avgEarnings}, {100, avgEarnings}}]};
Wolfram Language code: RectangleChart[data[[All, 1 ;; 2]], ChartLabels -> Placed[data[[All, 3]], Center, Rotate[#, Pi / 2]&], BarSpacing -> {0, 0}, Frame -> True, Epilog -> avgLine, FrameLabel -> {Column[{"Percent of Total Hours on Which Payment Was Based", "100% = 1,976,000,000 Hours"}, Alignment -> Center], "Average Earnings in Dollars per Hour"}]

制作有保险覆盖的劳动人口比例的图表：

Wolfram Language code: inputData = | | | | | ---- | ---- | ------------------------------------------ | | 5.8 | 95.8 | "Extraction of Minerals and Forestry" | | 28.4 | 90.3 | "Manufacturing and Mechanical Industries" | | 15.4 | 62.7 | "Trade" | | 5.7 | 62.7 | "Unspecified Industries and Services" | | 9.1 | 48.4 | "Transportation and Communication" | | 9.8 | 32.6 | "Domestic and Personal Service" | | 7.0 | 32.4 | "Professional Service" | | 22.8 | 3 | "Agriculture, Fishing, and Public Service" |;
Wolfram Language code: data = Table[Insert[d, 100 - d[[2]], 3], {d, inputData}];
Wolfram Language code: Clear@labeler labeler[{x_, y_}, {r_, 1}, ___] := Placed[{x, y}, {Before, Center}] labeler[{x_, y_}, {r_, c_}, ___] := Placed[y, Center]
Wolfram Language code: RectangleChart[Partition[#, 2]& /@ data[[All, {1, 2, 1, 3}]], PlotLabels -> Placed[data[[All, 3]], Tooltip], PlotStyle -> <|"Elements" -> {GrayLevel[0.62], RGBColor[0.98, 0.56, 0.17]}|>, LabelingFunction -> labeler, BarOrigin -> Left, ChartLayout -> "Stacked", BarSpacing -> {0, 0.01}, AxesLabel -> {None, "% of Total Working Force"}, PlotLegends -> <|"Elements" -> Placed[{"% Covered", "% Not Covered"}, Below]|>]

可视化单位售出量和他们在哪里出售：

Wolfram Language code: domesticSales = {58, 22, 10, 35}; exportSales = {12, 59, 50, 27}; intercompanySales = {30, 19, 40, 48}; units = {98, 27, 48, 77}; products = {"Product A", "Product B", "Product C", "Product D"}; data = Table[Labeled[{{units[[i]], domesticSales[[i]]}, {units[[i]], exportSales[[i]]}, {units[[i]], intercompanySales[[i]]}}, products[[i]], After], {i, Length[units]}];
Wolfram Language code: RectangleChart[data, BarOrigin -> Left, BarSpacing -> None, ChartLayout -> "Percentile", AxesLabel -> {"Percent", "Units"}, PlotLegends -> <|"Elements" -> Placed[{"Domestic sales", "Export sales", "Intercompany sales"}, Above]|>]

在欧洲国家列表中，比较人均 GDP：

Wolfram Language code: countries = {"Luxembourg", "Estonia", "Sweden", "Portugal", "Bulgaria", "Slovenia", "Austria"}; properties = {"GDPPerCapita", "Population"}; data = Table[CountryData[c, p], {c, countries}, {p, properties}];
Wolfram Language code: tooltipLabel[v_, {r_, c_}, ___] := Placed[Grid[{{countries[[c]]}, {"GDPPerCapita", v[[1]]}, {"Population", v[[2]]}}, Alignment -> Left], Tooltip]

鼠标指向矩形时，得到每个国家的总合：

Wolfram Language code: RectangleChart[data, LabelingFunction -> tooltipLabel, PlotStyle -> {RGBColor[0.70135, 0.093019, 0.00140383], RGBColor[0.289647, 0.222614, 0.484169], RGBColor[0.98677, 0.98793, 0.458686], RGBColor[0.42948, 0.524086, 0.719463], RGBColor[0.30808, 0.443137, 0.124895], RGBColor[0.895125, 0.71606, 0.0964523], RGBColor[0.138415, 0.184848, 0.429862]}, AxesLabel -> properties, PlotLegends -> Placed[countries, Below], ImageSize -> 400]

鼠标指向矩形时，得到每个国家的总和：

Wolfram Language code: countries = {"Canada", "France", "Italy", "Germany", "Japan", "Russia", "UnitedKingdom"}; gdp = CountryData[#, {"GDP", 2006}]& /@ countries; gdpPerCapita = CountryData[#, {"GDPPerCapita", 2006}]& /@ countries; population = CountryData[#, {"Population", 2006}]& /@ countries; data = Transpose[{gdp, population}]; legends = gdpPerCapita;
Wolfram Language code: RectangleChart[data, LabelingFunction -> (Placed[#, Tooltip, Style[Column[{Row[{"GDP (x-axis) : $", First@#}], Row[{"Population (y-axis) : ", Last@#}], Row[{"GDP Per Capita : $", First@# / Last@#}]}, Alignment -> {Left, Bottom}, Frame -> True], 14, FontFamily -> "Helvitica"]&]&), PlotStyle -> {RGBColor[0.8588235294117647, 0.00784313725490196, 0.00784313725490196], RGBColor[1., 0.26666666666666666, 0.], RGBColor[1., 0.4549019607843137, 0.2549019607843137], RGBColor[0.4823529411764706, 0.18823529411764706, 0.03529411764705882], RGBColor[1., 0.8784313725490196, 0.5058823529411764], RGBColor[0.7019607843137254, 0.7450980392156863, 0.8235294117647058], RGBColor[0.5, 0.5, 0.5]}, PlotLabels -> Placed[countries, Below, Rotate[Style[#, 12, FontFamily -> "Helvitica", StandardBrown], Pi / 2]&], PlotLabel -> Style["Visualizing GDP per Capita", 14, Bold, FontFamily -> "Helvitica", StandardBrown], PlotRange -> All, PlotLegends -> Placed[SwatchLegend[legends, LegendLayout -> "Column"], After]]

比较前期收益和 PE 比例：

Wolfram Language code: companies = {"AAPL", "MSFT", "GOOG", "INTC", "CSCO", "JPM", "BAC", "GS", "WFC", "MCD", "PEP", "GIS", "MRK", "PFE", "GSK", "XOM", "PSX", "OXY", "SLB"}; properties = {"EarningsPerShare", "PERatio"}; data = Table[FinancialData[c, p], {c, companies}, {p, properties}];

定义一个标签函数，将公司信息放在工具提示中：

Wolfram Language code: tooltipLabel[v_, {r_, c_}, ___] := Placed[Grid[{{FinancialData[companies[[c]], "Name"]}, {"Earnings", v[[1]]}, {"PE Ratio", v[[2]]}}, Alignment -> Left], Tooltip]

鼠标指向竖条，得到公司信息：

Wolfram Language code: RectangleChart[data, BarSpacing -> {0, 0}, LabelingFunction -> tooltipLabel, ColorFunction -> Function[{x, y}, ColorData["Rainbow"][y]], AxesLabel -> properties, ImageSize -> 500]

产生条形码：

Wolfram Language code: digitToBarWidths[0] = {3, 2, 1, 1}; digitToBarWidths[1] = {2, 2, 2, 1}; digitToBarWidths[2] = {2, 1, 2, 2}; digitToBarWidths[3] = {1, 4, 1, 1}; digitToBarWidths[4] = {1, 1, 3, 2}; digitToBarWidths[5] = {1, 2, 3, 1}; digitToBarWidths[6] = {1, 1, 1, 4}; digitToBarWidths[7] = {1, 3, 1, 2}; digitToBarWidths[8] = {1, 2, 1, 3}; digitToBarWidths[9] = {3, 1, 1, 2}; digitToBarWidths["Invert"] = {1, 1, 1, 1, 1}; digitToBarWidths["Start"] = {1, 1, 1}; digitToBarWidths["Stop"] = {1, 1, 1};
Wolfram Language code: barWidths[upc_List] := Module[{midpt = Floor[Length[upc] / 2]}, digitToBarWidths /@ Flatten[{"Start", Take[upc, midpt], "Invert", Drop[upc, midpt], "Stop"}]]
Wolfram Language code: makeBarCode[upc_String] := makeBarCode[ToExpression /@ Characters[upc]] makeBarCode[upc_List] := RectangleChart[Table[{w, 1}, {w, Flatten[barWidths[upc]]}], BarSpacing -> {0, 0}, PlotStyle -> <|"Base" -> EdgeForm[], "Elements" -> {Black, White}|>, Axes -> None, PlotLabel -> Row[upc]]
Wolfram Language code: makeBarCode["812686001109"]

属性和关系  (4)

用 RectangleChart3D 得到一个三维形式的 RectangleChart:

Wolfram Language code: {RectangleChart[{{1, 1}, {1, 2}, {2, 3}}], RectangleChart3D[{{1, 1, 1}, {1, 1, 2}, {2, 1, 3}}]}

BarChart 是 RectangleChart 的一个特例：

Wolfram Language code: {BarChart[{1, 2, 3}], RectangleChart[{{1, 1}, {1, 2}, {1, 3}}]}

用 SectorChart 以扇形显示数据集：

Wolfram Language code: {RectangleChart[{{1, 1}, {1, 2}, {2, 3}}], SectorChart[{{1, 1}, {1, 2}, {2, 3}}]}

用 Histogram3D 自动计算装仓并绘制柱状图：

Wolfram Language code: Histogram3D[RandomReal[NormalDistribution[0, 1], {200, 2}]]

巧妙范例  (1)

图表：

Wolfram Language code: RectangleChart[RandomReal[1, {50, 50, 2}], ChartLayout -> "Stacked", Axes -> None, BarSpacing -> {0, 1}, PerformanceGoal -> "Speed"]
Wolfram Research (2008)，RectangleChart，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RectangleChart.html （更新于 2026 年）.

文本

Wolfram Research (2008)，RectangleChart，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RectangleChart.html （更新于 2026 年）.

CMS

Wolfram 语言. 2008. "RectangleChart." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/RectangleChart.html.

APA

Wolfram 语言. (2008). RectangleChart. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RectangleChart.html 年

BibTeX

@misc{reference.wolfram_2026_rectanglechart, author="Wolfram Research", title="{RectangleChart}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/RectangleChart.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_rectanglechart, organization={Wolfram Research}, title={RectangleChart}, year={2026}, url={https://reference.wolfram.com/language/ref/RectangleChart.html}, note=[Accessed: 02-November-2026]}