WOLFRAM

Wolfram 语言与系统参考资料中心

DiscretePlot3D[f,{i,imin,imax},{j,jmin,jmax}]

生成 f 的值的图形，其中 i 从 imin 到 imax 取值， j 从 jmin 到 jmax 取值.

DiscretePlot3D[f,{i,imin,imax,di},{j,jmin,jmax,dj}]

分别用步长 di 和 dj.

DiscretePlot3D[f,{i,{i1,…,im}},{j,{j1,…,jn}}]

uses successive i values i1, …, jm and j values j1, …, jn.

DiscretePlot3D[{f1,f2,…},…,…]

绘制所有 fk 的值的图形.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据和布局  
标签和图例  
样式及外观  
选项  
Axes  
AxesLabel  
AxesOrigin  
Show More Show More
AxesStyle  
ColorFunction  
ColorFunctionScaling  
EvaluationMonitor  
ExtentElementFunction  
ExtentMarkers  
ExtentSize  
Filling  
FillingStyle  
ImageSize  
Joined  
LabelingFunction  
LabelingSize  
PlotLegends  
PlotMarkers  
PlotStyle  
PlotTheme  
RegionFunction  
ScalingFunctions  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DiscretePlot3D

DiscretePlot3D[f,{i,imin,imax},{j,jmin,jmax}]

生成 f 的值的图形，其中 i 从 imin 到 imax 取值， j 从 jmin 到 jmax 取值.

DiscretePlot3D[f,{i,imin,imax,di},{j,jmin,jmax,dj}]

分别用步长 di 和 dj.

DiscretePlot3D[f,{i,{i1,…,im}},{j,{j1,…,jn}}]

uses successive i values i1, …, jm and j values j1, …, jn.

DiscretePlot3D[{f1,f2,…},…,…]

绘制所有 fk 的值的图形.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

绘制一个二变量序列的图形：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], {t, 0, 10}, {u, 0, 10}]

将每一个点与一个区域向联系：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], {t, 0, 10}, {u, 0, 10}, ExtentSize -> Full]

绘制若干序列的图形：

Wolfram Language code: DiscretePlot3D[{PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], PDF[MultivariatePoissonDistribution[5, {2, 2}], {t, u}]}, {t, 0, 10}, {u, 0, 10}, ExtentSize -> Full]

范围  (12)

数据和布局  (4)

绘制多个数据集的图形：

Wolfram Language code: DiscretePlot3D[{Sin[t + u], Cos[t + u]}, {t, 0, 2Pi, Pi / 12}, {u, 0, 2Pi, Pi / 12}, ExtentSize -> Full]

对于单个数据，数据集，或一组数据集是用包装：

Wolfram Language code: {DiscretePlot3D[{Sin[t + u], Cos[t + u]}, {t, 0, 2 * Pi, Pi / 6}, {u, 0, 2 * Pi, Pi / 6}, ExtentSize -> Full], DiscretePlot3D[{Sin[t + u], Style[Cos[t + u], Green]}, {t, 0, 2 * Pi, Pi / 6}, {u, 0, 2 * Pi, Pi / 6}, ExtentSize -> Full], DiscretePlot3D[Style[{Sin[t + u], Cos[t + u]}, Green], {t, 0, 2 * Pi, Pi / 6}, {u, 0, 2 * Pi, Pi / 6}, ExtentSize -> Full]}

包装可以嵌套：

Wolfram Language code: DiscretePlot3D[Style[{Sin[t + u], Style[Cos[t + u], Green]}, Red], {t, 0, 2 * Pi, Pi / 12}, {u, 0, 2 * Pi, Pi / 12}, ExtentSize -> Full]

覆盖默认的工具提示：

Wolfram Language code: DiscretePlot3D[{Sin[t + u], Tooltip[Cos[t + u], "my data"]}, {t, 0, 2 * Pi, Pi / 12}, {u, 0, 2 * Pi, Pi / 12}, ExtentSize -> Full]

使用 PopupWindow 来提供更多更深入的信息：

Wolfram Language code: DiscretePlot3D[PopupWindow[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], TraditionalForm[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}]]], {t, 0, 10}, {u, 0, 10}, ExtentSize -> Full]

Button 可用来激活一个动作：

Wolfram Language code: DiscretePlot3D[Evaluate@Table[With[{lambda = λ}, Button[PDF[ MultivariatePoissonDistribution[lambda, {1, 1}], {t, u}], Speak[MultivariatePoissonDistribution[lambda, {1, 1}]]]], {λ, {1, 2, 3}}], {t, 0, 10}, {u, 0, 10}, PlotRange -> All, ExtentSize -> Full]

使用 ScalingFunctions 缩放轴：

Wolfram Language code: DiscretePlot3D[LCM[x, y], {x, 20}, {y, 20}, ExtentSize -> Full, ScalingFunctions -> "Log"]

标签和图例  (3)

标签单个点：

Wolfram Language code: DiscretePlot3D[Callout[GCD[x, y], If[x == y, x, None], Above], {x, Prime[Range[10]]}, {y, Prime[Range[10]]}]

使用工具提示条：

Wolfram Language code: DiscretePlot3D[Tooltip[GCD[x, y], GCD[x, y]], {x, Prime[Range[10]]}, {y, Prime[Range[10]]}]

使用 LabelingFunction 指定标签名称：

Wolfram Language code: DiscretePlot3D[GCD[x, y], {x, 1, 5}, {y, 1, 5}, LabelingFunction -> (#1[[1]] &)]
Wolfram Language code: DiscretePlot3D[Callout[GCD[x, y], IntegerName@GCD[x, y]], {x, 1, 5}, {y, 1, 5}]

样式及外观  (5)

用 ExtentSize 将一个点和一个区域相联系：

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], {t, 0, 10}, {u, 0, 10}, ExtentSize -> s, PlotLabel -> s], {s, {None, Full, Right, Scaled[0.5]}}]

在图形上用一个显式的式样列表：

Wolfram Language code: DiscretePlot3D[{Sin[t + u], Cos[t + u]}, {t, 0, 2 * Pi}, {u, 0, 2 * Pi}, PlotStyle -> {Red, Blue}, ExtentSize -> Full]

使用 ColorData 提供的任何一个渐变配色方案：

Wolfram Language code: {DiscretePlot3D[{Sin[t + u], Cos[t + u]}, {t, 0, 2 * Pi}, {u, 0, 2 * Pi}, ColorFunction -> "Pastel", ExtentSize -> Full], DiscretePlot3D[{Sin[t + u], Cos[t + u]}, {t, 0, 2 * Pi}, {u, 0, 2 * Pi}, ColorFunction -> Function[{x, y}, ColorData["NeonColors"][y]], ExtentSize -> Full]}

Style 可以用来覆盖式样：

Wolfram Language code: DiscretePlot3D[{Sin[t + u], Style[Cos[t + u], Red]}, {t, 0, 2 * Pi}, {u, 0, 2 * Pi}, PlotStyle -> Gray, ExtentSize -> Full]

显示图形标符：

Wolfram Language code: DiscretePlot3D[Exp[-x ^ 2 - y ^ 2], {x, -3, 3, 0.25}, {y, -3, 3, 0.25}, PlotMarkers -> "Sphere"]

显示延伸区域边界线：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], {t, 10}, {u, 10}, ColorFunction -> "Rainbow", ExtentSize -> Full, ExtentMarkers -> "Tube"]
Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], {t, 10}, {u, 10}, ExtentSize -> Full, ColorFunction -> "DarkRainbow", ExtentMarkers -> {{"Tube", None}, {"Tube", None}}]

使用高对比色彩方案中具有暗色背景的主题：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, PlotTheme -> "Marketing"]

选项  (90)

Axes  (3)

默认情况下，为每个 DiscretePlot3D 绘制 Axes：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full]

用 AxesFalse 不绘制坐标轴：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, Axes -> False]

单独显示每个坐标轴：

Wolfram Language code: {DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, Axes -> {True, False, False}], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, Axes -> {False, True, False}], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, Axes -> {False, False, True}]}

AxesLabel  (4)

默认情况下不绘制坐标轴的标签：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full]

在 轴放置标签：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesLabel -> "Mod[x,y]"]

指定坐标轴的标签：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesLabel -> {"x", "y", "Mod[x,y]"}]

用 DiscretePlot3D 中指定的变量作为标签：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesLabel -> Automatic]

AxesOrigin  (2)

自动确定坐标轴的位置：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full]

明确指定坐标轴的原点：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesOrigin -> {5, 0, 0}]

AxesStyle  (4)

改变坐标轴的样式：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesStyle -> Red]

指定每个坐标轴的样式：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesStyle -> {{Thick, Brown}, {Thick, Blue}, {Thick, Green}}]

为刻度和坐标轴设置不同的样式：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesStyle -> Green, TicksStyle -> StandardBlue]

为标签和坐标轴设置不同的样式：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AxesStyle -> Green, LabelStyle -> Black]

ColorFunction  (6)

根据 , , 或 值的比例给点配色：

Wolfram Language code: Map[DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ColorFunction -> Function[{x, y, z}, #], PlotLabel -> #]&, {Hue[x], Hue[y], Hue[z]}]

按照 , , 或 值的比例给曲面配色：

Wolfram Language code: Map[DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, Joined -> True, PlotRange -> All, ColorFunction -> Function[{x, y, z}, #], PlotLabel -> #]&, {Hue[x], Hue[y], Hue[z]}]

根据 , , 或 值的比例给区域配色：

Wolfram Language code: Map[DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full, ColorFunction -> Function[{x, y, z}, #], PlotLabel -> #]&, {Hue[x], Hue[y], Hue[z]}]

是用一个命名的渐变配色方案：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full, ColorFunction -> "Rainbow"]

ColorFunction 优先于 PlotStyle：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ColorFunction -> "Rainbow", PlotStyle -> Directive[Red, PointSize[Large]]]

当两个数互质时用黑色：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 1, 20}, {n, 1, 20}, ExtentSize -> Full, ColorFunction -> Function[{x, y, z}, If[z == 1, Black, Hue[z / 20]]], ColorFunctionScaling -> False]

ColorFunctionScaling  (1)

按照绝对高度配色：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 10}, {y, 0, 10}, ExtentSize -> Full, ColorFunction -> Function[{x, y, z}, Hue[z]], ColorFunctionScaling -> False]

EvaluationMonitor  (1)

收集所绘制的高度：

Wolfram Language code: {plot, points} = Reap[DiscretePlot3D[LCM[n, m], {m, 20}, {n, 20}, EvaluationMonitor :> Sow[LCM[n, m]], ExtentSize -> Full]];

显示这些高度的图形及直方图：

Wolfram Language code: {plot, Histogram[points]}

ExtentElementFunction  (5)

为 ExtentElementFunction 获取一个内置设置的列表：

Wolfram Language code: ChartElementData["DiscretePlot3D"]

对于详细的设置，使用 面板 ▶ 图表元素方案:

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 8}, {y, 0, 8}, ExtentSize -> Full, ExtentElementFunction -> f], {f, {"Cone", "Cube", "Cylinder", "PlaneFadingCube"}}]
Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 8}, {y, 0, 8}, ExtentSize -> Full, ExtentElementFunction -> f], {f, {"ProfileCube", "DoubleProfileCube", "SquareWaveCube", "TriangleWaveCube"}}]

这个 ChartElementFunction 适合于显示全局标度：

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 8}, {y, 0, 8}, ExtentSize -> Full, ExtentElementFunction -> f], {f, {"GradientScaleCube", "SegmentScaleCube"}}]

编写一个客户指定的 ExtentElementFunction:

Wolfram Language code: vase[{{xmin_, xmax_}, {ymin_, ymax_}, {zmin_, zmax_}}, ___] := {CapForm[None], Tube[ Table[{(xmin + xmax) / 2, (ymin + ymax) / 2, z}, {z, zmin, zmax, (zmax - zmin) / 15}], Join[Sort[RandomReal[(xmax - xmin){0.1, 0.5}, 8], Less], Sort[RandomReal[(xmax - xmin){0.1, 0.5}, 8], Greater]]]}
Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 5}, {y, 0, 5}, ExtentSize -> Full, ExtentElementFunction -> vase, PlotRange -> {0, 0.1}]

一个内置的函数可以含有某些选项；可用 面板 ▶ 图表元素方案 对它们进行设置：

Wolfram Language code: ChartElementData["ProfileCube", "Options"]
Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[1, {1, 1}], {x, y}], {x, 0, 5}, {y, 0, 5}, ExtentSize -> Full, ExtentElementFunction -> ChartElementData["ProfileCube", "Profile" -> p, "TaperRatio" -> r]], {p, {0.1, 1, 5}}, {r, {0, 0.5, 1}}]

ExtentMarkers  (4)

不要显示延伸面边界：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 6}, {n, 6}, ExtentSize -> Full, ExtentMarkers -> None, PlotStyle -> EdgeForm[]]

用线条显示延伸面边界：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 6}, {n, 6}, ExtentSize -> Full, ExtentMarkers -> {"Line", 5}, PlotStyle -> EdgeForm[]]

用不同尺寸的管子显示延伸面边界：

Wolfram Language code: Table[DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> Full, ExtentMarkers -> {"Tube", size}], {size, {Tiny, Small, Medium, Large}}]

将管子放置于延伸区域的前边和左边：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> Full, ExtentMarkers -> {{"Tube", None}, {"Tube", None}}]

ExtentSize  (6)

以点显示高度：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> None]

在高度周围绘出全尺寸区域

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> Full]

分布不均匀的点的情况：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, {1, 2, 3, 5, 8, 13}}, {n, {1, 2, 3, 5, 8, 13}}, ExtentSize -> Full]

使用固定尺寸的区域：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> 0.5]

分布不均匀的点的情况：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, {1, 2, 3, 5, 8, 13}}, {n, {1, 2, 3, 5, 8, 13}}, ExtentSize -> 0.5]

使用点与点之间距离的相对值的尺寸：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> Scaled[0.75]]

分布不均匀的点的情况：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, {1, 2, 3, 5, 8, 13}}, {n, {1, 2, 3, 5, 8, 13}}, ExtentSize -> Scaled[0.75]]

使用尺寸相等而不相互重叠的区域：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> All]

分布不均匀的点的情况：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, {1, 2, 3, 5, 8, 13}}, {n, {1, 2, 3, 5, 8, 13}}, ExtentSize -> All]

控制区域在点周围的置放：

Wolfram Language code: Table[DiscretePlot3D[LCM[m, n], {m, 5}, {n, 5}, ExtentSize -> es, PlotLabel -> es, PlotMarkers -> {"Sphere", Large}], {es, {{{None, Full}, {None, Full}}, {{Full, None}, {Full, None}}}}]

Filling  (3)

DiscretePlot3D 填充到 ：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n], {m, 15}, {n, 15}, Evaluate[opt]], {opt, {Joined -> False, Joined -> True, ExtentSize -> Full}}]

关闭填充：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n], {m, 15}, {n, 15}, Filling -> None, Evaluate[opt]], {opt, {Joined -> False, Joined -> True, ExtentSize -> Full}}]

填充到不同程度：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n] - Mod[n, m], {m, 15}, {n, 15}, Filling -> fill, PlotLabel -> fill], {fill, {Bottom, Top, Axis, -20}}]

FillingStyle  (3)

以一系列不同的样式填充到图形底部：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n] - Mod[n, m], {m, 15}, {n, 15}, Filling -> Bottom, FillingStyle -> fs], {fs, {Opacity[1], Red, Dashed, Thick}}]

扩展了的点的区域的情形：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n] - Mod[n, m], {m, 15}, {n, 15}, ExtentSize -> Full, Filling -> Bottom, FillingStyle -> fs], {fs, {Opacity[1], Red}}]

在填充面上下使用不同颜色：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n] - Mod[n, m], {m, 15}, {n, 15}, ExtentSize -> es, Filling -> Axis, FillingStyle -> {Red, Blue}], {es, {None, Full}}]

只填充填充面以下的部分：

Wolfram Language code: Table[DiscretePlot3D[Mod[m, n] - Mod[n, m], {m, 15}, {n, 15}, ExtentSize -> es, Filling -> Axis, FillingStyle -> {Red, None}], {es, {None, Full}}]

ImageSize  (7)

使用已命名尺寸，如 Tiny、Small、Medium 和 Large：

Wolfram Language code: {DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> Tiny], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code: {DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> 150], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code: {DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> {Automatic, 150}], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定的大小：

Wolfram Language code: {DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> UpTo[200]], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> {200, 250}, Background -> StandardGray]

设置 AspectRatioFull 将填充可用空间：

Wolfram Language code: DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AspectRatio -> Full, ImageSize -> {200, 250}, Background -> StandardGray]

使用允许的最大宽度和高度：

Wolfram Language code: {DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> {UpTo[150], UpTo[100]}], DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

用 ImageSizeFull 填充对象中的可用空间：

Wolfram Language code: Framed[Pane[DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, ImageSize -> Full, Background -> StandardGray], {200, 100}]]

以可用空间的比例指定图像的大小：

Wolfram Language code: Framed[Pane[DiscretePlot3D[Mod[x, y], {x, 10}, {y, 10}, ExtentSize -> Full, AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardGray], {250, 250}]]

Joined  (2)

将点连接成曲面：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, Joined -> True]

将一个曲面与延展区域相结合：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, Joined -> True, ExtentSize -> Full]

LabelingFunction  (4)

把标签放在点上方：

Wolfram Language code: DiscretePlot3D[GCD[x, y], {x, 1, 5}, {y, 1, 5}, LabelingFunction -> Above]

放在工具提示条上：

Wolfram Language code: DiscretePlot3D[GCD[x, y], {x, 1, 5}, {y, 1, 5}, LabelingFunction -> Tooltip]

使用标注标记点：

Wolfram Language code: DiscretePlot3D[GCD[x, y], {x, 1, 5}, {y, 1, 5}, LabelingFunction -> Callout[Automatic, Automatic]]

用它们的值标记点：

Wolfram Language code: DiscretePlot3D[GCD[x, y], {x, 1, 5}, {y, 1, 5}, LabelingFunction -> (#1&)]

用索引标记点：

Wolfram Language code: DiscretePlot3D[GCD[x, y], {x, 1, 5}, {y, 1, 5}, LabelingFunction -> (#2&)]

LabelingSize  (1)

指定文本标签的最大尺寸：

Wolfram Language code: DiscretePlot3D[Callout[GCD[x, y], IntegerName[x]], {x, 500, 505}, {y, 500, 505}, ImageSize -> Medium, LabelingSize -> 30]

使用完整标签：

Wolfram Language code: DiscretePlot3D[Callout[x + y, IntegerName[x + y]], {x, 0, 10}, {y, 0, 10}, ImageSize -> Medium, LabelingSize -> Full]

PlotLegends  (6)

使用自动图例：

Wolfram Language code: DiscretePlot3D[{Sin[x + y], Cos[x + y]}, {x, 20}, {y, 20}, ExtentSize -> Full, PlotLegends -> Automatic]

指定图例的标签列表：

Wolfram Language code: DiscretePlot3D[{x, y}, {x, 20}, {y, 20}, ExtentSize -> Full, PlotLegends -> {"label1", "label2"}]

使用命名的图例:

Wolfram Language code: DiscretePlot3D[{Sin[x + y], Sin[x - y]}, {x, 20}, {y, 20}, ExtentSize -> Full, PlotLegends -> "Expressions"]

PlotLegends 自动选择 PlotStyle 值:

Wolfram Language code: DiscretePlot3D[{Sin[(x + y) ^ 2], Sin[(x - y) ^ 2]}, {x, 0, 2, 0.2}, {y, 0, 2, 0.2}, ExtentSize -> Full, PlotStyle -> {Red, Blue}, PlotLegends -> "Expressions"]

使用 Placed 控制图例位置：

Wolfram Language code: Table[DiscretePlot3D[{Sin[(x + y)], Sin[(x - y)]}, {x, 0, 2, 0.2}, {y, 0, 2, 0.2}, ExtentSize -> Full, PlotStyle -> {Orange, Blue}, PlotLegends -> Placed["Expressions", pos]], {pos, {Above, Below}}]

使用 SwatchLegend 改变图例外观：

Wolfram Language code: DiscretePlot3D[{Sin[(x + y) ^ 2], Sin[(x - y) ^ 2]}, {x, 0, 2, 0.2}, {y, 0, 2, 0.2}, ExtentSize -> Full, PlotStyle -> {Red, Blue}, PlotLegends -> SwatchLegend["Expressions", LegendLabel -> "label", LegendFunction -> (Framed[#, RoundingRadius -> 5]&)]]

PlotMarkers  (4)

改变默认绘图标记的大小：

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotMarkers -> {Automatic, s}], {s, {Tiny, Small, Medium, Large}}]

在使用曲面的时候，往往不显示标记：

Wolfram Language code: {DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, Joined -> True], DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full]}

在曲面上使用点状标记：

Wolfram Language code: {DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, Joined -> True, PlotMarkers -> "Point", PlotStyle -> FaceForm[Lighter[Blue, 0.5]]], DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full, PlotMarkers -> "Point"]}

用球体作为标记：

Wolfram Language code: {DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotMarkers -> "Sphere"], DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full, PlotMarkers -> "Sphere"]}

改变球体的大小：

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotMarkers -> {"Sphere", s}], {s, {Tiny, Small, Medium, Large}}]

PlotStyle  (7)

是用不同的式样指令：

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> ps], {ps, {Red, PointSize[0.025], Darker[Green], Directive[Red, PointSize[Small]]}}]

默认时，对多个函数将选取不同式样：

Wolfram Language code: DiscretePlot3D[Evaluate[Table[PDF[MultivariatePoissonDistribution[2k, {k, 3k}], {x, y}], {k, 3}]], {x, 20}, {y, 20}, ExtentSize -> Full]

对不同函数明确指定式样：

Wolfram Language code: DiscretePlot3D[Evaluate[Table[PDF[MultivariatePoissonDistribution[2k, {k, 3k}], {x, y}], {k, 3}]], {x, 20}, {y, 20}, ExtentSize -> Full, PlotStyle -> {Red, Orange, Blue}]

PlotStyle 适用于点、线和曲面：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> Red]
Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full, PlotStyle -> Directive[Orange, EdgeForm[Blue]]]

PlotStyle 可以和 ColorFunction 结合使用：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> PointSize[Medium], ColorFunction -> Function[{x, y, z}, Hue[z]]]

PlotStyle 可以和 FillingStyle 结合使用：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> Red, FillingStyle -> Opacity[1]]

FillingStyle 默认时使用和 PlotStyle 相同的式样，包括透明度：

Wolfram Language code: DiscretePlot3D[PDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> Red]

PlotTheme  (4)

使用具有简单刻度和网格线的主题：

Wolfram Language code: DiscretePlot3D[{CDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], SurvivalFunction[MultivariatePoissonDistribution[3, {1, 1}], {t, u}]}, {t, 10}, {u, 10}, PlotTheme -> "Business"]

改变色彩方案：

Wolfram Language code: DiscretePlot3D[{CDF[MultivariatePoissonDistribution[3, {1, 1}], {t, u}], SurvivalFunction[MultivariatePoissonDistribution[3, {1, 1}], {t, u}]}, {t, 10}, {u, 10}, PlotTheme -> "Business", PlotStyle -> {Red, Blue}]

使用在高对比色彩方案中具有暗色背景的主题：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 15}, {n, 15}, PlotTheme -> "Marketing"]

不显示刻度：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 15}, {n, 15}, PlotTheme -> "Marketing", Ticks -> None]

RegionFunction  (4)

限制绘制区域：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 25}, {n, 25}, RegionFunction -> Function[{m, n, z}, m ≤ n]]

延伸区域被视为绘制点而不做裁剪：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 5}, {n, 5}, ExtentSize -> Full, RegionFunction -> Function[{m, n, z}, m <= n], PlotMarkers -> "Sphere"]

区域可以有若干不相连接的组成部分：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 25}, {n, 25}, RegionFunction -> Function[{m, n, z}, Mod[m + n, 10] ≤ 7]]

使用约束条件的逻辑组合来定义区域：

Wolfram Language code: DiscretePlot3D[GCD[m, n], {m, 25}, {n, 25}, RegionFunction -> Function[{m, n, z}, m ^ 2 + n ^ 2 ≤ 625 && m + n ≥ 25]]

ScalingFunctions  (9)

默认情况下，在每个方向的绘图使用线性标度：

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 0, 10, .5}, {y, 0, 10, .5}, ExtentSize -> Full]

在 方向使用对数标度：

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 1, 10, .5}, {y, 1, 10, .5}, ExtentSize -> Full, ScalingFunctions -> "Log"]

在 方向使用线性标度，在前面显示更小的数字：

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 0, 10, .5}, {y, 0, 10, .5}, ExtentSize -> Full, ScalingFunctions -> {None, "Reverse"}]

在 方向使用倒数标度：

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 1, 10, .5}, {y, 1, 10, .5}, ExtentSize -> Full, ScalingFunctions -> {None, "Reciprocal"}]

在 和 方向使用不同的标度：

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 0, 10, .5}, {y, 0, 10, .5}, ExtentSize -> Full, ScalingFunctions -> {"Reverse", "Log"}]

不改变 轴，反向 轴:

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 0, 10, .5}, {y, 0, 10, .5}, ExtentSize -> Full, ScalingFunctions -> {"Reverse", None}]

使用由函数和其反函数定义的 标度：

Wolfram Language code: DiscretePlot3D[Max[x, y], {x, 0, 10, .5}, {y, 0, 10, .5}, ExtentSize -> Full, ScalingFunctions -> {None, {-Log[#]&, Exp[-#]&}}]

Ticks 和 FaceGrids 中的位置是自动标度的：

Wolfram Language code: DiscretePlot3D[u + t ^ 2, {t, 0.01, 50}, {u, 0, 10}, ExtentSize -> Full, ScalingFunctions -> {"Log", None}, Ticks -> {2 ^ Range[10], Automatic, Automatic}, FaceGrids -> All]

PlotRange 是自动标度的：

Wolfram Language code: DiscretePlot3D[LCM[m, n], {m, 50}, {n, 50}, ExtentSize -> Full, ScalingFunctions -> "Log", PlotRange -> {100, 1000}]

应用  (2)

用于图示离散分布的性质，如概率密度函数：

Wolfram Language code: Table[DiscretePlot3D[PDF[MultivariatePoissonDistribution[μ, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> 0.5, PlotLabel -> Row[{"μ = ", μ}]], {μ, {1, 5}}]

累积分布函数：

Wolfram Language code: Table[DiscretePlot3D[CDF[MultivariatePoissonDistribution[μ, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> Purple, ExtentSize -> Right, PlotLabel -> Row[{"μ = ", μ}]], {μ, {1, 5}}]

残存函数：

Wolfram Language code: Table[DiscretePlot3D[SurvivalFunction[MultivariatePoissonDistribution[μ, {2, 3}], {x, y}], {x, 0, 15}, {y, 0, 15}, PlotStyle -> Orange, ExtentSize -> Right, PlotLabel -> Row[{"μ = ", μ}]], {μ, {1, 5}}]

用黎曼和求一个曲面下体积的近似：

Wolfram Language code: plot = Plot3D[PDF[BinormalDistribution[0.5], {x, y}], {x, -2, 2}, {y, -2, 2}, PlotStyle -> Directive[Opacity[0.4], Yellow], RegionFunction -> (# < 0 || #2 > 0&)]
Wolfram Language code: riemann = DiscretePlot3D[PDF[BinormalDistribution[0.5], {x, y}], {x, -2, 2, 0.5}, {y, -2, 2, 0.5}, ExtentSize -> Full, RegionFunction -> (# < 0 || #2 > 0&)]
Wolfram Language code: Show[plot, riemann]

属性和关系  (4)

Plot3D 生成连续的曲面：

Wolfram Language code: Plot3D[PDF[BinormalDistribution[0.5], {x, y}], {x, -2, 2}, {y, -2, 2}]

用 ListPointPlot3D 绘制数值的列表的图形：:

Wolfram Language code: {ListPointPlot3D[Table[Table[x + y, {x, 10}], {y, 10}]], DiscretePlot3D[x + y, {x, 10}, {y, 10}]}

用 BarChart3D 显示数值的列表的条形图：

Wolfram Language code: {BarChart3D[Table[Table[x + y, {x, 10}], {y, 10}], ChartLayout -> "Grid"], DiscretePlot3D[x + y, {x, 10}, {y, 10}, ExtentSize -> Full]}

用 DiscretePlot 绘制离散单变量函数的图形：

Wolfram Language code: DiscretePlot[PDF[PoissonDistribution[4], x], {x, 0, 10}, ExtentSize -> Scaled[0.5]]
Wolfram Research (2010)，DiscretePlot3D，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscretePlot3D.html （更新于 2019 年）.

文本

Wolfram Research (2010)，DiscretePlot3D，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscretePlot3D.html （更新于 2019 年）.

CMS

Wolfram 语言. 2010. "DiscretePlot3D." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/DiscretePlot3D.html.

APA

Wolfram 语言. (2010). DiscretePlot3D. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscretePlot3D.html 年

BibTeX

@misc{reference.wolfram_2026_discreteplot3d, author="Wolfram Research", title="{DiscretePlot3D}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DiscretePlot3D.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discreteplot3d, organization={Wolfram Research}, title={DiscretePlot3D}, year={2019}, url={https://reference.wolfram.com/language/ref/DiscretePlot3D.html}, note=[Accessed: 13-September-2026]}