WOLFRAM

Wolfram 语言与系统参考资料中心

SystemModelUncertaintyPlot[sys,spec]

按照 spec 绘制系统模型 sys 中由于输入不确定性而导致的输出不确定性.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
模型  
规范  
值的不确定性  
输入的不确定性  
切片函数  
数据封装  
选项  
AxesLabel  
Filling  
FrameLabel  
Show More Show More
Method  
PlotLabel  
PlotLayout  
PlotLegends  
ProgressReporting  
SamplingPeriod  
ScalingFunctions  
TargetUnits  
应用  
平衡附近的轨迹  
系统容差  
受控系统的验证  
轨道调整  
供暖系统中的过冲  
机器人的控制设计  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

SystemModelUncertaintyPlot

SystemModelUncertaintyPlot[sys,spec]

按照 spec 绘制系统模型 sys 中由于输入不确定性而导致的输出不确定性.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

在给定的区间内，绘制电阻变化时 RC 电路中电容器电压的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"ParameterValues" -> {"R" -> Quantity[Interval[{2, 7}], "Milliohms"]}|>]

范围  (24)

模型  (4)

绘制 SystemModel 的两个变量的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x", "y"}, "ParameterValues" -> {"theta" -> Interval[{0, π}]}|>, PlotRange -> All]

绘制 AffineStateSpaceModel 输出的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[AffineStateSpaceModel[{{Cos[x2], -1/10*x2 - Cos[x1^2]}, {{0}, {1}}, {x2}, {{0}}}, {x1, x2}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], <|"InitialValues" -> {x1 -> Interval[{1, 2}]}, "SimulationInterval" -> 3|>]

绘制 NonlinearStateSpaceModel 输出的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[NonlinearStateSpaceModel[{{Cos[x] + 4*a*Sin[x/2]}, {x + Sin[x]}}, {x}, {}, {Automatic}, Automatic, SamplingPeriod -> None], <|"ParameterValues" -> {a -> Interval[{1, 10}]}|>]

绘制 DiscreteInputOutputModel 输出的不确定性：

Wolfram Language code: diom = DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[0] + y[-2] + a*y[-1]}, {u[-1] + u[0] + u[1]}}}, {{0, 1, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, {1}, {MissingDataMethod -> None, ResamplingMethod -> ... ime", "LastValue", "OutputCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StateCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}];

使用 SquareWave 输入：

Wolfram Language code: SystemModelUncertaintyPlot[diom, <|"ParameterValues" -> {a -> Interval[{0.1, 1}]}, "Inputs" -> {1 -> SquareWave}|>, PlotRange -> All]

规范  (4)

绘制特定输出的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, π}]}|>, PlotRange -> All]

使用自定义数量的模拟绘制模型中的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"SimulationCount" -> 5, "Outputs" -> {"x", "y"}, "ParameterValues" -> {"theta" -> Interval[{0, π}]}|>, PlotRange -> All]

使用自定义模拟区间绘制特定输出的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "SimulationInterval" -> {0, 3}, "ParameterValues" -> {"theta" -> Interval[{0, π}]}|>, PlotRange -> All]

在仿真设置中包含 "Epoch" 的模型，会在一系列日期上绘制其值：

Wolfram Language code: model = SystemModel[[image], <|"ModelName" -> "MyModel", "SimulationSettings" -> {"Epoch" -> Now, "StopTime" -> Quantity[3, "Hours"]}|>]

绘制模型：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> {"room.temperature.T"}, "ParameterValues" -> {"room.roomInertia.C" -> Range[70000, 90000, 5000]}|>]

值的不确定性  (5)

绘制由给定参数的值列表生成的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Range[0, 1 / 2, 1 / 200]}|>, PlotRange -> All]

绘制通过对参数值进行区间抽样生成的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All]

绘制通过对参数值进行分布抽样生成的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> NormalDistribution[2, 0.1]}|>, PlotRange -> All]

绘制通过对参数值进行几何区域抽样生成的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> MeshRegion[{{0}, {1}, {2}}, Line[{1, 2, 3}]]}|>, PlotRange -> All]

绘制通过对两个初始值进行 Circle 抽样生成的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x", "y"}, "InitialValues" -> {{"x", "y"} -> Circle[]}|>, PlotRange -> All]

输入的不确定性  (3)

绘制使用 ARIMAProcess 作为输入时生成的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"SimulationInterval" -> {0, 10}, "Outputs" -> {"syse.sys.rs"}, "Inputs" -> {"T" -> ARIMAProcess[{-.01}, 1, {.01}, 10^-6]}|>, PlotRange -> All, TargetUnits -> "Millimeters"]

绘制使用多个函数作为输入时产生的不确定性：

Wolfram Language code: inputs = Table[With[{k = k}, Function[t, 0.1(k Tanh[t] + 0.1k Sin[0.15t])]], {k, 1, 10}];
Wolfram Language code: Plot[Through[inputs[x]], {x, 0, 60}]

使用以下曲线作为连续搅拌反应釜的输入流速：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Inputs" -> {"deltaFJ" -> inputs}|>, PlotRange -> All]

绘制对两个输入使用二维过程时产生的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[\!\(\*GraphicsBox[«8»]\), <|"Outputs" -> {"w"}, "Inputs" -> {{"V", "TL"} -> MAProcess[{{{.2, .1}, {-.1, .2}}}, {{0.001, 0}, {0, 0.001}}]}|>, PlotRange -> All]

切片函数  (4)

绘制时间数据的最小值和最大值之间的范围：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}, "SliceFunction" -> "MinMax"|>, PlotRange -> All]

绘制时间数据的自定义分位数：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}, "SliceFunction" -> {"Quantiles", {0, 0.45, 0.5, 0.55, 1}}|>, PlotRange -> All]

绘制具有自定义置信水平的时间数据的自定义置信区间：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}, "SliceFunction" -> {"Confidence", {0.95, 0.98, 0.99}}|>, PlotRange -> All]

绘制自定义切片函数：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}, "SliceFunction" -> {Mean[#] - StandardDeviation[#]&, Mean, Mean[#] + StandardDeviation[#]&}|>, PlotRange -> All, PlotLegends -> {μ - σ, μ, μ + σ}]

数据封装  (4)

对一个变量使用封装：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> Style["x", StandardRed], "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>]

对 "Shared" PlotLayout 中的几个变量使用封装：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {Style["vx", StandardRed], Style["y", StandardOrange]}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotLayout -> "Shared"]

封装可以嵌套：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> Labeled[Style["x", StandardRed], "position", Below], "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>]

对 "Shared" PlotLayout 中的几个变量使用封装：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {Callout[Style["vx", StandardRed], "velocity", Above], Callout[Style["y", StandardOrange], "position", Below]}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotLayout -> "Shared"]

添加 Tooltip：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> Tooltip["x", "position"], "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>]

自定义一个变量的图例：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> Legended["x", "position"], "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>]

自定义 "Shared" PlotLayout 中几个变量的图例：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {Legended["vx", "velocity"], Legended["y", "position"]}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotLayout -> "Shared"]

选项  (17)

AxesLabel  (2)

在默认的 PlotLayout 中，AxesLabel 默认设置为 None：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, Frame -> False, Axes -> True]

设置自定义标签：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, AxesLabel -> {"time", "position"}, Frame -> False, Axes -> True]

Filling  (2)

已知的切片函数默认使用自定义 Filling：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All]

设置自定义填充：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, Filling -> {1 -> {5}}]

FrameLabel  (2)

默认情况下，绘制变量的单位被用作 FrameLabel：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All]

设置自定义标签：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, FrameLabel -> {"time", "position"}, PlotRange -> All]

Method  (1)

使用 Method 设置自定义的模拟方法：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, Method -> <|"SimulationMethod" -> {"InterpolationPoints" -> 10}|>, PlotRange -> All]

PlotLabel  (1)

设置自定义绘图标签：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x", "y"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, PlotLabel -> {"Position: x", "Position: y"}]

PlotLayout  (2)

获取与每个输出的单独图的 Association：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x", "vy"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, PlotLayout -> "Association"]

合并各个图：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x", "vy"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, PlotLayout -> "Shared"]

PlotLegends  (2)

已知的切片函数默认使用自定义的 PlotLegends：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}, "SliceFunction" -> {"Quantiles", {0, 0.45, 0.5, 0.55, 1}}|>, PlotRange -> All]

设置自定义绘图图例：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}, "SliceFunction" -> {"Quantiles", {0, 0.45, 0.5, 0.55, 1}}|>, PlotLegends -> {None, None, "Median", None, None}]

ProgressReporting  (1)

使用 ProgressReporting 控制进度报告：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, ProgressReporting -> False]

SamplingPeriod  (1)

在对随机过程进行抽样时，设置自定义的抽样周期：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"SimulationInterval" -> {0, 10}, "Outputs" -> {"syse.sys.rs"}, "Inputs" -> {"T" -> ARIMAProcess[{-.01}, 1, {.01}, 10^-6]}|>, PlotRange -> All, TargetUnits -> "mm", SamplingPeriod -> 5]

ScalingFunctions  (2)

用 ScalingFunctions 绘制对数刻度的模型：

Wolfram Language code: SystemModelUncertaintyPlot[AffineStateSpaceModel[{{x1, 2*x1}, {{}}}, {{x1, 1}, {x2, 1}}], <|"Outputs" -> {x1, x2}, "InitialValues" -> {x1 -> {1, 10, 100, 1000}}|>, ScalingFunctions -> "Log"]

在仿真设置中包含 "Epoch" 的模型将按日期序列上的值进行绘制：

Wolfram Language code: model = SystemModel[[image], <|"ModelName" -> "MyModel", "SimulationSettings" -> {"Epoch" -> Now}|>]

绘制模型：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> {"H"}, "ParameterValues" -> {"k" -> Range[100, 130, 5]}|>]

用 ScalingFunctions{None,Automatic} 生成仿真时间图：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> {"H"}, "ParameterValues" -> {"k" -> Range[100, 130, 5]}|>, ScalingFunctions -> {None, Automatic}, TargetUnits -> {"Years", Automatic}]

用 DateTicksFormat 格式化日期刻度标签：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> {"H"}, "ParameterValues" -> {"k" -> Range[100, 130, 5]}|>, ScalingFunctions -> {DateScale[DateTicksFormat -> "YearShort"], Automatic}]

TargetUnits  (1)

使用 TargetUnits 设置自定义单位：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> {"x"}, "ParameterValues" -> {"theta" -> Interval[{0, 2π}]}|>, PlotRange -> All, TargetUnits -> {"Seconds", "Decimeters"}]

应用  (6)

平衡附近的轨迹  (1)

绘制简单阻尼摆在初始条件接近平衡点时角度和角速度的不确定性：

Wolfram Language code: model = CreateSystemModel["DampedPendulum", {ω'[t] == -g Sin[θ[t]] / l - b ω[t], θ'[t] == ω[t]}, t, {θ∈"Units.SI.Angle"}, <|"ParameterValues" -> {g -> 10, l -> 1 / 2, b -> 2}|>]

当系统以小角度静止开始时，它会向稳定的地面位置演化：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"SimulationInterval" -> 5, "Outputs" -> θ, "InitialValues" -> {θ -> CenteredInterval[0, π / 4]}|>, ...]

当系统在接近不稳定的完全倒立位置启动时，它同样会向地面位置演化：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"SimulationInterval" -> 5, "Outputs" -> θ, "InitialValues" -> {θ -> Interval[{3π / 4, π - π / 100}]}|>, ...]

绘制几条随机选择的轨迹：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"SimulationInterval" -> 5, "Outputs" -> θ, "InitialValues" -> {θ -> Interval[{3π / 4, π - π / 100}]}, "SliceFunction" -> Table[With[{k = k}, Part[#, k]&], {k, RandomSample[Range[200], 20]}]|>, ...]

系统容差  (1)

电路性能在很大程度上取决于其组件和参数的容差. 当该扬声器模型中一个组件的电阻遵循截断正态分布时，通过扬声器的电流变化是可以测量的：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> "speaker.l.i", "SimulationInterval" -> Quantity[40, "Milliseconds"], "ParameterValues" -> {"r1.R" -> TruncatedDistribution[{0, ∞}, NormalDistribution[6, 5]]}|>]

外部干扰也会影响电路的性能. 例如，扬声器的输入电压可能受到高频信号的影响：

Wolfram Language code: inputs = Table[With[{k = k}, Function[{t}, 2.5Sin[2 π t 50] + k Sin[2 π t 2000]]], {k, 0, 0.6, 0.05}];
Wolfram Language code: Plot[Through[inputs[t]], {t, 0, 0.01}]

绘制受这些高频干扰影响时扬声器电流的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> "speaker.l.i", "SimulationInterval" -> Quantity[10, "Milliseconds"], "Inputs" -> {"vi" -> inputs}|>, TargetUnits -> {"Milliseconds", "Milliamperes"}]

受控系统的验证  (1)

通过将球放置在远离稳定位置的位置来验证一个受控的球杆系统：

系统模型：

Wolfram Language code: model = [image];

球离开平衡点越远，系统越难将其带回到稳定位置：

Wolfram Language code: spec = <|"SimulationInterval" -> {0, 1.2}, "InitialValues" -> {"syse.sys.ballAndBeamDynamics.rs" -> Interval[{0, 0.15}]}|>;
Wolfram Language code: SystemModelUncertaintyPlot[model, Append[spec, "Outputs" -> {"syse.sys.ballAndBeamDynamics.rs"}], PlotRange -> All, PlotLabel -> "r"]

控制力在开始时达到峰值，然后又有几次峰值，以阻止球超过稳定位置：

Wolfram Language code: SystemModelUncertaintyPlot[model, Append[spec, "Outputs" -> {"syse.sys.T"}], PlotRange -> All, PlotLabel -> "Control effort"]

受控系统还应该针对外部干扰进行验证. 用白噪声扭矩扰动对受控球杆系统施加应力，并绘制系统在不同噪声采样周期下的控制力度：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"SimulationInterval" -> {0, 1.2}, "Outputs" -> {"syse.sys.T"}, "Inputs" -> {"T" -> WhiteNoiseProcess[0.1]}|>, SamplingPeriod -> 0.3, PlotRange -> All, PlotLabel -> "Control effort"]

轨道调整  (1)

研究短时切向助推对圆形轨道上的玩具航天器的影响：

Wolfram Language code: model = ConnectSystemModelComponents["BoostModel", {"orbit"∈"Control.CircularOrbit", "zero"∈"Blocks.Sources.Constant", "boost"∈"Blocks.Sources.Pulse"}, {"orbit.fr""zero.y", "orbit.fphi""boost.y"}, IconizedObject[«model settings»]]

大幅助推可能导致无界轨迹：

Wolfram Language code: sim = SystemModelSimulate[model, {"orbit.x", "orbit.y"}, Quantity[8, "Hours"], <|"ParameterValues" -> {"boost.amplitude" -> {0, 600, 700, 800, 900, 1000}}|>];
Wolfram Language code: SystemModelPlot[sim, PlotLegends -> None, Axes -> False, Frame -> True]

如果助推幅度遵循正态分布，则可以展开有界或无界轨迹. 绘制到力心距离的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> {"orbit.r"}, "ParameterValues" -> {"boost.amplitude" -> NormalDistribution[600, 100]}|>]

供暖系统中的过冲  (1)

从一个加热系统模型开始，该模型中的热流会在仿真中途切换方向：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

选择管道中的温度作为输出，并指定仿真区间：

Wolfram Language code: pipe9T = <|"Outputs" -> "pipe9.mediums[1].T", "SimulationInterval" -> 100|>;

选择管道直径作为参数，并将一个区间作为采样区域：

Wolfram Language code: uncertainty = <|"ParameterValues" -> {"pipe8.diameter" -> Interval[{0.012, 0.055}]}|>;

绘制管道温度相对于管道直径的不确定性，并观察其对过冲的影响：

Wolfram Language code: SystemModelUncertaintyPlot[model, Join[pipe9T, uncertainty], PlotRange -> {Automatic, {18, 50}}, PlotLabel -> "Temperature overshoot"]

选择两个管道中的温度作为输出：

Wolfram Language code: pipes89T = <|"Outputs" -> {"pipe9.mediums[1].T", "pipe8.mediums[1].T"}, "SimulationInterval" -> 100|>;

绘制温度的不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[model, Join[pipes89T, uncertainty], PlotRange -> All, PlotLayout -> "Shared", PlotLabel -> "Temperature overshoots"]

机器人的控制设计  (1)

从一个机器人模型开始，该机器人执行一个时间受限的运动，承载 300 公斤的载荷，目标旋转角度为 60°：

Wolfram Language code: model = SystemModel[\!\(\*GraphicsBox[«8»]\), <|"ParameterValues" -> {"mLoad" -> 300}, "ModelName" -> "IndustrialRobot"|>];

选择旋转角度作为输出并指定仿真区间：

Wolfram Language code: angle = <|"Outputs" -> "mechanics.r1.angle", "SimulationInterval" -> 1.856, "InterpolationPoints" -> 500|>;

选择控制器中的增益作为参数，并选择一个区间作为采样区域：

Wolfram Language code: uncertainty = <|"ParameterValues" -> {"kp1" -> Interval[{1, 30}]}|>;

绘制旋转角度相对于控制器增益的不确定性，并查看仿真结束时对目标角度的影响：

Wolfram Language code: SystemModelUncertaintyPlot[model, Join[angle, uncertainty], PlotRange -> {{1.2, 1.85}, {50, 65}}, PlotLabel -> "Rotation angle", GridLines -> {{}, {60}}]

属性和关系  (2)

使用 SystemModelPlot 绘制各个曲线：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);
Wolfram Language code: SystemModelPlot[model, {"Inertia2.w"}, <|"ParameterValues" -> {"Inertia2.J" -> 2}|>]

使用 SystemModelPlot 在进行参数扫描时绘制各个曲线：

Wolfram Language code: SystemModelPlot[model, {"Inertia2.w"}, <|"ParameterValues" -> {"Inertia2.J" -> {1, 2, 3}}|>]

使用 SystemModelPlot 绘制由 SystemModelSimulateSensitivity 计算得到的灵敏度带：

Wolfram Language code: sim = SystemModelSimulateSensitivity[model, 10, {"Inertia2.J"}, <|"ParameterValues" -> {"Inertia2.J" -> 2}|>]
Wolfram Language code: SystemModelPlot[sim, {{"Inertia2.w", "Inertia2.J", 0.5}}]

使用 SystemModelUncertaintyPlot 绘制不确定性：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> "Inertia2.w", "ParameterValues" -> {"Inertia2.J" -> CenteredInterval[{{1, 1, 536870912, -29}, 63}]}|>]

Interval 和 CenteredInterval 作为区域被抽样：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);
Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> "Inertia2.w", "ParameterValues" -> {"Inertia2.J" -> CenteredInterval[{{1, 1, 858993460, -33}, 66}]}|>]

Around 和 VectorAround 作为其对应的分布被抽样：

Wolfram Language code: SystemModelUncertaintyPlot[model, <|"Outputs" -> "Inertia2.w", "ParameterValues" -> {"Inertia2.J" -> Around[2., 0.1]}|>]

巧妙范例  (1)

可视化混沌系统对初始条件微小变化的敏感性：

Wolfram Language code: SystemModelUncertaintyPlot[[image], <|"Outputs" -> "x", "InitialValues" -> {"x" -> CenteredInterval[{{0, 0, 549755814, -39}, 72}]}|>]
Wolfram Research (2024)，SystemModelUncertaintyPlot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SystemModelUncertaintyPlot.html.

文本

Wolfram Research (2024)，SystemModelUncertaintyPlot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SystemModelUncertaintyPlot.html.

CMS

Wolfram 语言. 2024. "SystemModelUncertaintyPlot." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SystemModelUncertaintyPlot.html.

APA

Wolfram 语言. (2024). SystemModelUncertaintyPlot. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SystemModelUncertaintyPlot.html 年

BibTeX

@misc{reference.wolfram_2026_systemmodeluncertaintyplot, author="Wolfram Research", title="{SystemModelUncertaintyPlot}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/SystemModelUncertaintyPlot.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemmodeluncertaintyplot, organization={Wolfram Research}, title={SystemModelUncertaintyPlot}, year={2024}, url={https://reference.wolfram.com/language/ref/SystemModelUncertaintyPlot.html}, note=[Accessed: 03-November-2026]}