Wolfram 语言与系统参考资料中心

ComplexListPlot

参见
- ListPlot
- ReImPlot
- AbsArgPlot
- ComplexPlot
- ComplexPlot3D
- ReIm
- Abs
- Arg
- I
- ListPolarPlot
- PolarPlot
- MandelbrotSetPlot
- JuliaSetPlot
相关指南
- 复数可视化
- 参见
  - ListPlot
  - ReImPlot
  - AbsArgPlot
  - ComplexPlot
  - ComplexPlot3D
  - ReIm
  - Abs
  - Arg
  - I
  - ListPolarPlot
  - PolarPlot
  - MandelbrotSetPlot
  - JuliaSetPlot
- 相关指南
  - 复数可视化

ComplexListPlot

ComplexListPlot[{z₁,z₂,…}]

将复数 z₁、z₂、… 绘制为复平面上的点.

ComplexListPlot[{data₁,data₂,…}]

绘制所有 data_i 的数据.

ComplexListPlot[{…,w[data_i,…],…}]

绘制带有由符号封装 w 定义的特征的 .

范例

打开所有单元关闭所有单元

基本范例 (4)

绘制一组复数：

Wolfram Language code: ComplexListPlot[{-2 - 2 I, -1 - I, 0, 1 + I, 2 + 2 I}]

绘制多组复数：

Wolfram Language code: ComplexListPlot[{RandomComplex[{0, 1 + I}, 100], RandomComplex[{-2 - 2I, 2 + 2I}, 100]}]

绘制几个，同时显示图例：

Wolfram Language code:

data = Table[a t Exp[2 π I t], {a, 2, 4}, {t, 0, 1, 0.02}];
ComplexListPlot[data, PlotLegends -> {"a=2", "a=3", "a=4"}]

用 callout 标注每个点：

Wolfram Language code: ComplexListPlot[Callout[#, #]& /@ Table[E^π I k / 4, {k, 1, 8}]]

范围 (39)

数据 (7)

将复值列表绘制为 ${Re[z_(i)],Im[z_(i)]}$ 数据对列表：

Wolfram Language code: ComplexListPlot[Sin[Range[40] + 2I]]

绘制多组常规数据：

Wolfram Language code: ComplexListPlot[{Sin[Range[40] + 2I], Cos[Range[40] + 2I]}]

不包含非数值型和缺失数据：

Wolfram Language code: ComplexListPlot[{1 + I, 2 + 2I, Missing["NotAvailable"], 4 + 4I, None, 6 + 6I, ""}]

用 MaxPlotPoints 限制所用点的个数：

Wolfram Language code:

data = Table[Exp[2Pi I RandomReal[]], {n, 200}];
Table[ComplexListPlot[data, MaxPlotPoints -> mp], {mp, {Infinity, 100, 50}}]

自动选择 PlotRange：

Wolfram Language code:

{ComplexListPlot[{0, 1 + I, 2 + 2I, 3 + 3I, 4 + 20I, 5 + 5I, 20 + 6I}], 
	ComplexListPlot[{0, 1 + I, 2 + 2I, 3 + 3I, 4 + 20I, 5 + 5I, 20 + 6I}, PlotRange -> All]}

用 PlotRange 显示感兴趣的区域：

Wolfram Language code:

{ComplexListPlot[{0, 1 + I, 2 + 2I, 3 + 3I, 4 + 100I, 5 + 5I, 20 + 6I}], 
	ComplexListPlot[{0, 1 + I, 2 + 2I, 3 + 3I, 4 + 100I, 5 + 5I, 20 + 6I}, PlotRange -> {0, 7 + 7I}]}

用 ScalingFunctions 缩放坐标轴：

Wolfram Language code: ComplexListPlot[Table[10^k + 2^kI, {k, -2, 5}], ScalingFunctions -> {"Log10", "Log2"}]

表格数据 (1)

用随机起始种子运行牛顿法求解结果的表格数据：

Wolfram Language code: tab = Tabular[IconizedObject[«data»], {"seed", "solution", "basin"}]

绘制表格中的所有点：

Wolfram Language code: ComplexListPlot[tab -> "seed", PlotStyle -> AbsolutePointSize[2]]

使用 PivotToColumns 为每个吸引盆（basin of attraction）生成列：

Wolfram Language code: pivot = PivotToColumns[tab, "basin" -> "seed"]

分别绘制每个区域的数字：

Wolfram Language code: ComplexListPlot[pivot -> {Key[1], Key[2], Key[3]}, PlotStyle -> AbsolutePointSize[2]]

特殊数据 (4)

指定用字符串作为标签：

Wolfram Language code:

ComplexListPlot[{1 + I -> "a", 2 + 2I -> "b", 3 + 3I -> "c", 4 + 4I -> "d", 5 + 3I -> "e", 6 + 2I -> "f", 7 + I -> "g"}]
ComplexListPlot[{1 + I, 2 + 2 I, 3 + 3 I, 4 + 4 I, 5 + 3 I, 6 + 2 I, 7 + I} -> {"a", "b", "c", "d", "e", "f", "g"}]

为标签指定位置：

Wolfram Language code:

ComplexListPlot[{1 + I, 2 + 2 I, 3 + 3 I, 4 + 4 I, 5 + 3 I, 6 + 2 I, 7 + I} -> {"a", "b", "c", "d", "e", "f", "g"}, LabelingFunction -> Above]

将 Association 中的数值用作坐标：

Wolfram Language code: ComplexListPlot[<|"a" -> 2 + I, "b" -> 3 - I, "c" -> 5 + 2I, "d" -> 7, "e" -> 11 + 2I, "f" -> 13 - 3I|>]

绘制 SparseArray 中的数据：

Wolfram Language code: ComplexListPlot[SparseArray[RandomComplex[{0, 1 + I}, 25]]]

封装 (6)

在单个数据、数据集或者数据集集合上使用封装：

Wolfram Language code:

{ComplexListPlot[{{1 + I, Style[3 + 2I, Red], 6 + 3I}, {1 + 4I, 3 + 5I, 6 + 6I}}, PlotStyle -> PointSize[0.05]], 
	ComplexListPlot[{Style[{1 + I, 3 + 2I, 6 + 3I}, Red], {1 + 4I, 3 + 5I, 6 + 6I}}, PlotStyle -> PointSize[0.05]], 
	ComplexListPlot[Style[{{1 + I, 3 + 2I, 6 + 3I}, {1 + 4I, 3 + 5I, 6 + 6I}}, Red], PlotStyle -> PointSize[0.05]]}

封装可以嵌套：

Wolfram Language code:

{ComplexListPlot[{{1 + I, Style[3 + 2I, Red], 6 + 3I}, {1 + 4I, 3 + 5I, 6 + 6I}}, PlotStyle -> PointSize[0.05]], 
	ComplexListPlot[{Style[{1 + I, Style[3 + 2I, Red], 6 + 3I}, Green], {1 + 4I, 3 + 5I, 6 + 6I}}, PlotStyle -> PointSize[0.05]], 
	ComplexListPlot[Style[{Style[{1 + I, Style[3 + 2I, Red], 6 + 3I}, Green], {1 + 4I, 3 + 5I, 6 + 6I}}, Blue], PlotStyle -> PointSize[0.05]]}

对所有点使用特定标签：

Wolfram Language code: ComplexListPlot[Tooltip[Table[k + Sqrt[k]I, {k, 10}], "square roots"]]

用自动确定位置的文字对点进行标注：

Wolfram Language code: ComplexListPlot[Table[Labeled[RandomComplex[{0, 1 + I}], i], {i, 20}], PlotStyle -> PointSize[Medium], ImageSize -> 300]

用 PopupWindow 单击特征值以查看相应的特征向量：

Wolfram Language code:

{evalues, evecs} = Eigensystem[RandomComplex[{-1 - I, 1 + I}, {4, 4}]];
ComplexListPlot[PopupWindow@@@Transpose[{evalues, evecs}], PlotStyle -> PointSize[0.04]]

可用 Button 触发操作：

Wolfram Language code:

evalues = Eigenvalues[RandomComplex[{-1 - I, 1 + I}, {8, 8}]];
ComplexListPlot[Button[#, Speak[#]]& /@ evalues, PlotStyle -> PointSize[0.02]]

添加标签和图例 (15)

用自动确定位置的文字对点进行标注：

Wolfram Language code: ComplexListPlot[Table[Labeled[RandomComplex[{0, 1 + I}], i], {i, 20}]]

按相对于点的位置放置标签：

Wolfram Language code:

Table[ComplexListPlot[Table[Labeled[RandomComplex[{0, 1 + I}], i, p], {i, 20}], PlotLabel -> p], {p, {Above, Below, Before, After}}]

用 Labeled 标记数据：

Wolfram Language code:

ComplexListPlot[{
	Labeled[NestList[(0.9 + 0.1I)#&, 1 + I, 30], 0.1], Labeled[NestList[(0.9 + 0.2I)#&, 1 + I, 30], 0.2]
	}]

用 PlotLabels 标记数据：

Wolfram Language code:

ComplexListPlot[{
	NestList[(0.9 + 0.1I)#&, 1 + I, 30], NestList[(0.9 + 0.2I)#&, 1 + I, 30]
	}, PlotLabels -> {0.1, 0.2}]

在特定值的附近放置标签：

Wolfram Language code:

ComplexListPlot[{
	Labeled[NestList[(0.9 + 0.1I)#&, 1 + I, 30], 0.1, 0.1], Labeled[NestList[(0.9 + 0.2I)#&, 1 + I, 30], 0.2, 0.3]
	}]

使用缩放过的位置：

Wolfram Language code:

ComplexListPlot[{
	Labeled[NestList[(0.9 + 0.1I)#&, 1 + I, 30], 0.1, Scaled[0.1]], Labeled[NestList[(0.9 + 0.2I)#&, 1 + I, 30], 0.2, Scaled[0.1]]
	}]

指定文字相对于点的位置：

Wolfram Language code:

ComplexListPlot[{
	Labeled[NestList[(0.9 + 0.1I)#&, 1 + I, 30], 0.1, {Scaled[0.1], Above}], Labeled[NestList[(0.9 + 0.2I)#&, 1 + I, 30], 0.2, {Scaled[0.1], Below}]
	}]

用 Callout 自动标记数据：

Wolfram Language code:

ComplexListPlot[{
	Callout[NestList[(0.9 + 0.1I)#&, 1 + I, 30], 0.1], Callout[NestList[(0.9 + 0.2I)#&, 1 + I, 30], 0.2]
	}]

在指定位置放置标签：

Wolfram Language code:

ComplexListPlot[{
	Callout[NestList[(0.9 + 0.1I)#&, 1 + I, 30], 0.1, Above], Callout[NestList[(0.9 + 0.2I)#&, 1 + I, 30], 0.2, Below]
	}]

用 LabelingFunction 指定标签名：

Wolfram Language code: ComplexListPlot[z /. Solve[z^6 == 1, z], LabelingFunction -> (DisplayForm[RowBox[{"(", #1[[1]], #1[[2]], ")"}]]&)]

Wolfram Language code: ComplexListPlot[z /. Solve[z^12 == 1, z], LabelingFunction -> (Arg[#1[[1]] + I#[[2]]]&)]

对于密集的数据点，缺省情况下，一些标签将被转换成提示条：

Wolfram Language code: Quiet@ComplexListPlot[z /. Solve[z^50 == 1, z], LabelingFunction -> (Arg[#1[[1]] + I#[[2]]]&)]

增大绘图将显示出更多的标签：

Wolfram Language code: Quiet@ComplexListPlot[z /. Solve[z^50 == 1, z], LabelingFunction -> (Arg[#1[[1]] + I#[[2]]]&), ImageSize -> 500]

显示每个 data_i 的图例：

Wolfram Language code:

ComplexListPlot[{
	NestList[(0.9 + 0.1I)#&, 1 + I, 30], NestList[(0.9 + 0.2I)#&, 1 + I, 30]
	}, PlotLegends -> {0.1, 0.2}]

用 Legended 为特定数据集提供图例：

Wolfram Language code:

matrix = RandomComplex[{-1 - I, 1 + I}, {10, 10}];
evals1 = Eigenvalues[matrix];
evals2 = Eigenvalues[(matrix + ConjugateTranspose[matrix]/2)];
ComplexListPlot[{evals1, Legended[evals2, "eigenvalues of the
symmetric matrix"]}]

用 Placed 改变图例的位置：

Wolfram Language code: ComplexListPlot[{evals1, Legended[evals2, Placed["eigenvalues of the symmetric matrix", Below]]}]

用关联中的键作为标签：

Wolfram Language code: ComplexListPlot[<|"random" -> evals1, "symmetric" -> evals2|>, PlotLabels -> Automatic]

当你把鼠标移到绘图上方时，地图通常会有交互式 callouts 显示坐标：

Wolfram Language code: ComplexListPlot[{IconizedObject[«data»], IconizedObject[«data2»]}]

演示 (6)

自动用不同颜色为多个数据集着色以示区别：

Wolfram Language code:

f = (z^6 + z^3 + 1/z^10 - 1024);
zeros = z /. Solve[f == 0, z];
poles = z /. Solve[Denominator[f] == 0, z];
ComplexListPlot[{zeros, poles}]

为不同数据集指定明确的样式：

Wolfram Language code: ComplexListPlot[{zeros, poles}, PlotStyle -> {Blue, Red}]

使用绘图主题：

Wolfram Language code: ComplexListPlot[{zeros, poles}, PlotTheme -> "Marketing"]

显示每个数据集的图例：

Wolfram Language code: ComplexListPlot[{zeros, poles}, PlotLegends -> {"zeros", "poles"}]

用 Legended 为特定数据集提供图例：

Wolfram Language code: ComplexListPlot[{zeros, Legended[poles, "poles"]}]

为数据提供交互 Tooltip：

Wolfram Language code: ComplexListPlot[Table[Tooltip[Exp[2Pi I k / 10], Exp[2Pi I k / 10]], {k, 0, 9}]]

用形状区分不同的数据集：

Wolfram Language code: ComplexListPlot[Table[Exp[2Pi I k / n], {n, {3, 5, 7}}, {k, 0, n - 1}], PlotMarkers -> Automatic]

用标签区分不同的数据集：

Wolfram Language code: ComplexListPlot[Table[Exp[2Pi I k / n], {n, {3, 5, 7}}, {k, 0, n - 1}], PlotMarkers -> {"3", "5", "7"}]

通过 Joined 将各点连成线：

Wolfram Language code: ComplexListPlot[Table[Exp[2Pi I k / 10], {k, 0, 10}], Joined -> True]

用 InterpolationOrder 使数据更平滑：

Wolfram Language code: Table[ComplexListPlot[Table[Exp[2Pi I k / 10], {k, 0, 10}], Joined -> True, InterpolationOrder -> io], {io, {0, 1, 2}}]

选项 (156)

AspectRatio (4)

默认情况下，绘图的高宽比是自动确定的：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}]]

使用数值指定高宽比：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> 1 / GoldenRatio]

设置 AspectRatio1 可使高度与宽度相同：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> 1]

AspectRatioFull 调整高度和宽度以紧密贴合其他构造：

Wolfram Language code:

plot = ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> Full];
{Framed[Pane[plot, {75, 100}]], Framed[Pane[plot, {100, 100}]], Framed[Pane[plot, {100, 50}]]}

Axes (3)

默认情况下，ComplexListPlot 绘制轴：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}]]

使用 AxesOrigin 可指定轴相交处：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Frame -> False, Axes -> True, AxesOrigin -> {0, 0}]

分别显示每条轴：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Axes -> {True, False}], ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Axes -> {False, True}]}

AxesLabel (3)

默认情况下不绘制坐标轴标签：

Wolfram Language code: ComplexListPlot[Table[E^2π I k / 12, {k, 0, 11}]]

在轴上放置标签：

Wolfram Language code: ComplexListPlot[Table[E^2π I k / 12, {k, 0, 11}], AxesLabel -> "Im"]

指定轴标签：

Wolfram Language code: ComplexListPlot[Table[E^2π I k / 12, {k, 0, 11}], AxesLabel -> {"Real", "Im"}]

AxesOrigin (2)

轴的位置是自动确定的：

Wolfram Language code: ComplexListPlot[Table[10 + 3I + E^2π I k / 12, {k, 0, 11}]]

为轴指定一个明确的原点：

Wolfram Language code: ComplexListPlot[Table[10 + 3I + E^2π I k / 12, {k, 0, 11}], AxesOrigin -> {6, 1}]

AxesStyle (4)

更改轴的样式：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Frame -> False, Axes -> True, AxesStyle -> Red]

指定每条轴的样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Frame -> False, Axes -> True, AxesStyle -> {{Thick, Red}, {Thick, Blue}}]

对刻度和轴使用不同的样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Frame -> False, Axes -> True, AxesStyle -> Green, TicksStyle -> StandardGray]

对标签和轴使用不同的样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 π, 0.1}], Frame -> False, Axes -> True, AxesStyle -> Green, LabelStyle -> StandardGray]

ClippingStyle (4)

ClippingStyle 要求至少要有一个数据集是 Joined：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x] / x ^ 2, {x, -10, 10, 0.2}], ClippingStyle -> Red], 
	ComplexListPlot[Table[x + I Sin[x] / x ^ 2, {x, -10, 10, 0.2}], ClippingStyle -> Red, Joined -> True]}//Quiet

略去曲线被剪掉的区域：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x] / x ^ 2, {x, -10, 10, 0.2}], ClippingStyle -> None, Joined -> True]//Quiet

在底部用红线显示被剪掉的区域，在顶部用粗线显示被剪掉的区域：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x] / x ^ 2, {x, -10, 10, 0.2}], ClippingStyle -> {Red, Thick}, Joined -> True]//Quiet

用红色的粗线显示被剪掉的区域：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x] / x ^ 2, {x, -10, 10, 0.2}], ClippingStyle -> Directive[Red, Thick], Joined -> True]//Quiet

ColorFunction (3)

按缩放过的、、和坐标着色：

Wolfram Language code:

Table[ComplexListPlot[Table[Sin[2x]Exp[I x], {x, 0, 2π, .1}], Joined -> True, PlotLabel -> Hue[var], ColorFunction -> Function[{x, y, θ, r}, Evaluate[Hue[var]]]], {var, {x, y, θ, r}}]

对于曲线着色，ColorFunction 比 PlotStyle 的优先级高：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, .1}], ColorFunction -> "Rainbow", Joined -> True, PlotStyle -> Directive[Red, Thick]]

在 MeshShading 中设置 Automatic 以使用 ColorFunction：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, .1}], ColorFunction -> "Rainbow", Joined -> True, PlotStyle -> Directive[Red, Thick], Mesh -> 10, MeshShading -> {Automatic, StandardGray}, MeshStyle -> None]

ColorFunctionScaling (4)

ColorFunctionScaling 要求至少要有一个数据集是 Joined：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, .1}], ColorFunction -> "Rainbow", ColorFunctionScaling -> True], 
	ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, .1}], ColorFunction -> "Rainbow", ColorFunctionScaling -> True, Joined -> True]}

根据缩放过的值对曲线进行着色：

Wolfram Language code:

ComplexListPlot[Table[0.25(I + Exp[I t]), {t, 0, 2Pi, .1}], ColorFunction -> Function[{x, y}, Hue[y]], Joined -> True, ColorFunctionScaling -> True]

根据未经缩放的值对曲线进行着色：

Wolfram Language code:

ComplexListPlot[Table[0.25(I + Exp[I t]), {t, 0, 2Pi, .1}], ColorFunction -> Function[{x, y}, Hue[y]], Joined -> True, ColorFunctionScaling -> False]

根据未经缩放的、、和坐标对曲线进行着色：

Wolfram Language code:

Table[ComplexListPlot[Table[Sin[2x]Exp[I x], {x, 0, 2π, .05}], Joined -> True, ColorFunctionScaling -> False, PlotLabel -> Hue[var], ColorFunction -> Function[{x, y, θ, r}, Evaluate[Hue[var]]]], {var, {x, y, θ, r}}]

Frame (3)

在绘图周围绘制边框：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True]

在左右边绘制边框：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> {{True, True}, {False, False}}]

在左边和底边绘制边框：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> {{True, False}, {True, False}}]

FrameLabel (4)

沿着边框底边放置一个标签：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameLabel -> {"label"}]

在底边和左边放置标签：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameLabel -> {"bottom", "left"}]

在每条边框边上放置标签：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameLabel -> {{"left", "right"}, {"bottom", "top"}}]

对标签和边框刻度标签使用自定义样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameLabel -> {{"left", "right"}, {"bottom", "top"}}, LabelStyle -> Directive[Bold, Red]]

FrameStyle (2)

指定边框的样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameStyle -> Directive[StandardGray, Thick]]

为每条边框边指定样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameStyle -> {{Directive[Green, Thick], Directive[Red]}, {Directive[Gray, Thick], Directive[Blue]}}]

FrameTicks (9)

默认情况下会自动放置边框刻度：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True]

使用没有刻度的边框：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> None]

在底边使用边框刻度：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{None, None}, {Automatic, None}}]

默认情况下，顶边和右边有刻度线但没有刻度标签：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> Automatic]

使用 All 可在所有边上添加刻度标签：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> All]

在特定位置放置刻度线：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{{1, .5, -1}, Automatic}, {{1, Pi, 4}, Automatic}}]

使用特定标签在指定位置绘制边框刻度线：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{{{1, a}, {.5, b}, {-1, -a}}, Automatic}, {{{1, a}, {Pi, "Pi"}, {6, d}}, Automatic}}]

将刻度线的长度指定为图形大小的一定比例：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{{{1, a}, {.5, b}, {-1, -a}}, Automatic}, {{{1, a, 0.86}, {Pi, "Pi", 0.5}, {6, d, .4}}, Automatic}}]

在每个刻度线的正负方向上使用不同的尺寸：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{{{1, a}, {.5, b}, {-1, -a}}, Automatic}, {{{1, a, {0.86, 0.05}}, {Pi, Pi, {0.5, 0.1}}, {6, d, {.4, .2}}}, Automatic}}]

为每条边框刻度指定一个样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{{{1, a}, {.5, b}, {-1, -a}}, Automatic}, {{{1, a, 0.86, Directive[Red, Thick]}, {Pi, "Pi", 0.5, Directive[StandardGray, Thick, Dashed]}, {6, d, .4, Darker@Green}}, Automatic}}]

构造一个函数，将边框刻度放置在边框边的中点和极端：

Wolfram Language code: minMeanMax[min_, max_] := {{min, min}, {(max + min) / 2, (max + min) / 2}, {max, max}}

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> {{minMeanMax, None}, {minMeanMax, None}}, PlotRangePadding -> None]

FrameTicksStyle (3)

默认情况下，边框刻度和边框刻度标签使用与边框相同的样式：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameStyle -> Directive[Red]]

指定刻度的整体样式，包括标签：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameStyle -> Directive[Red], FrameTicksStyle -> Directive[Blue, Thick]]

对不同的边框边使用不同的样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Frame -> True, FrameTicks -> All, FrameTicksStyle -> {{Purple, Blue}, {Thick, Red}}]

ImageSize (8)

使用有名称的尺寸如 Tiny、Small、Medium 和 Large：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> Tiny], ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> 150], ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> {Automatic, 150}], ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> 1.5, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定大小：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> UpTo[200]], ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> {200, 200}, Background -> StandardBlue]

设置 AspectRatioFull 会填充可用空间：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> Full, ImageSize -> {200, 200}, Background -> StandardBlue]

使用最大尺寸的宽度和高度：

Wolfram Language code:

{ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> {UpTo[150], UpTo[100]}], ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

设置 ImageSizeFull 会填充对象中的可用空间：

Wolfram Language code:

Framed[Pane[ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> Full, Background -> StandardBlue], {200, 100}]]

将图像大小指定为可用空间的一部分：

Wolfram Language code:

Framed[Pane[ComplexListPlot[Table[x + I Sin[x], {x, 0, 2Pi, 0.1}], ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardBlue], {200, 100}]]

直接标记的点数可能取决于图像尺寸：

Wolfram Language code: data = RandomComplex[{0, 10 + 10I}, 200] -> Range[200];

Wolfram Language code: ComplexListPlot[data]

较小图形的标记点也较少：

Wolfram Language code: ComplexListPlot[data, ImageSize -> 200]

较大的图形标记点也较多：

Wolfram Language code: ComplexListPlot[data, ImageSize -> 500]

InterpolationOrder (4)

InterpolationOrder 要求至少要有一个数据集是 Joined：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, 1}], InterpolationOrder -> 2], ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, 1}], InterpolationOrder -> 2, Joined -> True]}

默认情况下采用线性插值：

Wolfram Language code: ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, 1}], Joined -> True, InterpolationOrder -> None, Mesh -> Full]

采用零阶或分段常数插值：

Wolfram Language code: ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, 1}], Joined -> True, InterpolationOrder -> 0, Mesh -> Full]

0 到 3 阶插值：

Wolfram Language code:

Table[ComplexListPlot[Table[t Exp[I t], {t, 0, 4Pi, 1}], Joined -> True, InterpolationOrder -> i, Mesh -> Full, PlotLabel -> i], {i, 0, 3}]

Joined (3)

连接数据集中的点：

Wolfram Language code:

data = Table[t Exp[2π I t], {t, 0, 10, .1}];
Table[ComplexListPlot[data, Joined -> s], {s, {False, True}}]

用线连接第一个数据集中的点，但用点显示第二个数据集中的数据：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[n, x] + I BesselI[n, x], {n, 1, 2}, {x, 0, 5, .1}], Joined -> {True, False}]

用线连接数据集中的点并显示原来的点：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[1, x] + I BesselI[1, x], {x, 0, 5, .1}], Joined -> True, Mesh -> All]

LabelingFunction (7)

如果值和标签的列表长度相同，则可用 Rule 对点进行标注：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> {0, 1, 2, 3, 4, 5, 6}]

可用规则和值列表来标注所选择的点：

Wolfram Language code:

ComplexListPlot[{1 -> 0, E^(2 I π/7) -> 1, E^(4 I π/7) -> 2, E^(6 I π/7) -> 3, E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)}]

用 LabelingFunctionNone 即可不显示标签：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> {0, 1, 2, 3, 4, 5, 6}, LabelingFunction -> None]

把标签放置在点的上方：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> {0, 1, 2, 3, 4, 5, 6}, LabelingFunction -> Above]

放置在 Tooltip 中：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> {0, 1, 2, 3, 4, 5, 6}, LabelingFunction -> Tooltip]

用有序对标注点：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)}, LabelingFunction -> (DisplayForm[ToBoxes[TraditionalForm[#1]] /. {"{" -> "(", "}" -> ")"}]&)]

用点的索引标注数据点：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)}, LabelingFunction -> (Last[#2] - 1&)]

LabelingSize (3)

按实际大小显示文字标签：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> {"zeroth", "first", "second", "third", "fourth", "fifth", "sixth"}]

指定文字标签的最大尺寸：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> {"zeroth", "first", "second", "third", "fourth", "fifth", "sixth"}, LabelingSize -> 25]

自动调整图像标签的大小：

Wolfram Language code: images = {[image], [image], [image], [image], [image], [image], [image]};

Wolfram Language code: ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> images]

指定图像标签的最大尺寸：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> images, LabelingSize -> 50]

用原始尺寸显示图像标签：

Wolfram Language code:

ComplexListPlot[{1, E^(2 I π/7), E^(4 I π/7), E^(6 I π/7), E^(8 I π/7), E^(10 I π/7), E^(12 I π/7)} -> images, ImageSize -> 72 8, LabelingSize -> Full]

MaxPlotPoints (1)

用 MaxPlotPoints 限制所用的点的数量：

Wolfram Language code:

data = Table[k Exp[2Pi I k / 100], {k, 200}];
Table[ComplexListPlot[data, MaxPlotPoints -> mp], {mp, {Infinity, 100, 50}}]

Mesh (6)

Mesh 要求至少要有一个数据集是 Joined：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10], ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, Joined -> True]}

初始采样网格和最终的采样网格通常是一样的：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> Full, Joined -> True], ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> All, Joined -> True]}

插值数据可引入更多数据点：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> Full, Joined -> True, InterpolationOrder -> 2], ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> All, Joined -> True, InterpolationOrder -> 2]}

在方向上使用 20 个等间距的网格：

Wolfram Language code: ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 20, Joined -> True]

在方向上用明确的值列表指定网格：

Wolfram Language code: ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> {{-9, 1, 2, 5, 8}}, Joined -> True]

为特定点指定明确的样式：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> {Table[{x, Directive[Hue[x / 20], PointSize[Large]]}, {x, -10, 10}]}, Joined -> True, ColorFunction -> (Hue[#1 / 20]&), ColorFunctionScaling -> False]

MeshFunctions (3)

MeshFunctions 要求至少要有一个数据集是 Joined：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}], ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, Joined -> True]}

在方向上显示 5 个网格（红色），在方向上显示 10 个网格（蓝色）：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Joined -> True, Mesh -> {5, 10}, MeshFunctions -> {#1&, #2&}, MeshStyle -> {Directive[PointSize[Large], Red], Directive[PointSize[Medium], Blue]}]

在、、和方向上使用均匀间隔的网格：

Wolfram Language code:

Table[ComplexListPlot[Table[Sin[2 x] Exp[I x], {x, 0, 2 π, .05}], Joined -> True, Mesh -> 5, MeshStyle -> AbsolutePointSize[5], MeshFunctions -> Function[{x, y, θ, r}, Evaluate[var]], PlotLabel -> var], {var, {x, y, θ, r}}]

MeshShading (7)

MeshShading 要求至少要有一个数据集是 Joined：

Wolfram Language code:

{ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshShading -> {Red, Blue}], ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshShading -> {Red, Blue}, Joined -> True]}

在方向上交替使用等宽的红色线段和蓝色线段：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, MeshShading -> {Red, Blue}, Joined -> True]

用 None 移除线段：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, MeshShading -> {Red, None}, Joined -> True]

MeshShading 可与 PlotStyle 一起使用：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, MeshShading -> {Red, Blue}, PlotStyle -> Dashed, Joined -> True]

MeshShading 比 PlotStyle 的优先级高：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, MeshShading -> {Red, Blue}, PlotStyle -> Green, Joined -> True]

通过将 MeshShading 设为 Automatic 对某些线段使用 PlotStyle：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, MeshShading -> {Red, Automatic}, PlotStyle -> StandardBlue, Joined -> True]

MeshShading 可与 ColorFunction一起使用：

Wolfram Language code:

ComplexListPlot[Table[t Exp[I t], {t, 20}], Mesh -> 10, MeshFunctions -> {#1&}, MeshShading -> {StandardGray, Automatic}, ColorFunction -> Function[{x, y}, Hue[x]], Joined -> True]

PlotHighlighting (7)

在默认设置 PlotHighlightingAutomatic 下，绘图有交互式坐标 callout：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}]]

设置 PlotHighlightingNone 可禁用整个绘图的突出显示：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}], PlotHighlighting -> None]

使用 Highlighted[…,None] 可仅禁用单个数据组的突出显示：

Wolfram Language code:

ComplexListPlot[{Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .2}], Highlighted[Table[40BesselJ[3, x] + I BesselI[3, x], {x, 0, 5, .2}], None]}]

将鼠标移到一组点上，用任意的图形指令对其进行突出显示：

Wolfram Language code:

ComplexListPlot[{Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .2}], Table[40BesselJ[3, x] + I BesselI[3, x], {x, 0, 5, .2}]}, PlotHighlighting -> Directive[Red, AbsolutePointSize[10], DropShadowing[]]]

将鼠标移到数据点上，用标签对其进行突出显示：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .2}], PlotHighlighting -> "Dropline"]

将鼠标移到曲线上，用标签和轴线对其进行突出显示：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .2}], PlotHighlighting -> "Dropline"]

使用组件显示绘图上最接近鼠标光标位置的点：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}], PlotHighlighting -> "XNearestPoint"]

指定点的样式：

Wolfram Language code:

ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}], PlotHighlighting -> {"XNearestPoint", <|"Style" -> Green|>}]

使用组件来显示离鼠标光标最近的点的坐标：

Wolfram Language code: ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}], PlotHighlighting -> "XYLabel"]

使用 Callout 选项改变标签外观：

Wolfram Language code:

ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}], PlotHighlighting -> {"XYLabel", <|"Appearance" -> "Corners", "CalloutMarker" -> "Circle"|>}]

结合各类组件创建自定义的效果：

Wolfram Language code:

ComplexListPlot[Table[40BesselJ[2, x] + I BesselI[2, x], {x, 0, 5, .1}], PlotHighlighting -> {{"XNearestPoint", <|"Style" -> StandardGray|>}, {"XYLabel", <|"Appearance" -> "Corners", "CalloutMarker" -> "Circle"|>}}]

PlotLabel (1)

为整个绘图添加标签：

Wolfram Language code: ComplexListPlot[Table[E^2π I k / 12, {k, 0, 11}], PlotLabel -> "12th roots of unity"]

PlotLabels (5)

为不同的点集指定文字标签：

Wolfram Language code: ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLabels -> {"circle", "line"}]

将标签放置在点的上方：

Wolfram Language code: ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLabels -> Placed[{"circle", "line"}, Above]]

用 callout 来标识点：

Wolfram Language code:

ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLabels -> {Callout["circle", {Scaled[0.25], Above}], Callout["line", {Scaled[0.25], Below}]}]

用 Association 的键作为标签：

Wolfram Language code:

ComplexListPlot[<|"circle" -> Sin[Range[20] + 2I], "line" -> Range[-5, 10] + 2I|>, PlotLabels -> Automatic, PlotLegends -> False]

用 None 不添加标签：

Wolfram Language code: ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLabels -> {None, "line"}]

PlotLegends (6)

用标签生成图例：

Wolfram Language code: ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLegends -> {"circle", "line"}]

用占位符生成图例：

Wolfram Language code: ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLegends -> Automatic]

图例的样式与点的样式相同：

Wolfram Language code: ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLegends -> {"circle", "line"}, PlotStyle -> {Red, Blue}]

用 Placed 指定图例的放置：

Wolfram Language code:

Table[ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLegends -> Placed[{"circle", "line"}, pos], PlotStyle -> {Red, Blue}], {pos, {Above, Below, Before, After}}]

将图例放置在绘图内：

Wolfram Language code:

ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLegends -> Placed[{"circle", "line"}, {0.85, 0.25}], PlotStyle -> {Red, Blue}]

用 PlotLegends 改变外观：

Wolfram Language code:

ComplexListPlot[{Sin[Range[20] + 2I], Range[-5, 10] + 2I}, PlotLegends -> PointLegend[{"circle", "line"}, LegendMarkerSize -> 10, LegendFunction -> Frame]]

PlotMarkers (8)

ComplexListPlot 通常用不同的颜色来区分不同的数据集：

Wolfram Language code: ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> None]

自动选择点的颜色和形状以区分不同的数据集：

Wolfram Language code:

ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> Automatic]

只用形状区分：

Wolfram Language code:

ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> Automatic, PlotStyle -> StandardBlue]

改变缺省标记的大小：

Wolfram Language code:

Table[ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> {Automatic, s}], {s, {Small, Medium, Large}}]

用文字作为标记：

Wolfram Language code:

ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> {"1", "2", "3", "4"}]

用图形作为标记：

Wolfram Language code:

{m1, m2, m3, m4} = Graphics /@ {Circle[{0, 0}, 1], Disk[{0, 0}, 1], Line[{{-0.5, -0.5}, {0.5, -0.5}, {0.5, 0.5}, {-0.5, 0.5}, {-0.5, -0.5}}], Polygon[{{-0.5, -0.5}, {0.5, -0.5}, {0, Sqrt[3] / 4}}]}

Wolfram Language code:

ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> Table[{s, 0.03}, {s, {m1, m2, m3, m4}}]]

对所有数据集使用相同的符号：

Wolfram Language code: ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> "●"]

明确指定符号和大小：

Wolfram Language code:

Table[ComplexListPlot[Table[Sin[2(t + p)]Exp[I (t + p)], {p, 0, 3Pi / 2, Pi / 2}, {t, 0, Pi / 2, 0.05}], PlotMarkers -> {"●", s}], {s, {4, 8, 12}}]

PlotRange (4)

自动计算 PlotRange：

Wolfram Language code: ComplexListPlot[Fourier[Table[Cos[2 π 3 t], {t, 0, 2, 0.05}]]]

显示整个数据集：

Wolfram Language code: ComplexListPlot[Fourier[Table[Cos[2 π 3 t], {t, 0, 2, 0.05}]], PlotRange -> All]

明确选择和的范围：

Wolfram Language code: ComplexListPlot[Fourier[Table[Cos[2 π 3 t], {t, 0, 2, 0.05}]], PlotRange -> {{-3, 3}, {-2, 2}}]

通过给出左下角和右上角的复坐标隐式选择和的范围：

Wolfram Language code: ComplexListPlot[Fourier[Table[Cos[2 π 3 t], {t, 0, 2, 0.05}]], PlotRange -> {-3 - 2I, 3 + 2I}]

PlotStyle (7)

使用不同的样式指令：

Wolfram Language code:

Table[ComplexListPlot[Table[Sin[3x]Exp[I x], {x, 0, Pi, 0.05}], PlotStyle -> ps], {ps, {Red, PointSize[Large], Darker[Green], Directive[Red, PointSize[Large]]}}]

默认情况下，为多个数据集分别选择不同的样式：

Wolfram Language code: ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}]]

明确指定不同数据集的样式：

Wolfram Language code: ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotStyle -> {Red, Green, Blue}]

将 PlotStyle 应用于曲线和点：

Wolfram Language code:

ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotStyle -> {Red, Green, Blue}, Joined -> {False, True, False}]

PlotStyle 可与 ColorFunction 一起使用：

Wolfram Language code:

ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotStyle -> Thick, Joined -> True, ColorFunction -> Function[{x, y}, Hue[x]]]

PlotStyle 可与 MeshShading 一起使用：

Wolfram Language code:

ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotStyle -> Dashed, Joined -> True, Mesh -> 10, MeshFunctions -> {#3&}, MeshShading -> {Red, Blue}]

默认情况下，MeshStyle 采用和 PlotStyle 相同的样式：

Wolfram Language code: ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotStyle -> Red, Joined -> True, Mesh -> All]

PlotTheme (2)

使用刻度简单并带有网格线的颜色明亮的主题：

Wolfram Language code: ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotTheme -> "Business"]

改变颜色方案：

Wolfram Language code: ComplexListPlot[Table[c Sin[3 x]Exp[I x], {c, 3}, {x, 0, Pi, 0.05}], PlotTheme -> "Business", PlotStyle -> 96]

PolarAxes (2)

添加极坐标轴和极坐标网格线：

Wolfram Language code: ComplexListPlot[Table[(1 + 3Sin[4t])Exp[I t], {t, 0, 6π, .05}], PolarAxes -> True, PolarGridLines -> True]

分别控制径向轴和极轴：

Wolfram Language code: ComplexListPlot[Table[a Cos[3t]Exp[I t], {a, 5}, {t, 0, Pi, 0.05}], PolarAxes -> {True, False}]

PolarAxesOrigin (2)

指定角度轴和径向轴相交于：

Wolfram Language code:

ComplexListPlot[Table[(1 + 3Sin[4t])Exp[I t], {t, 0, 6π, .05}], PolarAxes -> True, PolarGridLines -> True, PolarAxesOrigin -> {0, 6}]

将径向轴放置在图形的右边：

Wolfram Language code:

ComplexListPlot[Table[(1 + 3Sin[4t])Exp[I t], {t, 0, 6π, .05}], PolarAxes -> True, PolarGridLines -> True, PolarAxesOrigin -> {{Right, Up}, Automatic}, PolarTicks -> {None, Automatic}]

PolarGridLines (2)

自动选择极坐标网格线：

Wolfram Language code: ComplexListPlot[Table[Sin[4t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> True, PolarGridLines -> True]

在指定位置绘制网格线：

Wolfram Language code:

ComplexListPlot[Table[2Sin[4t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> {True, False}, PolarGridLines -> {Range[0, 2Pi, Pi / 4], {1, 2}}, PolarTicks -> {"Degrees", None}]

Wolfram Language code:

ComplexListPlot[Table[2Sin[4t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> {False, True}, PolarGridLines -> {Range[0, 2Pi, Pi / 4], {1, 2}}, PolarTicks -> {None, Automatic}, GridLinesStyle -> Orange]

PolarTicks (4)

自动放置极坐标刻度标记和标签：

Wolfram Language code: ComplexListPlot[Table[5Cos[2t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> Automatic, PolarTicks -> Automatic]

修改角度刻度：

Wolfram Language code:

ComplexListPlot[Table[5Cos[2t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> Automatic, PolarTicks -> {Range[-Pi + Pi / 12, Pi, Pi / 12], Automatic}]

用度为单位表示角：

Wolfram Language code: ComplexListPlot[Table[5Cos[2t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> Automatic, PolarTicks -> {"Degrees", Automatic}]

在指定位置放置极坐标刻度标记：

Wolfram Language code:

ComplexListPlot[Table[6Cos[2t]Exp[I t], {t, 0, 6π, .05}], PolarAxes -> {True, True}, PolarTicks -> {Range[0, 2Pi - Pi / 4, Pi / 4], Range[0, 10, 2]}]

ScalingFunctions (3)

单个缩放函数在径向缩放数据：

Wolfram Language code: ComplexListPlot[Table[(10I)^t, {t, -5, 6}], Joined -> True, PlotRange -> All, Mesh -> All, ScalingFunctions -> "Log10"]

Wolfram Language code:

data = Table[(1/t)Exp[I t], {t, 20}];
{ComplexListPlot[data, Joined -> True, PlotRange -> All, Mesh -> All], 
	ComplexListPlot[data, Joined -> True, PlotRange -> All, Mesh -> All, ScalingFunctions -> "Reciprocal"]}

指定两个缩放函数可在和方向上分别缩放数据：

Wolfram Language code: ComplexListPlot[Table[10^x + I 2^x, {x, 8}], ScalingFunctions -> {"Log10", "Log2"}]

None 表示在指定方向上不进行缩放：

Wolfram Language code: ComplexListPlot[Table[10^x + (-1)^kx I, {k, 2}, {x, -3, 8}], ScalingFunctions -> {"Log10", None}]

Ticks (9)

自动为每条轴放置刻度：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1]

设置 TicksNone 绘制没有任何刻度线的轴：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> None]

在轴上使用刻度，但在虚轴上不使用：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {Automatic, None}]

在特定位置放置刻度线：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {{1, Pi, 4}, {1, .5, -1}}]

使用特定标签在指定位置绘制刻度线：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {{{1, a}, {Pi, "Pi"}, {6, d}}, {{1, a}, {.5, b}, {-1, -a}}}]

在一条轴上使用特定刻度，在另一轴上使用自动刻度：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {{{1, a}, {Pi, Pi}, {6, d}}, Automatic}]

将刻度的长度指定为图形大小的一定比例：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {{{1, a, .36}, {Pi, Pi, .1}, {6, d, 0.05}}, Automatic}]

在每条刻度的正负方向上使用不同的尺寸：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {{{1, a, {.36, 0}}, {Pi, Pi, {.1, .1}}, {6, d, {0.05, .05}}}, Automatic}]

为每条刻度指定一个样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {{{1, a, {.36, 0}, Red}, {Pi, Pi, {.1, 0.08}, Blue}, {6, d, {0.05, .05}, Purple}}, Automatic}, TicksStyle -> Thick]

构造一个函数，将刻度放置在轴的中点和极值处：

Wolfram Language code: minMeanMax[min_, max_] := {{min, min}, {(max + min) / 2, (max + min) / 2}, {max, max}}

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, Ticks -> {Automatic, minMeanMax}, PlotRangePadding -> None]

TicksStyle (4)

默认情况下，刻度和刻度标签使用与轴相同的样式：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, AxesStyle -> Red]

指定整体刻度样式，包括刻度标签：

Wolfram Language code: ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, TicksStyle -> Red]

为每条轴指定刻度样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, TicksStyle -> {Directive[StandardGreen, Thick], Directive[StandardGray, 12]}]

对刻度标签和刻度线使用不同的样式：

Wolfram Language code:

ComplexListPlot[Table[x + I Sin[x], {x, 0, 2 Pi, 0.1}], AspectRatio -> 1, TicksStyle -> Directive[Red, Thick], LabelStyle -> Blue]

应用 (9)

绘制单位根：

Wolfram Language code:

Manipulate[ComplexListPlot[Labeled[Exp[#], #]& /@ Table[2Pi I k / n, {k, 0, n - 1}], Prolog -> {Circle[]}, ImageSize -> Medium, PlotMarkers -> {Automatic, Medium}, PlotRange -> {{-1.2, 1.2}, {-1.2, 1.2}}], {{n, 6}, 2, 20, 1}]

绘制离散时间信号及其频谱：

Wolfram Language code: signal = Table[Mod[i / 2, 10] / 10, {i, 100}];

Wolfram Language code:

{ListPlot[signal, Filling -> Axis], 
	ComplexListPlot[Fourier[signal], PlotRange -> All]}

绘制 zeta 函数的零点：

Wolfram Language code: Quiet@ComplexListPlot[Table[N[ZetaZero[k]], {k, 20}]]

绘制 Cauchy 矩阵的特征值：

Wolfram Language code: matrix = Table[1 / (i + j - I), {i, 1, 10}, {j, 1, 10}];

Wolfram Language code: ComplexListPlot[1.Eigenvalues[matrix], ScalingFunctions -> {"Log", "Log"}]

绘制的解：

Wolfram Language code: roots = NSolve[Sin[2z] == 1 + Cos[Sin[z]] && -2π ≤ Re[z] ≤ 2π && -2π ≤ Im[z] ≤ 2π, z];

Wolfram Language code: ComplexListPlot[z /. roots, Ticks -> {Range[-2Pi, 2Pi, Pi], Range[-2Pi, 2Pi, Pi]}]

显示矩阵的 Gershgorin 圆盘和特征值：

Wolfram Language code: A = {{10 + 6I, -1, 2, 1}, {1.2, 8 - 3I, 2.2, 2.5}, {-2, 3, 2 + 5I, 1}, {1, -1, -1, I - 11}};

Wolfram Language code:

{MatrixForm[A], 
	ComplexListPlot[Eigenvalues[A], PlotStyle -> Directive[Red, PointSize[.02]], PlotRange -> {{-15, 15}, {-10, 15}}, Prolog -> {Opacity[.4], StandardBlue, 
	MapIndexed[Disk[{Re[#1[[#2]]][[1]], Im[#1[[#2]]][[1]]}, (Total[Abs[#1]] - Abs[#1[[#2]]])[[1]]]&, A]}]}

显示 PDE 问题的特征值. 求结构阻尼波动方程 , 形式为的解：

Wolfram Language code:

ϵ = .1;
eValues = Flatten[Table[{(1/2) (-n^2 ϵ - n Sqrt[-4 + n^2 ϵ^2]), (1/2) (-n^2 ϵ + n Sqrt[-4 + n^2 ϵ^2])}, {n, 1, 100}]];
ComplexListPlot[eValues, PlotRange -> {{-42, 1}, {-11, 11}}, PlotStyle -> Directive[Red, PointSize[.015]], Epilog -> {Gray, Circle[{-(1/ϵ), 0}, (1/ϵ)]}]

可视化牛顿法的迭代：

Wolfram Language code:

ComplexListPlot[Last[Reap[FindRoot[z^3 - 1, {z, 2 - 0.7I}, Method -> "Newton", EvaluationMonitor :> Sow[z]]]], Joined -> True, Mesh -> Full, LabelingFunction -> (Last[#2] - 1&)]

二分图的特征值关于虚轴对称：

Wolfram Language code:

g = Graph[{16, 110, 211, 411, 52, 54, 69, 74, 76, 78, 710, 81, 92, 98, 118}, VertexStyle -> {v_ ? OddQ -> Red, v_ ? EvenQ -> Blue}];

Wolfram Language code: {g, ComplexListPlot[Eigenvalues[AdjacencyMatrix[g]]]}

属性和关系 (9)

用 ListPlot、ListLinePlot 或 ListPolarPlot 绘制实数数据：

Wolfram Language code:

{ListPlot[Table[{x, Exp[x]}, {x, -Pi, Pi, .1}]], 
	ListLinePlot[Table[{x, Exp[x]}, {x, -Pi, Pi, .1}]], 
	ListPolarPlot[Table[{x, Exp[x]}, {x, -Pi, Pi, .1}]]}

ComplexListPlot 与 ListPlot 密切相关：

Wolfram Language code:

data = Table[Exp[I x], {x, -Pi, Pi, .1}];
{ComplexListPlot[data], ListPlot[ReIm[data], AspectRatio -> Automatic]}

使用 ComplexPlot 用颜色显示函数的参数和幅值：

Wolfram Language code: ComplexPlot[Log[z], {z, 3}]

使用 ComplexPlot3D 用轴作为幅值：

Wolfram Language code: ComplexPlot3D[Log[z], {z, 3}]

用 ComplexArrayPlot 绘制复数数组：

Wolfram Language code: ComplexArrayPlot[Table[x ^ 3 + I y ^ 2, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}]]

使用 ReImPlot 和 AbsArgPlot 在实数上绘制复数值：

Wolfram Language code: ReImPlot[Log[x], {x, -3, 3}]

Wolfram Language code: AbsArgPlot[Log[x], {x, -3, 3}]

ComplexContourPlot 在复平面上绘制曲线：

Wolfram Language code: ComplexContourPlot[Abs[Log[z]] == 1, {z, 3}]

ComplexRegionPlot 在复平面上绘制区域：

Wolfram Language code: ComplexRegionPlot[Abs[Log[z]] < 1, {z, 3}]

ComplexStreamPlot 和 ComplexVectorPlot 将复数视为方向：

Wolfram Language code: ComplexStreamPlot[Log[z], {z, 3}]

Wolfram Language code: ComplexVectorPlot[Log[z], {z, 3}]

可能存在的问题 (2)

沿轴绘制实值数据：

Wolfram Language code: {ListPlot[{10, 11, 12, 13}], ListPlot[{{10, 0}, {11, 0}, {12, 0}, {13, 0}}], ComplexListPlot[{10, 11, 12, 13}]}

在实轴和虚轴上使用相同的缩放函数时，径向缩放是不同的：

Wolfram Language code:

data = Table[(10I)^t, {t, -4, 4, .1}];
{ComplexListPlot[data, Joined -> True, Mesh -> All, ScalingFunctions -> "Log10"], 
	ComplexListPlot[data, Joined -> True, Mesh -> All, ScalingFunctions -> {"Log10", "Log10"}]}

巧妙范例 (3)

2010–2011 年全国冰球联赛常规赛球队获胜加权邻接矩阵的特征值分析：

Wolfram Language code:

g = ExampleData[{"NetworkGraph", "NationalHockeyLeague"}]
ComplexListPlot[Eigenvalues[WeightedAdjacencyMatrix[g]], PlotStyle -> {Orange, PointSize[.02]}, PlotRange -> All]

图的邻接矩阵的特征值的实部中的对称性表明该图可能是二分图，但在这种情况下该图不是二分图：

Wolfram Language code:

g = ExampleData[{"NetworkGraph", "SimpleFoodWeb"}]
ComplexListPlot[Eigenvalues[AdjacencyMatrix[g]], PlotStyle -> {Black, PointSize[.025]}, PlotRange -> All]
BipartiteGraphQ[g]

计算两倍于 {0,1,…,n-1} 中各数值的整数模除：

Wolfram Language code:

n = 7;
TableForm[Transpose@Table[{x, 2 x, Mod[2 x, n]}, {x, 0, n - 1}], TableHeadings -> {{x, 2 x, Mod[2  x, n]}, None}, TableAlignments -> Right]

用图形表示作为复平面上点的整数，并将表示和之间的点连接起来：

Wolfram Language code:

lines = Table[{Exp[2π I x / n], Exp[2π I Mod[2 x, n] / n]}, {x, 0, n - 1}];
labels = Table[Text[x, 1.1{Cos[(2π x/n)], Sin[(2π x/n)]}], {x, 0, n - 1}];
ComplexListPlot[lines, Joined -> True, Epilog -> {Circle[], labels}, PlotStyle -> StandardBlue, PlotRange -> 1.2, Ticks -> None] /. Line -> Arrow

如果使用值足够大，则会出现一个包络：

Wolfram Language code:

n = 250;
lines = Table[{Exp[2π I x / n], Exp[2π I Mod[2 x, n] / n]}, {x, 0, n - 1}];
ComplexListPlot[lines, Joined -> True, Epilog -> {Circle[]}, Ticks -> None, PlotStyle -> Directive[Thin, RGBColor[0.29, 0.588, 0.612]]]

使用三和五的倍数：

Wolfram Language code:

lines = Table[{Exp[2π I x / n], Exp[2π I Mod[3 x, n] / n]}, {x, 0, n - 1}];
ComplexListPlot[lines, Joined -> True, Epilog -> {Circle[]}, Ticks -> None, PlotStyle -> Directive[Thin, RGBColor[0.886243, 0.527215, 0.0910023]]]

Wolfram Language code:

lines = Table[{Exp[2π I x / n], Exp[2π I Mod[5 x, n] / n]}, {x, 0, n - 1}];
ComplexListPlot[lines, Joined -> True, Epilog -> {Circle[]}, Ticks -> None, PlotStyle -> Directive[Thin, RGBColor[0.613966, 0.37652, 0.585084]]]

Top

	<\|"k₁"z₁,"k₂"z₂,…\|>	值 {z₁,z₂,…}
	{z₁"lbl₁",z₂"lbl₂",…}, {z₁,z₂,…}{"lbl₁","lbl₂",…}	带有标签 {lbl₁,lbl₂,…} 的值 {z₁,z₂,…}
	SparseArray	以数组形式给出的值

	col	绘制列 col 的复数值
	{col₁,col₂,…}	绘制列 col₁、col₂、… 的值

	Annotation[data_i,label]	为数据提供注释
	Button[data_i,action]	定义数据被点击时要执行的操作
	Callout[data_i,label]	用 callout 标记函数
	Callout[data_i,label,pos]	把 callout 放在相对位置 pos
	EventHandler[data_i,…]	为数据定义通用事件处理器
	Highlighted[data_i,effect]	动态突出显示 f_i 的效果
	Highlighted[data_i,Placed[effect,pos]]	静态突出显示 f_i 在位置 pos 处的效果
	Hyperlink[data_i,uri]	将数据变为超链接
	Labeled[data_i,label]	标记数据
	Labeled[data_i,label,pos]	把标签放在相对位置 pos
	Legended[data_i,label]	在图例中标识数据
	PopupWindow[data_i,cont]	为数据添加弹出窗口
	StatusArea[data_i,label]	当鼠标移过时在状态栏中显示
	Style[data_i,styles]	用指定样式显示数据
	Tooltip[data_i,label]	为数据添加提示条
	Tooltip[data_i]	将数据用作提示条

	{…,w[z_i],…}	封装数据中的值 z_i
	w[data_i]	封装数据
	w[{data₁,…}]	封装一组 data_i
	w₁[w₂[…]]	使用嵌套封装

	Automatic	自动放置标签
	Above, Below, Before, After	数据周围的位置
	x	在位置 x 处的数据周围
	Scaled[s]	沿数据的缩放过的位置 s
	{s,Above},{s,Below},…	沿数据在位置 s 处的相对位置
	{pos,epos}	在数据的相对位置 pos 处放置的标签中的 epos

	None	无图例
	Automatic	自动确定图例
	{lbl₁,lbl₂,…}	用 lbl₁、lbl₂、… 作为图例的标签
	Placed[lspec,…]	指定图例的放置

	{sty₁,sty₂,…}	针对各个数据集的一系列样式
	<\|"key"val,…\|>	针对不同层级的数据的样式元素

	"Base"	所有 data_i 的整体样式
	"Lists"	针对每个 data_i 的样式列表 sty_i

		style	突出显示指定的数据
		"Ball"	突出显示并标记数据中的指定点
		"Dropline"	突出显示并为数据中的指定点添加标签，并在轴线上标出垂线
		"XSlice"	突出显示并标记沿垂直切面的所有点
		"YSlice"	突出显示并标记沿水平切面的所有点
		Placed[effect,pos]	静态突出显示给定的位置 pos

ComplexListPlot

更多信息和选项

所有选项的列表

范例

基本范例 (4)

范围 (39)

数据 (7)

表格数据 (1)

特殊数据 (4)

封装 (6)

添加标签和图例 (15)

演示 (6)

选项 (156)

AspectRatio (4)

Axes (3)

AxesLabel (3)

AxesOrigin (2)

AxesStyle (4)

ClippingStyle (4)

ColorFunction (3)

ColorFunctionScaling (4)

Frame (3)

FrameLabel (4)

FrameStyle (2)

FrameTicks (9)

FrameTicksStyle (3)

ImageSize (8)

InterpolationOrder (4)

Joined (3)

LabelingFunction (7)

LabelingSize (3)

MaxPlotPoints (1)

Mesh (6)

MeshFunctions (3)

MeshShading (7)

PlotHighlighting (7)

PlotLabel (1)

PlotLabels (5)

PlotLegends (6)

PlotMarkers (8)

PlotRange (4)

PlotStyle (7)

PlotTheme (2)

PolarAxes (2)

PolarAxesOrigin (2)

PolarGridLines (2)

PolarTicks (4)

ScalingFunctions (3)

Ticks (9)

TicksStyle (4)

应用 (9)

属性和关系 (9)

可能存在的问题 (2)

巧妙范例 (3)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX