WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BodePlot[lsys]

線形時間不変系 lsys のボード(Bode)線図を与える．

BodePlot[lsys,{ωmin,ωmax}]

ωminから ωmaxまでの周波数範囲の線図を与える．

BodePlot[expr,{ω,ωmin,ωmax}]

変数 ω を使った expr の線図を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
CoordinatesToolOptions  
GridLines  
GridLinesStyle  
Show More Show More
PhaseRange  
PlotLayout  
PlotTheme  
SamplingPeriod  
ScalingFunctions  
StabilityMargins  
StabilityMarginsStyle  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BodePlot

BodePlot[lsys]

線形時間不変系 lsys のボード(Bode)線図を与える．

BodePlot[lsys,{ωmin,ωmax}]

ωminから ωmaxまでの周波数範囲の線図を与える．

BodePlot[expr,{ω,ωmin,ωmax}]

変数 ω を使った expr の線図を与える．

詳細とオプション

例題

すべて開く すべて閉じる

例  (3)

ある系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{20}}, 20 + s}, s]]

二次の系：

Wolfram Language code: lsys[ω_, ζ_] := TransferFunctionModel[{{{ω^2}}, s^2 + 2*s*ζ*ω + ω^2}, s];

明示的な周波数範囲でプロットする：

Wolfram Language code: BodePlot[lsys[1, 1], {.01, 100}]

状態空間モデルのボード線図：

Wolfram Language code: BodePlot[StateSpaceModel[{{{0, 1}, {-0.5, -0.05}}, {{0}, {1}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

スコープ  (13)

定ゲイン系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{10}}, 1}, s]]

積分器のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, s}, s]]

微分器のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{s}}, 1}, s]]

一次遅れ系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, 1 + 10*s}, s]]

一次進み系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1 + 10*s}}, 1}, s]]

二次系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{100}}, 100 + 1.*s + s^2}, s]]

高次TransferFunctionModel：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{5*(1 + 0.1*s)}}, s + 0.512*s^2 + 0.0064*s^3 + 0.0002*s^4}, s]]

時間遅延系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{E^(-0.5*s)}}, 1. + 2.*s}, s]]

離散時間系：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{-0.9 + z}}, -0.8 + z}, z, SamplingPeriod -> 1]]

周波数範囲を指定する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{-4 + 4.9*z}}, (-4.5 + z)*(-1 + z)}, z, SamplingPeriod -> 1], {0.05, (π/2)}]

状態空間モデルのボード線図：

Wolfram Language code: BodePlot[StateSpaceModel[{{{-1, 10, 0}, {-2, -7, 335}, {0, 0, -10}}, {{0}, {0}, {10}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

それ自身の正弦波伝達関数を使って指定された系：

Wolfram Language code: BodePlot[(10/20ω I + 1), {ω, 0.0005, 10}]

多入力多出力系のボード線図：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{2, 1}, {0.5, 0.1}}, {{1 + s, 2 + s}, {3 + s, 4 + s}}}, s]]

一般化と拡張  (1)

ボード線図は，伝達関数モデルから，あるいはその式から直接取得できる：

Wolfram Language code: g = (12/9 + 0.48s + s^2);
Wolfram Language code: {BodePlot[TransferFunctionModel[g, s]], BodePlot[g]}

オプション  (21)

CoordinatesToolOptions  (5)

座標を得るためにグラフィックスを選んでピリオドキーを押す：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{2500}}, 15500 + 400*s + s^2}, s]]

周波数rad/sであるなら，これを で割って座標周波数の値をHzで得る：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{4}}, 4 + 2*s + s^2}, s], CoordinatesToolOptions -> ("DisplayFunction" -> Function[pt, {(pt[[1]]/2 π), pt[[2]]}])]

異なる単位による各プロットについての座標周波数値：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{16}}, (1 + s)*(4 + s)^2}, s], CoordinatesToolOptions -> {"DisplayFunction" -> Function[pt, {(pt[[1]]/2 π), pt[[2]]}]}]

もとの単位による周波数値，絶対単位によるゲイン，ラジアンによる位相：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{5}}, s*(10 + 6*s + s^2)}, s], CoordinatesToolOptions -> {{"DisplayFunction" -> Function[pt, {pt[[1]], 10^(pt[[2]]/20)}]}, {"DisplayFunction" -> Function[pt, {pt[[1]], pt[[2]] Degree}]}}]

位相の表示とコピー用の値としてラジアンを指定する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{100*s}}, 1 + s}, s], CoordinatesToolOptions -> {Automatic, {"DisplayFunction" -> Function[pt, {pt[[1]], pt[[2]] Degree}], "CopiedValueFunction" -> Function[pt, {pt[[1]], pt[[2]]Degree}]}}]

GridLines  (3)

格子線を表示する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1.6}}, 1.6 + 3*s + s^2}, s], GridLines -> Automatic]

ゲイン線図のみに格子線を表示する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{10}}, (2 + s)*(4 + s)*(6 + s)}, s], GridLines -> {Automatic, None}]

特定の格子線を表示する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, s^2*(3 + s + s^2)}, s], GridLines -> {{List[0.01, 0.1, 1, 10], Range[-150, 140, 20]}, {List[0.01, 0.1, 1, 10], Range[0, 200, 25]}}]

GridLinesStyle  (2)

格子線のスタイルを指定する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, 10 + 3*s + s^3}, s], GridLines -> Automatic, GridLinesStyle -> Red]

異なる格子線のスタイルを指定する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1 + s}}, s*(2 + s)* (3 + s)}, s], GridLines -> Automatic, GridLinesStyle -> {{Green, Orange}, {Red, Orange}}]

PhaseRange  (1)

位相は，一般に，連続関数としてプロットされる：

Wolfram Language code: BodePlot[(1/(s + 1)^4(s + 5)), PlotLayout -> "Phase"]

位相の範囲を指定する：

Wolfram Language code: BodePlot[(1/(s + 1)^4(s + 5)), PlotLayout -> "Phase", PhaseRange -> {-2 π, 0}]

PlotLayout  (1)

デフォルトで，ゲイン線図は位相線図の上に置かれる：

Wolfram Language code: tfm = TransferFunctionModel[{{{-5 + s}}, s*(1 + 3*s + s^2)}, s];
Wolfram Language code: BodePlot[tfm, PlotLabel -> {"Magnitude Plot", "Phase Plot"}]

結果をリストで得る：

Wolfram Language code: BodePlot[tfm, PlotLayout -> "list", PlotLabel -> {"magnitude", "phase"}]

ゲイン線図のみ：

Wolfram Language code: BodePlot[tfm, PlotLayout -> "Magnitude"]

位相線図のみ：

Wolfram Language code: BodePlot[tfm, PlotLayout -> "Phase"]

PlotTheme  (2)

単純な目盛，格子線，明るいカラースキームのテーマを使う：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{20}}, 20 + s}, s], PlotTheme -> "Business"]

カラースキームを変える：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{20}}, 20 + s}, s], PlotTheme -> "Business", PlotStyle -> 56]

SamplingPeriod  (2)

系の説明でサンプリング周期を指定する：

Wolfram Language code: tfm = TransferFunctionModel[{{{0.5}}, (-0.1 + z)*z^2}, z, SamplingPeriod -> 1];
Wolfram Language code: BodePlot[tfm, {0.1, Pi}]

BodePlot関数でサンプリング周期を指定する：

Wolfram Language code: BodePlot[(5/(-0.1 + z) z^2), {0.1, π}, SamplingPeriod -> 1]

サンプリング周期が小さいと帯域幅が高くなる：

Wolfram Language code: BodePlot[(5/(-0.1 + z) z^2), {0.1, π}, SamplingPeriod -> 0.5]

ScalingFunctions  (2)

ゲインを絶対値で，位相はラジアンで示す：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, (1 + s)*(1 + 10*s)}, s], {0.1, 10}, ScalingFunctions -> {{Automatic, "Absolute"}, {Automatic, "Radian"}}]

周波数を均等目盛でプロットする：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1 + s}}, 1 + 5*s + s^2}, s], {0.1, 10}, ScalingFunctions -> {{"Linear", Automatic}, {"Linear", Automatic}}]

StabilityMargins  (2)

安定余裕を示す：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{50}}, (2 + s)*(3 + s)*(8 + s)}, s], StabilityMargins -> True]

位相余裕のみ示す：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{50}}, (2 + s)*(3 + s)*(8 + s)}, s], StabilityMargins -> {False, True}]

StabilityMarginsStyle  (1)

安定余裕のスタイルを指定する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{10000}}, (5 + s)*(20 + s)* (50 + s)}, s], {0.1, 100}, StabilityMargins -> True, StabilityMarginsStyle -> {Green, Directive[Red, Dashed]}]

アプリケーション  (7)

タイプ0系の静止位置誤差定数は定常状態におけるゲインである：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{10}}, 1 + s}, s], {0.001, 10}, Epilog -> {PointSize[Medium], Red, Point[{Log10[0.001], 20 Log10[Limit[(10/s + 1), s -> 0]]}]}, PlotRange -> {{0.0008, 10}, Automatic}, PlotLayout -> "Magnitude", Frame -> False]

離散時間タイプ0系：

Wolfram Language code: BodePlot[ TransferFunctionModel[{{{z}}, (-0.6 + z)*(-0.05 + z)}, z, SamplingPeriod -> 0.5], {0.001, (π/0.5)}, Epilog -> {PointSize[Medium], Red, Point[{Log10[0.001], 20 Log10[Limit[(z/(z - 0.05) (z - 0.6)), z -> 1]]}]}, PlotRange -> {{0.0008, (π/0.5)}, Automatic}, PlotLayout -> "Magnitude", Frame -> False]

タイプ1系の静止速度誤差定数は0 dBラインと最初の10年におけるデシベルのセグメント（あるいはその延長）のほぼ交点である：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{5}}, s*(3 + s)}, s], {0.1, 100}, Epilog -> {Line[{{Log10[0.1], 0}, {Log10[100], 0}}], PointSize[Large], Red, Point[{ Log10[Limit[s (5 /s(s + 3)), s -> 0]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]

離散時間タイプ1系：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, (-1 + z)*(-0.025 + z)}, z, SamplingPeriod -> 1], {0.1, π}, Epilog -> {Line[{{Log10[0.1], 0}, {Log10[π], 0}}], PointSize[Medium], Red, Point[{Log10[Limit[(z - 1/(z - 1) (z - 0.025)), z -> 1]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]

タイプ2の系の静止加速度誤差定数の平方根は最初の10年間にデシベルのセグメント（あるいはその延長）と0 dB線とのほぼ交点である：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{1}}, s^2*(1 + s)}, s], {0.1, 10}, Epilog -> {Line[{{Log10[0.1], 0}, {Log10[10], 0}}], PointSize[Medium], Red, Point[{ Log10[Sqrt[Limit[s^2(1/s^2(s + 1)), s -> 0]]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]

離散時間タイプ2系：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{0.0001*z}}, (-1 + z)^2* (0.1 - 0.3*z + z^2)}, z, SamplingPeriod -> 1], {0.001, π}, Epilog -> {Line[{{Log10[0.001], 0}, {Log10[π], 0}}], PointSize[Medium], Red, Point[{Log10[Sqrt[Limit[((z - 1)^2 (0.0001 z)/(z - 1)^2 (z^2 - 0.3 z + 0.1)), z -> 1]]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]

比例積分(PI)補償器を使って位相余裕の向上を可視化する：

Wolfram Language code: BodePlot[{Tooltip[TransferFunctionModel[{{{583900}}, s*(36 + s)*(100 + s)}, s]], Tooltip[TransferFunctionModel[{{{36786*(0.98 + s)}}, s*(0.062 + s)* (36 + s)*(100 + s)}, s]]}, StabilityMargins -> {True, True}, StabilityMarginsStyle -> {RGBColor[0.24, 0.6, 0.8], RGBColor[0.95, 0.627, 0.1425]}, PlotStyle -> {RGBColor[0.24, 0.6, 0.8], RGBColor[0.95, 0.627, 0.1425]}, PlotLayout -> "Phase", Frame -> False]

サンプリング周期が1のゼロ次ホールドの周波数応答を可視化する：

Wolfram Language code: BodePlot[TransferFunctionModel[{{{(-1 + E^s)/E^s}}, s}, s], {0.01, 30}, ScalingFunctions -> {{"Linear", "Absolute"}, {"Linear", "Degree"}}, PlotRange -> All]

ラプラス変数がラジアン／秒のときに，周波数がヘルツのボード線図を得る：

Wolfram Language code: tfm = TransferFunctionModel[{{{100}}, s*(100 + 10*s + s^2)}, s];
Wolfram Language code: BodePlot[tfm[I 2 π f], f]

連続時間系については，ラプラス変数をスケールすることで，同じ結果を得ることができる：

Wolfram Language code: BodePlot[tfm[2 π s]]

ラジアン／秒のZ変換変数による離散時間系についてのヘルツの点：

Wolfram Language code: BodePlot[(-0.4 + E^2 I f π/0.5  + E^2 I f π), f, SamplingPeriod -> 1]

特性と関係  (1)

SingularValuePlotはボード線図のゲイン線図を多入力多出力系に一般化する：

Wolfram Language code: tfm = TransferFunctionModel[{{{10000}}, (5 + s)*(20 + s)* (50 + s)}, s];
Wolfram Language code: {SingularValuePlot[tfm], BodePlot[tfm, PlotLayout -> "Magnitude", Frame -> False]}
Wolfram Research (2010), BodePlot, Wolfram言語関数， https://reference.wolfram.com/language/ref/BodePlot.html （2014年に更新）.

テキスト

Wolfram Research (2010), BodePlot, Wolfram言語関数， https://reference.wolfram.com/language/ref/BodePlot.html （2014年に更新）.

CMS

Wolfram Language. 2010. "BodePlot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/BodePlot.html.

APA

Wolfram Language. (2010). BodePlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BodePlot.html

BibTeX

@misc{reference.wolfram_2026_bodeplot, author="Wolfram Research", title="{BodePlot}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/BodePlot.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bodeplot, organization={Wolfram Research}, title={BodePlot}, year={2014}, url={https://reference.wolfram.com/language/ref/BodePlot.html}, note=[Accessed: 10-August-2026]}