ListPointPlot3D[{{x1,y1,z1},{x2,y2,z2},…}]
座標{xi,yi,zi}の点の3Dの散布図を生成する.
ListPointPlot3D[array]
二次元配列の高さの値を持つ点の3D散布図を生成する.
ListPointPlot3D[{data1,data2,…}]
複数の点集団を,デフォルトにより,別々の色でプロットする.
ListPointPlot3D
ListPointPlot3D[{{x1,y1,z1},{x2,y2,z2},…}]
座標{xi,yi,zi}の点の3Dの散布図を生成する.
ListPointPlot3D[array]
二次元配列の高さの値を持つ点の3D散布図を生成する.
ListPointPlot3D[{data1,data2,…}]
複数の点集団を,デフォルトにより,別々の色でプロットする.
詳細とオプション
- データ値の xi,yi,ziは次の形式で与えられる.
-
xi 実数 Quantity[xi,unit] 単位付きの数量 Around[xi,ei] 不確かさが eiの値 xi Interval[{xmin,xmax}] xminから xmaxまでの値 - 上記の形式ではない値 xi,yi,ziは欠落しているものとみなされ,表示されない.
- dataiは次の形式と解釈を持つ.
-
<|"k1"{x1,y1,z1},"k2"{x2,y2,z2},…|> 値{{x1,y1,z1},{x2,y2,z2},…} {{x1,y1,z1}"lbl1",{x2,y2,z2}"lbl2",…}, data{"lbl1","lbl2",…} ラベル{lbl1,lbl2,…}が付いた値{{x1,y1,z1},{x2,y2,z2},…} SparseArray 通常の配列としての値 QuantityArray 大きさ WeightedData 重みなしの値 - ListPointPlot3D[objcspec]は,Tabularオブジェクト,TimeSeriesオブジェクト,またはEventSeriesオブジェクト obj から,指定 cspec を用いて値を抽出し,それをプロットする.
- 以下は,表形式データのプロットに使用できる指定 cspec である.
-
{cx,cy,cz} キー z の値を,キー x およびキー y からの値とプロットする {{cx1,cy1,cz1},{cx2,cy2,cz2},…} キー z1をキー x1および y1に対してプロットし,キー z2をキー x2およびキー y2に対してプロットする等 - dataiには次のラッバー w が使える.
-
Annotation[datai,label] データの注釈を与える Button[datai,action] データがクリックされたときに実行するアクションを定義する Callout[datai,label] コールアウトでデータにラベルを付ける Callout[datai,label,pos] 相対位置 pos にコールアウトを置く EventHandler[datai,…] データのための一般的なイベントハンドラを定義する Hyperlink[datai,uri] データをハイパーリンクにする Labeled[datai,label] データにラベルを付ける Labeled[datai,label,pos] 相対位置 pos にラベルを置く Legended[datai,label] 凡例でデータを区別する PopupWindow[datai,cont] データにポップアップウィンドウを付ける StatusArea[datai,label] マウスオーバーの際にステータスエリアに表示する Style[datai,styles] 指定のスタイルでデータを表示する Tooltip[datai,label] データにツールチップを付ける Tooltip[datai] データ値をツールチップとして使う - ラッパー w は複数のレベルで適用できる.
-
{{…,w[zi,j],…}} 配列データ中の値 zi,jをラップする {…,w[{xi,yi,zi}],…} 点{xi,yi,zi}をラップする w[datai] データをラップする w[{data1,…}] dataiの集合をラップする w1[w2[…]] ネストしたラッパーを使う - Callout,Labeled,Placedには,次の位置 pos を使うことができる.
-
Automatic 自動的にラベルを置く Above, Below, Before, After データ周囲の位置 {pos,epos} データの相対的な位置 pos に置かれたラベル中の epos - ラベルは,常にカメラの方を向く平面に置かれる.BeforeやAfter等はその平面上の位置を参照する.
- ListPointPlot3Dでは,Graphics3Dのオプションに次の追加・変更を加えたものが使える. [全オプションのリスト]
-
Axes True 軸を描くかどうか BoxRatios {1,1,0.4} 境界3Dボックスの割合 ColorFunction Automatic 点の色をどのように決めるか ColorFunctionScaling True ColorFunctionの引数をスケールするかどうか DataRange Automatic データを推測するための x と y の値の範囲 Filling None 各点の軸をどのように塗り潰すか FillingStyle Automatic 塗潰しに使うスタイル IntervalMarkers Automatic 不確かさをどのように描画するか IntervalMarkersStyle Automatic 不確かな要素のスタイル LabelingFunction Automatic 点にどのようにラベルを付けるか LabelingSize Automatic コールアウトとラベルのサイズ LabelingTarget Automatic 自動ラベル配置の決定方法 PerformanceGoal $PerformanceGoal パフォーマンスのどの面について最適化するか PlotFit None 曲線を点にどのようにフィットするか PlotFitElements Automatic プロット内に表示するフィットされた要素 PlotInteractivity $PlotInteractivity インタラクティブ要素を許可するかどうか PlotLegends None 点についての凡例 PlotRange {Full,Full,Automatic} 含める z や他の値の範囲 PlotRangePadding Automatic 値の範囲をどの程度充填するか PlotStyle Automatic 点のスタイル PlotTheme $PlotTheme プロットの全体的なテーマ RegionFunction (True&) 点を含めるかどうかの決定方法 RegionBoundaryStyle ![TemplateBox[{Automatic, paclet:ref/Automatic}, RefLink, BaseStyle -> {3ColumnTableMod}] TemplateBox[{Automatic, paclet:ref/Automatic}, RefLink, BaseStyle -> {3ColumnTableMod}]](Files/ListPointPlot3D.ja/1.png)
領域に使用するスタイル ScalingFunctions None 個々の座標をどのようにスケールするか - オプション設定のFilling->Automaticは,すべての点の幹を示す.
- DataRangeは,値{{z11, …, z1n},…,{zm1,…,zmn}} {z1q,…,zn}をどのように{{x11,y11,z11},…,{xmn,ymn,zmn}}と解釈するかを決定する.次は,可能な設定である.
-
Automatic,All 1 から m または n まで一様に {{xmin,xmax},{ymin,ymax}} xminから xmaxまで,および yminから ymaxまで一様に - 一般に,3つ1組のリスト{{x1,y1,z1},{x2,y2,z2},…}は点のリストであると解釈されるが,DataRangeAllと設定するとこれを複数のデータ datai {{z11,z12,z13},{z21,z22,z23},…}と強制的に解釈するようになる.
- PlotLegendsの典型的な設定には,次が含まれる.
-
None 凡例なし Automatic 凡例を自動的に決定する {lbl1,lbl2,…} lbl1,lbl2,…を凡例ラベルとして用いる Placed[lspec,…] 凡例の配置を指定する - PlotStylesty は,各曲線に使用するスタイルを指定する.可能な設定には以下が含まれる.
-
{sty1,sty2,…} データ集合に対するスタイルの列 <|"key"val,…|> データの異なるレベルに対するスタイル要素 - 使用可能なキーは次の通りである.
-
"Base" すべての datai に対する全体的なスタイル "Lists" datai ごとのスタイル styi のリスト - ColorData["DefaultPlotColors"] は,PlotStyle で使用されるデフォルトの色の並びを与える.
- ColorFunctionおよびRegionFunction内の関数に渡される引数は,x,y,z である.ColorFunction内の関数には,デフォルトで,これらの引数をスケールしたものが渡される.
全オプションのリスト
例題
すべて開く すべて閉じる例 (6)
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}]]data = Flatten[Table[{r Cos[t], r Sin[t], Sinc[r]}, {r, 0, 10, 0.5}, {t, 0, 2Pi, 0.1}], 1];ListPointPlot3D[data]Calloutとしてラベルを加える:
ListPointPlot3D[RandomReal[1, {6, 3}] -> RandomWord[6], LabelingFunction -> Callout]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, 3, 0.2}, {j, 0, 3, 0.2}], Filling -> Bottom]ListPointPlot3D[{Table[Sin[j ^ 2 + i], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], Table[Sin[j ^ 2 + i] + 3, {i, 0, 3, 0.1}, {j, 0, 3, 0.1}]}]ListPointPlot3D[Table[Sin[i]Cos[j], {i, -5, 5, .25}, {j, -5, 5, .25}], ColorFunction -> "Rainbow"]スコープ (36)
一般的なデータ (8)
値からなる正則データの場合,
と
のデータ範囲は整数値であるとみなされる:
ListPointPlot3D[Table[Sin[j / 3], {i, 20}, {j, 20}]]DataRangeを使って明示的な
と
のデータ範囲を与える:
ListPointPlot3D[Table[Sin[j / 3], {i, 20}, {j, 20}], DataRange -> {{0, 1}, {0, 1}}]ListPointPlot3D[{Table[Sin[j / 3], {i, 20}, {j, 20}], Table[-Sin[j / 3], {i, 20}, {j, 20}]}]
の組からなる非正則データの場合,
と
のデータ範囲はデータから推測される:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}]]data1 = Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}];
data2 = Table[{i, Cos[i + Pi / 2], Sin[i + Pi / 2]}, {i, 0, 20, .1}];ListPointPlot3D[{data1, data2}]ListPointPlot3D[ReplacePart[Partition[Range[100], 10], {{3, 3} -> None, {5, 7} -> I, {8, 4} -> Missing["NotAvailable"]}], PlotStyle -> PointSize[Large]]ListPointPlot3D[Table[Sqrt[2 - i ^ 2 - j ^ 2], {i, -2, 2, .1}, {j, -2, 2, .1}]]プロット範囲(PlotRange)は自動的に選択される:
ListPointPlot3D[Table[1 / (x ^ 2 + y ^ 2), {x, -2, 2, 8 / 51}, {y, -2, 2, 8 / 51}]]PlotRangeを使って関心領域に焦点を当てる:
{ListPointPlot3D[Table[x ^ 4 + y ^ 4 - x ^ 2 - y ^ 2 + 1, {x, -2, 2, 0.15}, {y, -2, 2, 0.15}]], ListPointPlot3D[Table[x ^ 4 + y ^ 4 - x ^ 2 - y ^ 2 + 1, {x, -2, 2, 0.15}, {y, -2, 2, 0.15}], PlotRange -> {0, 2}]}RegionFunctionを使って曲面を不等式で与えられる範囲に限定する:
data = Flatten[Table[{x, y, Sin[x ^ 2 + y ^ 2] / (x ^ 2 + y ^ 2)}, {x, -4, 4, 0.2}, {y, -4, 4, 0.2}], 1];//QuietListPointPlot3D[data, PlotRange -> All, RegionFunction -> Function[{x, y, z}, Norm[{x, y}] < 4]]表形式データ (2)
tab = Tabular[IconizedObject[«data»], {"x", "y", "f", "g"}]ListPointPlot3D[tab -> {"x", "y", "f"}]ListPointPlot3D[tab -> {{"x", "y", "f"}, {"x", "y", "g"}}]ListPointPlot3D[tab -> {{"x", "y", "f"}, {"x", "y", "g"}}, PlotLegends -> {"f", "g"}]tab = ResourceData["Sample Tabular Data: Palmer Penguins"]ListPointPlot3D[tab -> {"bill_length", "flipper_length", "body_mass"}]PivotToColumnsを使って各種について値の列を作成する:
pivot = PivotToColumns[tab, "species" -> "bill_length"]ListPointPlot3D[pivot -> {{"Adelie", "flipper_length", "body_mass"}, {"Gentoo", "flipper_length", "body_mass"}, {"Chinstrap", "flipper_length", "body_mass"}}, AxesLabel -> {"bill length", "flipper length", "body mass"}, PlotLegends -> {"Adelie", "Gentoo", "Chinstrap"}]特別なデータ (6)
Quantityを使って単位があるデータを含める:
ListPointPlot3D[Quantity[RandomReal[1, {6, 3}], "Meters"], AxesLabel -> Automatic]QuantityArrayのデータをプロットする:
data = QuantityArray[EntityValue[
EntityClass[
"Star", {EntityProperty["Star", "DistanceFromEarth"] ->
TakeSmallest[25]}], {"Mass", "Radius", "DistanceFromEarth"}]]ListPointPlot3D[data, AxesLabel -> Automatic]TargetUnitsで使う単位を指定する:
ListPointPlot3D[data, TargetUnits -> {"Tons", Automatic, Automatic}, AxesLabel -> Automatic]zvar = Table[Around[Sin[x] Cos[y], 1], {x, -4, 4}, {y, -4, 4}];ListPointPlot3D[zvar]ListPointPlot3D[{{2 -> "a", 3 -> "b", 5 -> "c", 7 -> "d", 11 -> "e", 13 -> "f", 17 -> "g"}}]ListPointPlot3D[{{2, 3, 5, 7, 11, 13, 17} -> {"a", "b", "c", "d", "e", "f", "g"}}]ListPointPlot3D[{{2, 3, 5, 7, 11, 13, 17} -> {"a", "b", "c", "d", "e", "f", "g"}}, LabelingFunction -> Above]SparseArrayのデータをプロットする:
ListPointPlot3D[SparseArray[{{i_, i_} -> -2, {i_, j_} /; Abs[i - j] == 1 -> 1}, {5, 5}]]データのラッパー (6)
個々のデータ,データ集合,あるいはデータ集合の集合にラッパーを使う:
{ListPointPlot3D[{{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[{Style[{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}, Green], {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[Style[{{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}, {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, Blue], PlotStyle -> PointSize[0.05]]}{ListPointPlot3D[{{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[{Style[{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, Green], {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[Style[{Style[{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, Green], {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, Blue], PlotStyle -> PointSize[0.05]]}ListPointPlot3D[Tooltip[RandomReal[1, {10, 3}]]]ListPointPlot3D[Tooltip[RandomReal[1, {10, 3}], "hello"]]ListPointPlot3D[Table[Labeled[RandomReal[1, 3], i], {i, 20}], PlotStyle -> PointSize[Medium], ImageSize -> 300]PopupWindowを使って追加的なドリルダウン情報を与える:
ListPointPlot3D[{{1, 1, 1}, PopupWindow[{2, 2, 2}, DateListPlot[FinancialData["IBM", "Jan. 1, 2004"]]], {3, 3, 3}}, PlotStyle -> PointSize[0.05]]Buttonを使って任意のアクションを起こすことができる:
ListPointPlot3D[{{1, 1, 1}, Button[{2, 2, 2}, Speak[2]], {3, 3, 3}}, PlotStyle -> PointSize[0.05]]ラベル付けと凡例 (6)
ListPointPlot3D[Table[Labeled[RandomReal[1, 3], i], {i, 20}], PlotStyle -> PointSize[Medium], ImageSize -> 300]Table[ListPointPlot3D[Table[Labeled[RandomReal[1, 3], i, p], {i, 5}], PlotLabel -> p], {p, {Above, Below, Before, After}}]LabelingFunctionでラベル名を指定する:
ListPointPlot3D[RandomReal[1, {10, 3}], LabelingFunction -> (#1[[1]] &)]data = Table[Table[{x, y, f}, {x, 0, 2Pi, 0.1}, {y, 0, 2Pi, 0.1}], {f, {Sin[x + y], Sin[2x + y]}}];ListPointPlot3D[Join@@@data, PlotLegends -> {Sin[x + y], Sin[2x + y]}]Legendedを使って特定のデータ集合に凡例を与える:
{upper, lower, average} = Join@@@Table[Table[{x, y, f}, {x, 0, 2Pi, 0.1}, {y, 0, 2Pi, 0.1}], {f, {Sin[x + y], Sin[-x - y], Sin[x + y] + Sin[-x - y]}}];ListPointPlot3D[{upper, lower, Legended[average, "average"]}]Placedを使って凡例の位置を変える:
ListPointPlot3D[{upper, lower, Legended[average, Placed["average", Below]]}]data = Table[Labeled[{RandomReal[i], RandomReal[i], RandomReal[i]}, RandomWord[]], {i, 10}];ListPointPlot3D[data, LabelingSize -> 30]ListPointPlot3D[data, LabelingSize -> Full]密な点の集合の場合は,デフォフトで,ラベルの中にツールチップに変えられるものがある:
data = Table[Labeled[{RandomReal[i], RandomReal[i], RandomReal[i]}, i], {i, 200}];ListPointPlot3D[data]ListPointPlot3D[data, ImageSize -> 400]プレゼンテーション (8)
点の明示的なPlotStyleを与える:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -3, 3, 0.05}, {j, -3, 3, 0.05}], PlotStyle -> Directive[Orange, PointSize[Tiny]]]data1 = Table[Sqrt[1 - x ^ 2 - y ^ 2], {x, -1, 1, 0.05}, {y, -1, 1, 0.1}];data2 = Table[-Sqrt[1 - x ^ 2 - y ^ 2], {x, -1, 1, 0.05}, {y, -1, 1, 0.1}];ListPointPlot3D[{data1, data2}, PlotStyle -> {Red, Blue}, BoxRatios -> Automatic, DataRange -> {{-1, 1}, {-1, 1}}]ListPointPlot3D[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], AxesLabel -> {j, i}, PlotLabel -> Sin[i + j ^ 2], PlotStyle -> Purple]ListPointPlot3D[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], ColorFunction -> Function[{x, y, z}, Hue[z]]]各点にインタラクティブなTooltipを与える:
ListPointPlot3D[Tooltip[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}]], PlotStyle -> Darker[Green]]プロット全体にインタラクティブなTooltipを与える:
ListPointPlot3D[Tooltip[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], TraditionalForm@Sin[i + j ^ 2]], PlotStyle -> Darker[Green]]ListPointPlot3D[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], Filling -> Bottom, FillingStyle -> Directive[Opacity[0.3], Blue], PlotStyle -> Directive[PointSize[Tiny], Red]]ListPointPlot3D[Table[Table[Sin[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Business"]ListPointPlot3D[Table[Table[Sin[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Marketing"]オプション (94)
Axes (3)
デフォルトで,Axesが描かれる:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}]]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> False]{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> {True, False, False}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> {False, True, False}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> {False, False, True}]}AxesLabel (4)
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True, AxesLabel -> z]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True, AxesLabel -> {x, y, z}]ListPointPlot3D[Table[{Quantity[i, "Meters"], Quantity[Cos[i], "Meters"], Quantity[Sin[i], "Meters"]}, {i, 0, 20, .1}], Axes -> True, AxesLabel -> Automatic]AxesOrigin (2)
AxesStyle (4)
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> Red]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> {{Thick, Brown}, {Thick, Blue}, {Thick, Green}}]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> Green, TicksStyle -> Red]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> Green, LabelStyle -> Red]ColorFunction (5)
Table[ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> Function[{x, y, z}, Evaluate[f]], PlotLabel -> f], {f, {Hue[x], Hue[y], Hue[z]}}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0.]]]定義済みの階調度にColorDataを使う:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> (ColorData["Rainbow"][#1]&)]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> "Rainbow"]ColorFunctionはPlotStyleよりも優先順位が高い:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> "Rainbow", PlotStyle -> Directive[Opacity[.5], Red]]ColorFunctionScaling (2)
data = Flatten[Table[{x, y, Abs[Sin[x + I y]]}, {x, -2Pi, 2Pi, Pi / 5}, {y, -2, 2, 1 / 5}], 1];ListPointPlot3D[data, ColorFunction -> Function[{x, y, z}, Hue@Rescale[Arg[Sin[x + I y]], {-Pi, Pi}]], ColorFunctionScaling -> False]スケールされていない座標はDataRangeに依存する:
data = Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}];ListPointPlot3D[data, ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0]], ColorFunctionScaling -> False]ListPointPlot3D[data, ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0]], ColorFunctionScaling -> False, DataRange -> {{0, 1}, {0, 1}}]DataRange (5)
ListPointPlot3D[Table[Sin[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}]]ListPointPlot3D[Table[Sin[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}], DataRange -> {{0, 2Pi}, {0, 2Pi}}]ListPointPlot3D[{Array[Times, {40, 40}], Array[700&, {30, 30}]}, DataRange -> {{0, 1}, {0, 1}}, PlotRange -> All, PlotStyle -> {Red, Blue}]data = Flatten[Table[{i, j, Sin[i + j]}, {j, 0, 2Pi, 0.2}, {i, -3, 3, .5}], 1];ListPointPlot3D[data]data = Table[Sin[i + j], {j, 0, 2Pi, 0.5}, {i, -1, 1}];ListPointPlot3D[data, DataRange -> All]ListPointPlot3D[data]Filling (3)
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> Bottom]塗潰しはRegionFunctionで切り取られた範囲に沿って行われる:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -Pi, Pi, 0.3}, {j, -Pi, Pi, 0.3}], Filling -> Bottom, RegionFunction -> (#1 ^ 2 + #2 ^ 2 < 5&), DataRange -> {{-Pi, Pi}, {-Pi, Pi}}]ListPointPlot3D[Table[Cos[y] + a, {a, {-1, 1}}, {x, 0, 2Pi, .3}, {y, 0, 2Pi, .3}], Filling -> {1 -> {Bottom, Blue}, 2 -> {Top, Red}}]FillingStyle (3)
Table[ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> Bottom, FillingStyle -> fs], {fs, {Directive[Opacity[0.2], Blue], Directive[Red, Dashed]}}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> 0, FillingStyle -> {Orange, Blue}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> 0, FillingStyle -> {None, Blue}]ImageSize (7)
Tiny,Small,Medium,Largeのような名前付きのサイズを使う:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> Tiny], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> Small]}{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> 150], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 1.5, ImageSize -> 150]}{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> {Automatic, 150}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> UpTo[200]], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 2, ImageSize -> UpTo[200]]}グラフィックスの幅と高さを指定して,必要な場合はスペースで充填する:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> {200, 300}, Background -> StandardYellow]AspectRatioFullと設定すると,使用可能なスペースが塗り潰される:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> Full, ImageSize -> {200, 300}, Background -> StandardYellow]{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> {UpTo[150], UpTo[100]}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}ImageSizeFullを使ってオブジェクト内の使用可能なスペースを塗り潰す:
Framed[Pane[ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> Full, Background -> StandardYellow], {200, 100}]]Framed[Pane[ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardYellow], {200, 200}]]IntervalMarkers (2)
zvar = Table[Around[Sin[x] Cos[y], 1], {x, -4, 4}, {y, -4, 4}];ListPointPlot3D[zvar]名前付きのIntervalMarkersを使う:
xyzvar = Flatten[
Table[{x, y, Around[Sin[x] Cos[y], 1]}, {x, -4, 4}, {y, -4, 4}], 1];ListPointPlot3D[xyzvar, IntervalMarkers -> "Tubes"]IntervalMarkersStyle (2)
zvar = Table[Around[Sin[x] Cos[y], 1], {x, -4, 4}, {y, -4, 4}];ListPointPlot3D[zvar]xyzvar = Flatten[
Table[{x, y, Around[Sin[x] Cos[y], 1]}, {x, -4, 4}, {y, -4, 4}], 1];ListPointPlot3D[xyzvar, IntervalMarkersStyle -> Red]LabelingSize (3)
コールアウトとラベル内の画像は,デフォルトで,自動的にサイズが調整される:
ListPointPlot3D[RandomReal[1, {6, 3}] -> {[image], [image], [image] , [image], [image], [image]}, LabelingFunction -> Callout]LabelingSizeを使ってラベルの表示サイズを変える:
ListPointPlot3D[RandomReal[1, {6, 3}] -> {[image], [image], [image] , [image], [image], [image]}, LabelingFunction -> Callout, LabelingSize -> 20]SeedRandom[1];data = RandomInteger[100, {10, 3}] -> RandomWord[10]ListPointPlot3D[data, LabelingFunction -> Callout]ListPointPlot3D[data, LabelingFunction -> Callout, LabelingSize -> 40]LabelingTarget (7)
ListPointPlot3D[IconizedObject[«data»]]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> All]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> "Dense"]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> 0.25]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> "Sides"|>]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> "Corners"|>]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> {"Right", "Top"}|>]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedOverlaps" -> {"Points"}|>]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowLabelClipping" -> True|>]PlotFit (4)
ListPointPlot3D[IconizedObject[«data»], PlotFit -> Automatic]ListPointPlot3D[IconizedObject[«data»], PlotFit -> "Linear"]ListPointPlot3D[IconizedObject[«data»], PlotFit -> "Quadratic"]ListPointPlot3D[IconizedObject[«data»], PlotFit -> NearestModel[]]PlotFitElements (3)
デフォルトで,フィットされたモデルがデータとともに表示される:
ListPointPlot3D[IconizedObject[«data»], PlotFit -> Automatic]デフォルトの信頼水準0.95でデータの信頼帯をプロットする:
Quiet@ListPointPlot3D[IconizedObject[«data»], PlotFit -> Automatic, PlotFitElements -> "BandSurfaces"]Quiet@ListPointPlot3D[IconizedObject[«data»], PlotFit -> Automatic, PlotFitElements -> {"BandSurfaces", <|"ConfidenceLevel" -> 0.5|>}]ListPointPlot3D[IconizedObject[«data»], PlotFit -> Automatic, PlotFitElements -> {"Residuals", <|"Style" -> Red|>}]PlotLegends (5)
ListPointPlot3D[{Table[Sin[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}], Table[Cos[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}]}]ListPointPlot3D[{Table[Sin[i + j], {i, 0, 10, 0.25}, {j, 0, 10, 0.25}], Table[-Sin[i - j], {i, 0, 10, 0.25}, {j, 0, 10, 0.25}]}, PlotStyle -> {Red, Blue}, PlotLegends -> {Sin[x + y], -Sin[x - y]}]ListPointPlot3D[{Table[Sin[j / 3], {i, 20}, {j, 20}], Table[-Sin[j / 3], {i, 20}, {j, 20}]}, PlotStyle -> {Blue, Orange}, PlotLegends -> Automatic]Placedを使って凡例の置き方を指定する:
Table[ListPointPlot3D[{Table[Sin[j ^ 2 + i], {i, -Pi, Pi, 0.2}, {j, -2, 2, 0.2}], Table[Cos[j ^ 2 + i], {i, -Pi, Pi, 0.2}, {j, -2, 2, 0.2}]}, PlotLegends -> Placed[TraditionalForm /@ {Sin[x ^ 2 + y], Cos[x ^ 2 + y]}, pos], PlotLabel -> pos], {pos, {Above, Below}}]Table[ListPointPlot3D[{Table[Sin[Log[(i + j) ^ 2]], {i, 20}, {j, 20}], Table[Sin[-Log[(i + j) ^ 2]], {i, 20}, {j, 20}]}, PlotLegends -> Placed[{"data 1", "data 2"}, pos], PlotLabel -> pos], {pos, {Above, Below}}]BarLegendでカスタムの凡例を構築する:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> (ColorData["Rainbow"][#1]&), PlotLegends -> Placed[BarLegend[{"Rainbow", {-1, 1}}], Below]]PlotRange (3)
ListPointPlot3D[Table[Exp[-x ^ 2 - y ^ 2], {x, -3, 3, .1}, {y, -3, 3, .1}], PlotStyle -> PointSize[Tiny]]ListPointPlot3D[Table[Exp[-x ^ 2 - y ^ 2], {x, -3, 3, .1}, {y, -3, 3, .1}], PlotRange -> All, PlotStyle -> PointSize[Tiny]]ListPointPlot3D[Table[y ^ 2 - x ^ 2, {x, -4, 4, 0.1}, {y, -4, 4, 0.1}], PlotRange -> {-2, 2}]PlotStyle (4)
デフォルトで,複数のデータ集合には異なるスタイルが選択される:
ListPointPlot3D[{IconizedObject[«Data 1»], IconizedObject[«Data 2»]}]ListPointPlot3D[{IconizedObject[«Data 1»], IconizedObject[«Data 2»]}, PlotStyle -> {StandardRed, StandardBlue}]連想に基づくシンタックスを使ってすべてのデータのベーススタイルを設定する:
ListPointPlot3D[{IconizedObject[«Data 1»], IconizedObject[«Data 2»]}, PlotStyle -> <|"Base" -> PointSize[Large]|>]ListPointPlot3D[{IconizedObject[«Data 1»], IconizedObject[«Data 2»]}, PlotStyle -> <|"Lists" -> {StandardGreen, StandardRed}|>]ListPointPlot3D[{IconizedObject[«Data 1»], IconizedObject[«Data 2»]}, PlotStyle -> <|"Base" -> PointSize[Large], "Lists" -> {StandardGreen, StandardRed}|>]PlotTheme (2)
ListPointPlot3D[Table[Table[Cos[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Web"]ListPointPlot3D[Table[Table[Cos[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Web", PlotStyle -> {StandardBlue, StandardGreen}]RegionBoundaryStyle (3)
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> Automatic]Noneを使って領域を示さないようにする:
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> None]カスタムのRegionBoundaryStyleを使う:
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> Directive[Yellow, Opacity[.8]]]RegionFunction (4)
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.05}, {j, 0, Pi, 0.05}], RegionFunction -> Function[{x, y, z}, Abs[z] > 0.5], PlotStyle -> PointSize[Small]]範囲はDataRangeに依存する:
data = Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}];ListPointPlot3D[data, RegionFunction -> Function[{x, y, z}, Norm[{x, y}] < 4]]ListPointPlot3D[data, RegionFunction -> Function[{x, y, z}, Norm[{x, y}] < 4], DataRange -> {{0, Pi}, {0, Pi}}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.05}, {j, 0, Pi, 0.05}], RegionFunction -> Function[{x, y, z}, 0 < Mod[x ^ 2 + y ^ 2, 2] < 1], DataRange -> {{0, Pi}, {0, Pi}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> None]ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small]]ScalingFunctions (5)
SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}]]SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> "Log"]SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> "Reverse"]SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> {"Log", "Log", "Reverse"}]SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> {None, None, {-Log[#]&, Exp[-#]&}}]Ticks (6)
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}]]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> None]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{5, 15, 25}, {5, 15, 25}, {-.9, 0, .9}}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{{5, a}, {15, b}, {25, c}}, {{5, a}, {15, b}, {25, c}}, {{-.9, -A}, {0, 0}, {.9, A}}}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{{5, a, .05}, {15, b, .05}, {25, c, .05}}, {{5, a, .01}, {15, b, .01}, {25, c, .01}}, {{-.9, -A, .1}, {0, 0, .1}, {.9, A, .1}}}]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{{5, a, .05, Directive[Red]}, {15, b, .05, Directive[Red, Thick]}, {25, c, .05, Directive[Red, Thick, Dashed]}}, {{5, a, .05, Directive[Blue]}, {15, b, .05, Directive[Blue, Thick]}, {25, c, .05, Directive[Blue, Thick, Dashed]}}, {{-.9, -A, .1, Directive[Darker@Yellow, Thick]}, {0, 0, .1, Directive[Darker@Yellow, Thick, Dashed]}, {.9, A, .1, Directive[Darker@Yellow, Thick]}}}]TicksStyle (3)
デフォルトで,目盛と目盛ラベルには軸と同じスタイルが使われる:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], AxesStyle -> Directive[Thick, Red]]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], TicksStyle -> Directive[Bold, Red]]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], TicksStyle -> {Directive[Green, Bold], Directive[Bold, Red], Directive[Bold, Blue]}]アプリケーション (1)
points = Reap[NIntegrate[Boole[(x - 1)^2 + z^2 < 1] + Boole[(y - 1)^2 - z^2 < 1], {x, 0, 2}, {y, 0, 2}, {z, 0, 1}, EvaluationMonitor :> Sow[{x, y, z}]]][[2, 1]];ListPointPlot3D[points, BoxRatios -> Automatic, ColorFunction -> "Rainbow", PlotStyle -> PointSize[Small]]特性と関係 (11)
ListPlotとListLinePlotを使って高さを2Dでプロットする:
{ListPlot[{1, 3, 4, 2, 7, 5}], ListLinePlot[{1, 3, 4, 2, 7, 5}]}{ListPlot[{{1, 5}, {2, 2}, {3, 9}, {4, 3}, {4, 7}, {5, 7}, {7, 1}, {8, 4}}], ListLinePlot[{{1, 5}, {2, 2}, {3, 9}, {4, 3}, {4, 7}, {5, 7}, {7, 1}, {8, 4}}]}ListLinePlot3Dを使って点のリストを通る曲線をプロットする:
ListLinePlot3D[Table[{Cos[t], Sin[t], Sin[5t]}, {t, 0, 2Pi, 0.1}]]ListLinePlot3D[Table[Sin[j ^ 2 + i], {i, 0, 3, 0.25}, {j, 0, 3, 0.1}]]ListPlot3Dを使ってデータから曲面を作成する:
ListPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}]]Plot3Dを使って関数を可視化する:
Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}]ListLogPlot,ListLogLogPlot,ListLogLinearPlotを対数データのプロットに使う:
ListLogPlot[Table[Binomial[25, k], {k, 0, 25}], Joined -> True]ListPolarPlotを極プロットに使う:
ListPolarPlot[Table[{x, Sqrt[x]}, {x, 0, 2Pi, 0.1}], Joined -> True]DateListPlotを使ってデータを経時的に示す:
DateListPlot[{34, 51, 11, 5, 39, 47, 28, 42, 66, 13, 24, 31}, {2006, 1}, Joined -> True]ListContourPlotを使って連続データから等高線を作成する:
ListContourPlot[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}]]ListDensityPlotを使って連続データから密度を作成する:
ListDensityPlot[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}]]ArrayPlotとMatrixPlotを離散値配列に使う:
ArrayPlot[Table[GCD[i, j], {i, 1, 20}, {j, 1, 20}]]ParametricPlotをパラメトリック曲線に使う:
{ParametricPlot[{Cos[θ], Sin[θ]}, {θ, 0, 2Pi}], ListLinePlot[Table[{Cos[θ], Sin[θ]}, {θ, 0, 2Pi, 0.1}], AspectRatio -> 1]}おもしろい例題 (2)
ListPointPlot3D[Table[Table[{t, Cos[t + s Pi / 2], Sin[t + s Pi / 2]}, {t, 0, 5Pi, .2}], {s, 4}], BoxRatios -> Automatic]ListPointPlot3D[Table[Table[(4Pi - t){Cos[t + s Pi / 2], Sin[t + s Pi / 2], 0} + {0, 0, 2t}, {t, 0, 4Pi, .1}], {s, 4}], Filling -> Bottom, ColorFunction -> "Rainbow", BoxRatios -> Automatic, FillingStyle -> Directive[LightGreen, Thick, Opacity[.1]]]履歴
2007 で導入 (6.0) | 2012 で更新 (9.0) ▪ 2014 (10.0) ▪ 2016 (11.0) ▪ 2018 (11.3) ▪ 2020 (12.1) ▪ 2025 (14.2) ▪ 2025 (14.3) ▪ 2026 (15.0)
テキスト
Wolfram Research (2007), ListPointPlot3D, Wolfram言語関数, https://reference.wolfram.com/language/ref/ListPointPlot3D.html (2026年に更新).
CMS
Wolfram Language. 2007. "ListPointPlot3D." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ListPointPlot3D.html.
APA
Wolfram Language. (2007). ListPointPlot3D. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ListPointPlot3D.html
BibTeX
@misc{reference.wolfram_2026_listpointplot3d, author="Wolfram Research", title="{ListPointPlot3D}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ListPointPlot3D.html}", note=[Accessed: 09-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_listpointplot3d, organization={Wolfram Research}, title={ListPointPlot3D}, year={2026}, url={https://reference.wolfram.com/language/ref/ListPointPlot3D.html}, note=[Accessed: 09-November-2026]}