SectorChart3D[{{x1,y1,z1},{x2,y2,z2},…}]
扇形の角度が xi,半径が yi,高さが ziに比例する3D扇形グラフを作成する.
SectorChart3D[{…,wi[{xi,yi,zi},…],…,wj[{xj,yj,zj},…],…}]
扇形の特徴が記号的ラッパー wkで定義された3D扇形グラフを作成する.
SectorChart3D[{data1,data2,…}]
複数のデータ集合 dataiから3D扇形グラフを作成する.
SectorChart3D
SectorChart3D[{{x1,y1,z1},{x2,y2,z2},…}]
扇形の角度が xi,半径が yi,高さが ziに比例する3D扇形グラフを作成する.
SectorChart3D[{…,wi[{xi,yi,zi},…],…,wj[{xj,yj,zj},…],…}]
扇形の特徴が記号的ラッパー wkで定義された3D扇形グラフを作成する.
SectorChart3D[{data1,data2,…}]
複数のデータ集合 dataiから3D扇形グラフを作成する.
詳細とオプション
- SectorChart3Dのデータ要素は次の形式で与えることができる.
-
{xi,yi,zi} 純粋な扇形の角度,半径,高さ {Quantity[xi,ux],Quantity[yi,uy],Quantity[zi,uz]} 単位付きの扇形の確度,半径,高さ wi[{xi,yi,zi},…] 大きさが{xi,yi,zi}でラッパーが wiの扇形 formi->mi メタデータ miを持った扇形の形式 - これらの形式で与えられないデータは3D扇形グラフの作成時に無視される.
- SectorChart3Dのためのデータ集合は次の形式で与えることができる.
-
{e1,e2,…} ラッパーがある/ない要素のリスト <|k1e1,k2e2,…|> キーと長さの連想 TimeSeries[…],EventSeries[…],TemporalData[…] 時系列,事象系列,一時データ WeightedData[…] 重みのあるデータ集合 w[{e1,e2,…},…] データ集合全体に適用されたラッパー w[{data1,data1,…},…] すべてのデータ集合に適用されたラッパー - SectorChart3D[objcspec]は,列指定 cspec を用いて,Tabularオブジェクト,TimeSeriesオブジェクトまたはEventSeriesオブジェクト obj から値を抽出し,プロットする.
- 次は,表データのプロットに使用可能な列指定 cspec の形式である.
-
{colx,coly,colz} 列 x,y,z からのデータをプロットする {{colx1,coly1,colz1},{colx2,coly2,colz2},…} 列の複数の集合をプロットする - グラフの要素に次のラッパーを使用することができる.
-
Annotation[e,label] 注釈を与える Button[e,action] 要素がクリックされたときに実行するアクションを定義する EventHandler[e,…] 要素の一般的なイベントハンドラを定義する Hyperlink[e,uri] 要素がハイパーリンクとして機能するようにする Labeled[e,…] 要素にラベルを付けて表示する Legended[e,…] グラフの説明文に要素の特徴を含む Mouseover[e,over] 要素がマウスオーバーの形式を示すようにする PopupWindow[e,cont] 要素にポップアップウィンドウを加える StatusArea[e,label] 要素の上にマウスが来たときにステータスエリアに表示する Style[e,opts] 要素を指定したスタイルで示す Tooltip[e,label] 要素に任意のツールチップを加える - SectorChart3Dでは,LabeledとPlacedで次の位置が取れる.
-
"RadialOuter","RadialCenter","RadialInner" 扇形内の位置 "RadialOutside","RadialInside","RadialEdge" 扇形外の位置 "RadialCallout" コールアウトで示した位置 {{sθ,sr,sz},{lx,ly}} 扇形内のスケールされた位置{sθ,sr,sz}におけるラベル内のスケールされた位置{lx,ly} - SectorChart3DにはGraphics3Dと同じオプションに次の追加・変更を加えたものが使える. [全オプションのリスト]
-
Boxed False 境界ボックスを描画するかどうか BoxRatios {1,1,0.1} 境界3Dボックスの比 ChartElementFunction Automatic 扇形の生のグラフィックスをどのように生成するか ColorFunction Automatic 扇形の彩色方法 ColorFunctionScaling True ColorFunctionの引数を正規化するかどうか LabelingFunction Automatic 扇形にどのようにラベルを付けるか LegendAppearance Automatic 凡例の全体的な外観 Lighting "Neutral" 使用する擬似光源 PerformanceGoal $PerformanceGoal パフォーマンスのどの面について最適化するか PlotInteractivity $PlotInteractivity インタラクティブ要素を許可するかどうか PlotLabels None 扇形のカテゴリラベル PlotLayout Automatic 使用する全体的なレイアウト PlotLegends None データ要素とデータ集合の凡例 PlotRange Automatic 含める値の範囲 PlotStyle Automatic 扇形のスタイル PlotTheme $PlotTheme グラフの全体的なテーマ SectorOrigin Automatic 扇形の始点 SectorSpacing Automatic 扇形の間隔 TargetUnits Automatic グラフ内に表示する単位 ViewPoint {0,-2.4,2} 視点 - 複数のデータ集合は,PlotLayoutの次の設定を使って表示できる.
-

"Grouped" 各データ集合のデータを分離する 
"Stacked" 各データ集合のデータを積み重ねる - PlotLegendsの典型的な設定には,以下が含まれる.
-
None 凡例なし Automatic 凡例を自動的に決定する {lbl1,lbl2,…} lbl1,lbl2,…を凡例ラベルとして使用する Placed[lspec,…] 凡例の配置を指定する - PlotStylesty は,各曲線に使用するスタイルを指定する.可能な設定には次のものが含まれる.
-
{sty1,sty2,…} データに対するスタイルの列 <|"key"val,…|> データの異なるレベルに対するスタイル要素 - 使用可能なキーは次の通りである.
-
"Base" すべての棒に対する全体的なスタイル "Elements" 各グループ内の要素 yiに対するスタイルのリスト "Groups" 値 dataiの各グループのスタイルのリスト - ColorData["DefaultChartColors"]は,PlotStyleによって使用されるデフォルトの色の並びを与える.
- ChartElementFunctionに渡される引数は,ネストしたデータ集合リストにおける各レベルからの扇形の範囲{{θmin,θmax},{rmin,rmax},{zmin,zmax}},値{xi,yi,zi},メタデータ{m1,m2,…}である.
- ChartElementFunctionの組込み設定のリストはChartElementData["SectorChart3D"]から得られる.
- ColorFunctionに渡される引数は θ,r,z である.
- SectorChart3Dのオプションおよびその他の構造からのスタイルその他の指定は事実上PlotStyle,ColorFunction,Styleその他のラッパー,ChartElementFunctionの順に適用される.後ろの指定が前の指定を無効にする.
全オプションのリスト
例題
すべて開く すべて閉じる例 (3)
SectorChart3D[{{2, 2, 3}, {2, 1, 2}, {1, 2, 1}}]SectorChart3D[{{2, 2, 3}, {2, 1, 2}, {1, 2, 1}}, SectorOrigin -> {Automatic, 1}]SectorChart3D[{{{1, 1.5, 3}, {1, 1, 2}, {1, 1, 1}}, {{1, 1, 3}, {1, 1, 2}, {1, 1.5, 1}}}]スコープ (28)
データとレイアウト (12)
SectorChart3D[{{{1, 1, 3}, {1, 2, 2}, {1, 3, 2}}, {{2, 1, 3}, {2, 2, 3}, {2, 3, 2}}, {{3, 1, 3}, {3, 2, 3}, {3, 3, 1}}}]SectorChart3D[{{{1, 2, 2}, {2, 3, 3}}, {{1, 1, 3}, {2, 2, 3}, {3, 3, 1}}, {{1, 1, 3}, {2, 2, 3}, {3, 3, 2}, {4, 4, 1}}}]実数ではないデータは欠測値とみなされ,一般にグラフからは除かれる:
SectorChart3D[{{{1, 2, 2}, {2, 3, 3}}, {{1, 1, 3}, {Missing[], 2, 3}, {3, 3, 1}}, {{1, 1, 3}, {2, 2, 3}, {foo, 3, 2}, {4, 4, 1}}}]SectorChart3D[{{Quantity[1, "Seconds"], Quantity[3, "Seconds"], Quantity[5, "Meters"]}, {Quantity[1, "Seconds"], Quantity[7, "Seconds"], Quantity[3, "Meters"]}, {Quantity[2, "Seconds"], Quantity[4, "Seconds"], Quantity[5, "Meters"]}, {Quantity[3, "Seconds"], Quantity[4, "Seconds"], Quantity[7, "Meters"]}, {Quantity[5, "Seconds"], Quantity[4, "Seconds"], Quantity[3, "Meters"]}}]TimeSeries,EventSeries,TemporalData内のタイムスタンプは無視される:
SectorChart3D[TimeSeries[{{19, 16, 10}, {9, 3, 6}, {7, 6, 2}, {17, 12, 5}}, {"May 24, 1982"}]]SectorChart3D[<|"a" -> {1, 3, 1}, "b" -> {2, 4, 3}, "c" -> {5, 3, 5}, "d" -> {3, 5, 2}|>]SectorChart3D[<|"a" -> {1, 3, 1}, "b" -> {2, 4, 3}, "c" -> {5, 3, 5}, "d" -> {3, 5, 2}|>, PlotLabels -> Automatic]SectorChart3D[<|"a" -> {1, 3, 1}, "b" -> {2, 4, 3}, "c" -> {5, 3, 5}, "d" -> {3, 5, 2}|>, PlotStyle -> {Hue[0.61, 0.7, 1], Hue[0.17, 0.4, 0.65], Hue[0.64, 0.5, 0.75], Hue[0.45, 0.4, 0.7]}, PlotLegends -> Automatic]SectorChart3D[<|"group a" -> <|"a" -> {1, 3, 1}, "b" -> {2, 4, 3}, "c" -> {5, 3, 5}, "d" -> {3, 5, 2}|>, "group b" -> <|"a" -> {1, 3, 1}, "b" -> {2, 4, 3}, "c" -> {5, 3, 5}, "d" -> {3, 5, 2}|>|>, PlotLegends -> Automatic]WeightedData内の重みは無視される:
SectorChart3D[WeightedData[{{5, 4, 6}, {3, 3, 3}, {2, 3, 2}, {3, 3, 4}}, {0.5, 0.2, 0.1, 0.05}]]Table[SectorChart3D[RandomInteger[{1, 4}, {2, 10, 3}], ChartLayout -> l], {l, {"Grouped", "Stacked"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 1}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> o, PlotLabel -> o], {o, {{0, "Clockwise"}, {0, "Counterclockwise"}}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 1}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> o, PlotLabel -> o], {o, {0, Pi / 2}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 1}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> o, PlotLabel -> o], {o, {{{0, "Clockwise"}, 0}, {{0, "Clockwise"}, 1}}}]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};Table[SectorChart3D[data, SectorSpacing -> s, PlotLabel -> s, PlotStyle -> Opacity[0.8]], {s, {Automatic, {0, 1}, {0.1, 1}}}]表形式データ (3)
tabdata = AggregateRows[Tabular[ResourceData["Sample Data: 1993 US Cars"]], {"AvgPrice" -> (Mean[#AvgPrice]&), "TotalCars" -> (Length[#AvgPrice]&), "AvgWeight" -> (Mean[#Weight]&), "AvgFuelTankCap" -> (Mean[#FuelTankCapacity]&)}, {"Type"}]SectorChart3D[tabdata -> {"TotalCars", "AvgPrice", "AvgWeight"}, PlotLabels -> Normal[tabdata[All, "Type"]]]TimeSeriesまたはEventSeriesのすべての成分の値をプロットする:
SectorChart3D[TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 5,
"Endpoints" -> TabularColumn[Association[
"Data" -> {2, {{NumericArray[{20563, -2147483648}, "Integer32"], {},
DataStructure["BitVec ... ularColumn[Association[
"Data" -> {{17, 5, 7, 6, 13}, {}, None}, "ElementType" -> "Integer64"]],
TabularColumn[Association["Data" -> {{3, 2, 2, 1, 1}, {}, None},
"ElementType" -> "Integer64"]]}}]]]], Association[]]]TimeSeriesまたはEventSeriesの成分の集合の値をプロットする:
ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 5,
"Endpoints" -> TabularColumn[Association[
"Data" -> {2, {{NumericArray[{20563, -2147483648}, "Integer32"], {},
DataStructure["BitVec ... e" -> "Integer64"]], TabularColumn[Association[
"Data" -> {{3.5511999004449324, 1.777675777376151, 1.3490852490420469,
3.8396388450135266, 4.100051503528421}, {}, None}, "ElementType" -> "Real64"]]}}]]]],
Association[]];SectorChart3D[ts -> {"a", "b", "c"}]SectorChart3D[ts -> {{"a", "b", "c"}, {"d", "e", "f"}}]ラッパー (4)
個々のデータ,データ集合,あるいはデータ集合の集合にラッパーを使う:
{{d1, d2, d3, d4}, {w1, w2, w3, w4}} = {{{2, 1, 3}, {3, 4, 2}, {4, 2, 2}, {3, 4, 1}}, {{2, 2, 3}, {2, 3, 2}, {3, 2, 2}, {4, 3, 1}}};{SectorChart3D[{{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3, d4}, {w1, w2, w3, w4}}], SectorChart3D[{Style[{d1, d2, d3, d4}, RGBColor[0.14, 0.8, 0.14]], {w1, w2, w3, w4}}], SectorChart3D[Style[{{d1, d2, d3, d4}, {w1, w2, w3, w4}}, RGBColor[0.4, 0.6, 1]]]}{SectorChart3D[{{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3, d4}, {w1, w2, w3, w4}}], SectorChart3D[{Style[{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3, d4}, RGBColor[0.14, 0.8, 0.14]], {w1, w2, w3, w4}}], SectorChart3D[Style[{Style[{d1, Style[d2, RGBColor[0.93, 0.27, 0.27]], d3, d4}, RGBColor[0.14, 0.8, 0.14]], {w1, w2, w3, w4}}, RGBColor[0.4, 0.6, 1]]]}SectorChart3D[{{1, 3, 2}, {2, 1, 3}, Tooltip[{3, 3, 1}, "median"], {4, 2, 1}}]SectorChart3D[Table[Tooltip[{CountryData[c, "Population"], CountryData[c, "LifeExpectancy"], 1}, CountryData[c, "Flag"]], {c, CountryData["G8"]}]]PopupWindowを使って追加的なドリルダウン情報を与える:
SectorChart3D[{{1, 3, 2}, {2, 1, 3}, PopupWindow[{3, 3, 2}, DateListPlot[FinancialData["IBM", "Jan. 1, 2004"]]], {4, 2, 1}}]Buttonを使って任意のアクションを開始することができる:
SectorChart3D[{{1, 3, 2}, {2, 1, 3}, Button[{3, 3, 2}, Speak[3]], {4, 2, 1}}]スタイルと外観 (6)
SectorChart3D[{{1, 3, 2}, {2, 1, 3}, {3, 3, 2}, {4, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1], RGBColor[1, 0.75, 0]}]PlotStyleを使ってすべてのグラフ要素の初期スタイルを設定することができる:
SectorChart3D[{{1, 3, 2}, {2, 1, 3}, {3, 3, 2}, {4, 2, 1}}, PlotStyle -> <|"Base" -> EdgeForm[{Thick, RGBColor[0.93, 0.27, 0.27]}], "Elements" -> 45|>]Styleを使ってスタイルを無効にすることができる:
SectorChart3D[{{1, 3, 2}, Style[{2, 1, 3}, RGBColor[0.93, 0.27, 0.27]], {3, 3, 2}, {4, 2, 1}}, PlotStyle -> {RGBColor[0.797253, 0.904982, 0.410498], RGBColor[0.934691, 0.945708, 0.75346], RGBColor[0.769879, 0.92369, 0.977371], RGBColor[1, 0.566415, 0.0386511]}]ChartElementData["SectorChart3D"]Table[SectorChart3D[{{1, 3, 2}, {2, 1, 3}, {3, 3, 2}, {4, 2, 1}}, ChartElementFunction -> f, PlotStyle -> {RGBColor[0.823529, 0.788464, 0.657969], RGBColor[0.710414, 0.677302, 0.556176], RGBColor[0.687785, 0.640955, 0.477546], RGBColor[0.610864, 0.569268, 0.42414]}, SectorOrigin -> {Automatic, 1}], {f, {"CylindricalSector3D", "ProfileSector3D", "TorusSector3D"}}]詳細設定には「パレット」▶「チャートエレメントスキーム」を使う:
SectorChart3D[{{1, 3, 2}, {2, 1, 3}, {3, 3, 2}, {4, 2, 1}}, SectorOrigin -> {Automatic, 1}, ChartElementFunction -> ChartElementDataFunction["ProfileSector3D", "GradientDirection" -> "Angular"], PlotStyle -> {RGBColor[0.468742, 0., 0.0158236], RGBColor[0.871407, 0.20684366666666665, 0.013399966666666667], RGBColor[0.9899876666666667, 0.5566463333333334, 0.06420996666666667], RGBColor[1., 0.820127, 0.126955]}]SectorChart3D[{{1, 3, 2}, {2, 2, 1}, {3, 3, 4}, {4, 2, 3}}, PlotTheme -> "Marketing"]SectorChart3D[{{{6, 9, 12}, {8, 8, 3}, {8, 9, 7}, {3, 4, 5}, {7, 7, 10}}, {{4, 3, 12}, {3, 5, 7}, {3, 7, 4}, {4, 7, 12}, {9, 6, 5}}}, PlotTheme -> "Monochrome"]ラベルと凡例 (3)
Labeledを使って扇形にラベルを付ける:
SectorChart3D[{{1, 3, 2}, {2, 1, 3}, Labeled[{3, 3, 2}, "label"], {4, 2, 1}}]Table[SectorChart3D[{{1, 3, 2}, {2, 1, 3}, Labeled[{3, 3, 2}, "label", p], {4, 2, 1}}, PlotLabel -> p, SectorOrigin -> {Automatic, 1}], {p, {"RadialInner", "RadialCenter", "RadialOuter"}}]Table[SectorChart3D[{{1, 3, 2}, {2, 1, 3}, Labeled[{3, 3, 2}, "label", p], {4, 2, 1}}, PlotLabel -> p, SectorOrigin -> {Automatic, 1}], {p, {"RadialInside", "RadialOutside"}}]Table[SectorChart3D[{Labeled[{1, 3, 2}, "L1", p], Labeled[{2, 1, 3}, "L2", p], Labeled[{3, 3, 2}, "L3", p], Labeled[{4, 2, 1}, "L4", p]}, PlotLabel -> p], {p, {"RadialCallout", "VerticalCallout"}}]LabelingFunctionを使って扇形の値のラベルを与える:
SectorChart3D[{{2, 1, 2}, {2, 3, 3}, {3, 4, 2}, {4, 2, 1}}, LabelingFunction -> "RadialOutside"]オプション (74)
Axes (3)
デフォルトで,Axesは描かれない:
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True]{SectorChart3D[{{1, 1, 1}, {1, 2, 2}, {2, 3, 2}, {3, 2, 8}}, Axes -> {False, False, True}], SectorChart3D[{{1, 1, 1}, {1, 2, 2}, {2, 3, 2}, {3, 2, 8}}, Axes -> {False, True, False}], SectorChart3D[{{1, 1, 1}, {1, 2, 2}, {2, 3, 2}, {3, 2, 8}}, Axes -> {True, False, False}]}AxesLabel (3)
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True, AxesLabel -> z]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True, AxesLabel -> {x, y, z}]AxesOrigin (2)
AxesStyle (3)
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True, AxesStyle -> RGBColor[0.93, 0.27, 0.27]]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True, AxesStyle -> {{Thick, RGBColor[0.67, 0.54, 0.42]}, {Thick, RGBColor[0.4, 0.6, 1]}, {Thick, RGBColor[0.14, 0.8, 0.14]}}]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, Axes -> True, AxesStyle -> RGBColor[0.14, 0.8, 0.14], TicksStyle -> RGBColor[0.4, 0.6, 1]]ChartElementFunction (6)
ChartElementFunctionの組込み設定のリストを得る:
ChartElementData["SectorChart3D"]詳細設定には「パレット」▶「チャートエレメントスキーム」を使う:
Table[SectorChart3D[Tuples[{1, 2}, 3], ChartElementFunction -> f, SectorOrigin -> {{3Pi / 2, 1}, 1}, PlotStyle -> {RGBColor[0.773754, 0.420615, 0.187213], RGBColor[0.443442, 0.110262, 0.100633], RGBColor[0.877699, 0.728923, 0.228702], RGBColor[0.882353, 0.597772, 0.124285], RGBColor[0.266972, 0.112123, 0.117922], RGBColor[0.683253, 0.00616464, 0.0506752], RGBColor[1, 0.8, 0.4], RGBColor[0.70135, 0.246342, 0.10016]}, PlotLabel -> f], {f, {"CylindricalSector3D", "ProfileSector3D", "TorusSector3D"}}]ChartElementDataを使って上記と同じグラフ要素描画関数を指定する:
SectorChart3D[Tuples[{1, 2}, 3], ChartElementFunction -> Function[{angleRadiusMinMax, yr, meta}, ChartElementData["CylindricalSector3D"][angleRadiusMinMax, yr, meta]]]入力から渡されたメタデータ,この場合はデータのグラフ化を使う:
DataDrilldownSector[{{t0_, t1_}, {r0_, r1_}, {h0_, h1_}}, y_, {data_List}] :=
PopupWindow[ChartElementData["ProfileSector3D"][{{t0, t1}, {r0, r1}, {h0, h1}}, y], BarChart3D[data]]DataDrilldownSector[{{t0_, t1_}, {r0_, r1_}, {h0_, h1_}}, y_, _] :=
ChartElementData["CylindricalSector3D"][{{t0, t1}, {r0, r1}, {h0, h1}}, y]SectorChart3D[{{1, 1, 2} -> Range[5], {1, 2, 3}, {2, 1, 2} -> RandomReal[1, 10], {2, 2, 1}}, ChartElementFunction -> DataDrilldownSector]ChartElementFunctionのリストを与える:
SectorChart3D[Tuples[{1, 2}, 3], ChartElementFunction -> {"CylindricalSector3D", "ProfileSector3D", "TorusSector3D"}, PlotStyle -> {RGBColor[0.468742, 0., 0.0158236], RGBColor[0.6706774285714285, 0.06984285714285714, 0.009042057142857144], RGBColor[0.8432481428571429, 0.15849014285714286, 0.008003357142857142], RGBColor[0.9277247142857143, 0.30355071428571423, 0.024193185714285713], RGBColor[0.978545, 0.4534661428571428, 0.0459689], RGBColor[0.995709, 0.6082364285714286, 0.07333049999999999], RGBColor[1., 0.7211567142857143, 0.10022122857142858], RGBColor[1., 0.820127, 0.126955]} , SectorOrigin -> {Automatic, 1}]組込みの要素関数にはオプションがあることがある.「パレット」▶「チャートエレメントスキーム」を使ってオプションを設定する:
ChartElementData["ProfileSector3D", "Options"]Table[SectorChart3D[Tuples[{1, 2}, 3], SectorOrigin -> {Automatic, 1}, ChartElementFunction -> ChartElementDataFunction["ProfileSector3D", "Profile" -> p], PlotLabel -> p], {p, {0.1, 1, 3, 5}}]ColorFunction (4)
SectorChart3D[Table[{Exp[-t ^ 2], Exp[-t ^ 2], 1}, {t, -2, 2, 0.25}], ColorFunction -> Function[{angle, radius}, ColorData["Rainbow"][angle]]]ColorFunctionScaling->Falseを使ってスケールされていない角の値を得る:
SectorChart3D[Tuples[{1, 2}, 3], ColorFunction -> (Switch[{#1, #2}, {1, 1}, RGBColor[1, 0.75, 0], {1, 2}, RGBColor[0.98, 0.56, 0.17], {2, 1}, RGBColor[0.93, 0.27, 0.27], _, RGBColor[0.4, 0.6, 1]]&), ColorFunctionScaling -> False]ColorFunctionはChartStyleのスタイルを無効にする:
SectorChart3D[Tuples[{1, 2, 3}, 3], PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.67, 0.54, 0.42]}, ColorFunction -> "Pastel"]ColorFunctionを使って異なるスタイル効果を組み合せる:
SectorChart3D[Table[{Exp[-t ^ 2], Exp[-t ^ 2], 1}, {t, -2, 2, 0.25}], ColorFunction -> Function[{angle, radius}, Opacity[radius]], PlotStyle -> RGBColor[0.8, 0.3, 0.8]]ColorFunctionScaling (2)
ColorFunctionScaling->Falseを使ってスケールされていない高さの値を得る:
SectorChart3D[Tuples[{1, 2}, 3], ColorFunction -> (Switch[{#1, #2}, {1, 1}, RGBColor[1, 0.75, 0], {1, 2}, RGBColor[0.98, 0.56, 0.17], {2, 1}, RGBColor[0.93, 0.27, 0.27], _, RGBColor[0.4, 0.6, 1]]&), ColorFunctionScaling -> False]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ColorFunction -> Function[{angle, radius}, ColorData["Rainbow"][angle radius / 4]], ColorFunctionScaling -> False]ImageSize (7)
Tiny,Small,Medium,Largeのような名前付きのサイズを使う:
{SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> Tiny], SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> Small]}{SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> 150], SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, AspectRatio -> 1.5, ImageSize -> 150]}{SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> {Automatic, 150}], SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, AspectRatio -> 2, ImageSize -> {Automatic, 150}]}{SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> UpTo[200]], SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, AspectRatio -> 2, ImageSize -> UpTo[200]]}グラフィックスの幅と高さを指定して,必要な場合はスペースで充填する:
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> {200, 250}, Background -> LightBlue]AspectRatioFullと設定すると,使用可能なスペースが塗り潰される:
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, AspectRatio -> Full, ImageSize -> {200, 250}, Background -> LightBlue]{SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> {UpTo[150], UpTo[100]}], SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}ImageSizeFullを使ってオブジェクト内の使用可能なスペースを塗り潰す:
Framed[Pane[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, ImageSize -> Full, Background -> LightBlue], {200, 200}]]Framed[Pane[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> LightBlue], {200, 100}]]LabelingFunction (7)
TooltipとStatusAreaからの値で自動的なラベル付けを使う:
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, LabelingFunction -> Automatic]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, LabelingFunction -> None]Placedを使ってラベルの置き方を制御する:
Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, LabelingFunction -> (Placed[First@#, p]&), PlotLabel -> p, Ticks -> None], {p, {"RadialInner", "RadialCenter", "RadialOuter"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> {Automatic, 4}, LabelingFunction -> (Placed[Last@#, p]&), PlotLabel -> p], {p, {"RadialInside", "RadialOutside", "RadialEdge"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, LabelingFunction -> (Placed[#[[2]], p]&), PlotLabel -> p], {p, {"RadialCallout", "VerticalCallout"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, LabelingFunction -> (Placed[First@#, p]&), PlotLabel -> p, SectorOrigin -> {Automatic, 2}], {p, {{0, 0, 0}, {1 / 2, 1 / 2, 1 / 2}, {1, 1, 1}}}]すべてのラベルを最初の外周コーナーに置き,ラベル内の座標を変化させる:
Table[SectorChart3D[{{1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotLabels -> (Placed[Framed /@ {"aa", "bb", "cc"}, {{1, 1, 1}, p}]), PlotLabel -> p, SectorOrigin -> {Automatic, 2}], {p, {{0, 0}, {1 / 2, 1 / 2}, {1, 1}}}]SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, LabelingFunction -> (Placed[Row[{"$", #[[1]]}, " "], "RadialOutside"]&)]PerformanceGoal (3)
インタラクティブなハイライト機能を持つ扇形グラフを生成する:
SectorChart3D[Tuples[{1, 2, 3}, 3], PerformanceGoal -> "Quality"]インタラクティブな動作を使用不可にしてパフォーマンスを向上させる:
SectorChart3D[Tuples[{1, 2, 3}, 3], PerformanceGoal -> "Speed"]一般に,インタラクティブではないグラフの方がメモリが少なくて済む:
Table[ByteCount@SectorChart3D[Tuples[{1, 2, 3}, 3], PerformanceGoal -> p], {p, {"Quality", "Speed"}}]PlotInteractivity (4)
扇形の数がそれほど多くないグラフには,ツールチップとマウスオーバー効果が自動的に付けられる:
SectorChart3D[{{1, 1, 1}, {2, 1, 2}, {2, 2, 1}}]SectorChart3D[{{1, 1, 1}, {2, 1, 2}, {2, 2, 1}}, PlotInteractivity -> False]入力の一部として与えられたインタラクティブ要素を無効にする:
SectorChart3D[{{1, 1, 1}, {2, 1, 2}, Tooltip[{2, 2, 1}, "Hello"]}, PlotInteractivity -> False]与えたインタラクティブ要素を有効にして,自動のものは無効にする:
SectorChart3D[{{1, 1, 1}, {2, 1, 2}, Tooltip[{2, 2, 1}, "Hello"]}, PlotInteractivity -> <|"User" -> True, "System" -> False|>]PlotLabels (6)
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotLabels -> {"a", "b", "c", "d"}]SectorChart3D[{{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotLabels -> {"a", "b"}]データ内のLabeled ラッパーは,追加のラベルを配置する:
SectorChart3D[{{1, 1, 3}, Labeled[{1, 2, 2}, "label", "RadialOutside"], {2, 3, 2}, {3, 2, 1}}, PlotLabels -> {"a", "b", "c", "d"}]Placed を使ってラベルの配置を制御する:
Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotLabels -> Placed[{"a", "b", "c", "d"}, p], PlotLabel -> p], {p, {"RadialInner", "RadialCenter", "RadialOuter"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> {Automatic, 1}, PlotLabels -> Placed[{"a", "b", "c", "d"}, p], PlotLabel -> p, Ticks -> None], {p, {"RadialInside", "RadialOutside", "RadialEdge"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> {Automatic, 1}, PlotLabels -> Placed[{"a", "b", "c", "d"}, p], PlotLabel -> p, Ticks -> None], {p, {"RadialCallout", "VerticalCallout"}}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, SectorOrigin -> {Automatic, 1}, PlotLabels -> Placed[{"aa", "bb", "cc", "dd"}, p], PlotLabel -> p], {p, {{0, 0, 0}, {1 / 2, 1 / 2, 1}, {1, 1, 1}}}]Placed の第3引数を使ってフォーマットを制御する:
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotLabels -> Placed[{"aaa", "bbb", "ccc", "ddd"}, "RadialOutside", Style[#, RGBColor[0.93, 0.27, 0.27], 16, Bold]&]]SectorChart3D[{{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotLabels -> {"r1", "r2"}]SectorChart3D[{{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotLabels -> <|"Elements" -> {"c1", "c2", "c3"}|>]SectorChart3D[{{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotLabels -> <|"Groups" -> {"r1", "r2"}, "Elements" -> {"c1", "c2", "c3"}|>]Placed を用いて配置に影響を与える:
SectorChart3D[{{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotLabels -> <|"Groups" -> Placed[{"r1", "r2"}, "RadialOuter"], "Elements" -> Placed[{"c1", "c2", "c3"}, "RadialCenter"]|>]SectorChart3D[{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, PlotLabels -> Placed[{{"a", "b", "c"}, {"x", "y", "z"}}, {"RadialCenter", "RadialCallout"}]]PlotLayout (2)
PlotLayout は,デフォルトで,同心円状の輪にグループ化される:
data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};{SectorChart3D[data], SectorChart3D[data, PlotLayout -> "Grouped"]}data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotLayout -> "Stacked"]SectorChart3D[RandomReal[1, {10, 5, 3}], PlotLayout -> "Stacked"]PlotLegends (7)
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3", "ccc4"}|>, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.927848, 0.742785, 0.6151383333333333], RGBColor[0.929162, 0.95034, 0.6648153333333333], RGBColor[0.431296, 0.709773, 0.927077]}|>]SectorChart3D[{{{1, 2, 3}, {2, 2, 2}, {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotLegends -> <|"Groups" -> {"rr1", "rr2"}|>, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]Legendedを使って 追加の凡例項目を加える:
SectorChart3D[{{{1, 2, 3}, Legended[Style[{2, 2, 2}, RGBColor[0.93, 0.27, 0.27]], "aa"], {2, 1, 2}}, {{2, 2, 2}, {1, 2, 2}, {2, 3, 2}}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>, PlotLegends -> <|"Elements" -> {"ccc1", "ccc2", "ccc3"}|>]Legended を用いて,個々の凡例項目を指定する:
SectorChart3D[{{1, 1, 3}, Legended[{1, 2, 2}, "aa"], {2, 3, 2}, {3, 2, 1}}, PlotStyle -> <|"Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.8750956, 0.6580038, 0.746929], RGBColor[0.9440982, 0.7955892, 0.5942686], RGBColor[0.9537862, 0.937389, 0.6180996], RGBColor[0.7952328000000001, 0.8988539999999999, 0.8302508], RGBColor[0.431296, 0.709773, 0.927077]}|>]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotLegends -> {"Group A", "Group B"}, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotLegends -> {"Group A", "Group B", "Group C"}, PlotStyle -> <|"Groups" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}|>]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotLegends -> <|"Groups" -> {"Test A", "Test B"}, "Elements" -> {"John", "Mary", "Bob"}|>, PlotStyle -> <|"Groups" -> {EdgeForm[Directive[Opacity[1], RGBColor[0.93, 0.27, 0.27], Thickness[0.01]]], EdgeForm[Directive[Opacity[1], Dashed]]}, "Elements" -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.9584254999999999, 0.877884, 0.5906629999999999], RGBColor[0.431296, 0.709773, 0.927077]}|>]Placedを使って凡例の配置を制御する:
data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};Table[SectorChart3D[data, PlotLegends -> Placed[{"John", "Mary", "Bob"}, pos], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}], {pos, {Before, Below}}]Table[SectorChart3D[data, PlotLegends -> Placed[{"John", "Mary", "Bob"}, pos], PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}], {pos, {Before, After}}]PlotStyle (5)
扇形のスタイル指定には PlotStyle を用いる:
SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1], RGBColor[1, 0.75, 0]}]Table[SectorChart3D[{{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}, PlotStyle -> s], {s, {EdgeForm[{Opacity[1], Blue}], Opacity[0.7]}}]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.4, 0.6, 1]}]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotStyle -> <|"Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}|>]SectorChart3D[data, PlotStyle -> <|"Groups" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14]}|>]SectorChart3D[data, PlotStyle -> <|"Base" -> EdgeForm[{Thick, Dashed}], "Groups" -> {Opacity[0.3], Opacity[0.9]}, "Elements" -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}|>]SectorChart3D[{{1, 1, 2}, Style[{1, 2, 2}, Opacity[0.2]], {2, 3, 2}, {3, 2, 1}}, PlotStyle -> {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1], RGBColor[1, 0.75, 0]}]Style は,PlotStyle の設定を上書きすることがある:
SectorChart3D[{{1, 1, 2}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}, Style[{1, 2, 3}, EdgeForm[None]]}, PlotStyle -> EdgeForm[{Thick, Dashed, Opacity[0.8]}]]"Elements" または "Groups" は "Base" 設定を上書きする場合がある:
data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, PlotStyle -> <|"Base" -> EdgeForm[None], "Elements" -> EdgeForm[Dashed]|>]ColorFunction を用いて,異なるスタイル効果を組み合せる:
SectorChart3D[Tuples[{1, 2}, 3], PlotStyle -> EdgeForm /@ {Dashed, Dotted, DotDashed}, ColorFunction -> (Blend[{RGBColor[0.4, 0.6, 1], RGBColor[0.93, 0.27, 0.27]}, #]&)]SectorChart3D[RandomReal[{0.4, 1}, {3, 8, 3}], PlotStyle -> <|"Groups" -> "Rainbow"|>, ChartLayout -> "Grouped", ColorFunction -> Function[{height}, Opacity[height]]]SectorChart3D[RandomReal[{0.4, 1}, {3, 8, 3}], PlotStyle -> <|"Groups" -> "Rainbow"|>, ChartLayout -> "Grouped", ColorFunction -> Function[{x, y, z}, RGBColor[x, y, z]]]SectorChart3D[RandomReal[{0.4, 1}, {2, 8, 3}], ChartElementFunction -> "TorusSector3D", PlotStyle -> {RGBColor[0.761959, 0.470832, 0.940597], RGBColor[0.431296, 0.709773, 0.927077]}]PlotTheme (1)
SectorOrigin (4)
デフォルトで,扇形は左側から始まり,時計回りに加えられていく:
{SectorChart3D[{Labeled[{1, 3, 3}, "Begin"], {2, 2, 2}, {2, 3, 1}, {3, 2, 2}}], SectorChart3D[{Labeled[{1, 3, 3}, "Begin"], {2, 2, 2}, {2, 3, 1}, {3, 2, 2}}, SectorOrigin -> {{Pi, "Clockwise"}, 0}]}SectorChart3D[{Labeled[{1, 3, 3}, "Begin"], {2, 2, 2}, {2, 3, 1}, {3, 2, 2}}, SectorOrigin -> {{Pi, "Clockwise"}, 1}]SectorChart3D[{Labeled[{1, 3, 3}, "Begin"], {2, 2, 2}, {2, 3, 1}, {3, 2, 2}}, SectorOrigin -> {{Pi / 2, "Counterclockwise"}, 1}]SectorChart3D[{Labeled[{1, 3, 3}, "Begin"], {2, 2, 2}, {2, 3, 1}, {3, 2, 2}}, SectorOrigin -> {{Pi / 2, "Clockwise"}, 1}]SectorSpacing (5)
data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, SectorSpacing -> Automatic]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};SectorChart3D[data, SectorSpacing -> None]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};Table[SectorChart3D[data, SectorSpacing -> s, PlotLabel -> s], {s, {Tiny, Small, Medium, Large}}]data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};Table[SectorChart3D[data, SectorSpacing -> s, PlotLabel -> s], {s, {Automatic, 1, 3}}]扇形の間,および扇形のグループの間に明示的なスペースを使う:
data = {{{1, 1, 3}, {2, 2, 2}, {2, 3, 1}}, {{1, 1, 3}, {1, 2, 2}, {2, 3, 2}, {3, 2, 1}}};Table[SectorChart3D[data, SectorSpacing -> s, PlotLabel -> s], {s, {Automatic, {0.1, 1}, {0.05, 2}}}]アプリケーション (3)
countries = CountryData["Africa"];
properties = {"GDPPerCapita", "PovertyFraction", "Population"};data = Table[With[{v = cp}, Button[v[[2 ;; 4]], Speak[StringJoin[ToString /@ {v[[1]], ", GDP per capita: $", Round[v[[2]]], ", Poverty Fraction: ", v[[3]], ", Population: ", Round[v[[4]]]}]]]], {cp, Table[Prepend[Table[QuantityMagnitude@CountryData[c, p], {p, properties}], c], {c, countries}]}];SectorChart3D[data]data = {10, 30, 50, 40, 70};
sectorData = Table[| | |
| ----------------- | ------- |
| {data[[i]], 1, 3} | i === 3 |
| {data[[i]], 1, 1} | True |, {i, Length@data}]SectorChart3D[sectorData, PlotLabels -> data]countries = CountryData["Africa"];
properties = {"GDP", "PovertyFraction", "Population"};
data = Table[QuantityMagnitude@CountryData[c, p], {c, countries}, {p, properties}];labeler[v_, {r_, c_}, ___] := Placed[Grid[{{Style[countries[[c]], Bold], }, {"GDP", v[[1]]}, {"Poverty", v[[2]]}, {"Population", v[[3]]}}, Alignment -> Left], Tooltip]SectorChart3D[data, LabelingFunction -> labeler]特性と関係 (4)
SectorChart3DはPieChart3Dを一般化したものである:
{SectorChart3D[{{1, 1, 1}, {2, 1, 1}, {3, 1, 1}}], PieChart3D[{1, 2, 3}]}SectorChartを使って二次元の扇形を描画する:
SectorChart[{{2, 2}, {2, 1}, {1, 2}}]BubbleChartを使ってトリプレットをバブルとして描画する:
BubbleChart[RandomReal[1, {3, 10, 3}]]ListPointPlot3Dを使ってトリプレットを点として描画する:
ListPointPlot3D[RandomReal[1, {25, 3}], Filling -> Bottom]おもしろい例題 (1)
SectorChart3D[RandomReal[10, {2, 200, 3}], ColorFunction -> "DeepSeaColors", PerformanceGoal -> "Speed", Background -> GrayLevel[0.62], PlotStyle -> EdgeForm[None]]関連するガイド
履歴
2008 で導入 (7.0) | 2012 で更新 (9.0) ▪ 2014 (10.0) ▪ 2025 (14.2) ▪ 2025 (14.3) ▪ 2026 (15.0)
テキスト
Wolfram Research (2008), SectorChart3D, Wolfram言語関数, https://reference.wolfram.com/language/ref/SectorChart3D.html (2026年に更新).
CMS
Wolfram Language. 2008. "SectorChart3D." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/SectorChart3D.html.
APA
Wolfram Language. (2008). SectorChart3D. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SectorChart3D.html
BibTeX
@misc{reference.wolfram_2026_sectorchart3d, author="Wolfram Research", title="{SectorChart3D}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/SectorChart3D.html}", note=[Accessed: 17-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_sectorchart3d, organization={Wolfram Research}, title={SectorChart3D}, year={2026}, url={https://reference.wolfram.com/language/ref/SectorChart3D.html}, note=[Accessed: 17-November-2026]}